excelif命令使用

1. excel中if函數的使用方法

excel中if函數的使用方法

IF函數是工作中最常用的函數之一，下面是我給大家帶來的excel中if函數的使用方法，希望對您有所幫助！

excel中if函數的使用方法 篇1

一、IF函數的使用方法（入門級）

1、單條件判斷返回值

=IF(A1>20,"完成任務","未完成")

2、多重條件判斷

=IF(A1="101","現金",IF(A1="1121","應收票據"，IF(A1=1403,"原材料")))

註：多條件判斷時，注意括弧的位置，右括弧都在最後，有幾個IF就輸入幾個右括弧。

3、多區間判斷

=IF(A1<60,"不及格",IF(A1<80,"良好","優秀"))

=IF(A1>=80,"優秀",IF(A1>=60,"良好","不及格"))

註：IF在進行區間判斷時，數字一定要按順序判斷，要麼升要不降。

二、IF函數的使用方法(進階)

4、多條件並列判斷

=IF(AND(A1>60,B1<100),"合格","不合格")

=IF(OR(A1>60,B1<100),"合格","不合格")

註：and()表示括弧內的多個條件要同時成立

or()表示括弧內的多個條件任一個成立

5、復雜的多條件判斷

=IF(OR(AND(A1>60,B1<100),C1="是"),"合格","不合格")

=IF(ADN(OR(A1>60,B1<100),C1="是"),"合格","不合格")

6、判斷後返回區域

=VLOOKUP(A1,IF(B1=1,C:D,F:G),2,0)

註：IF函數判斷後返回的不只是值，還可以根據條件返回區域引用。

三、IF函數的使用方法（高級）

7、IF({1,0}結構

=VLOOKUP(A1,IF({1,0},C1:C10,B1:B10),2,0)

{=VLOOKUP(J15&K15,IF({1,0},A1:A2&B1:B2,C1:C2),2,0)}

註：利用數組運算返回數組的原理，IF（{1,0}也會返回一個數組，即當第一個參數為1時的結果放在第1列，為0時的結果放在數組第二列。

8、N(IF( 和 T(IF(

{=SUM(VLOOKUP(T(IF({1,0},J15,K15)),E15:G17,3,0))}

注:vlookup函數第一個參數不能直接使用數組，借用t(if結構可以轉換成內存數組。

excel中if函數的使用方法 篇2

一、excel if函數基本用法

在excel表格中，如果我們學會使用excel if函數來處理數據的話，可以提高我們的工作效率。接下來我們一起來學習excel if函數的.基本用法吧！

excel if函數語法格式：=IF(條件，值1，值2)

語法格式說明：

IF括弧中的逗號是英文下的逗號；當條件滿足時，則返回值1；當條件不滿足時，則返回值2；值2可以省略，省略後返回值由FALSE代替。

excel if函數用法

實例的內容：使用excel if函數將是否合格一列的數據補充完整（大於或等於60分的為合格，其它的為不合格）。

操作步驟：將滑鼠游標放在是否合格單元格下的空單元格->在fx後的輸入框中輸入「=IF(E2>=60,"合格","不合格")」並按回車鍵（Enter鍵）->將滑鼠游標放在該單元格的右下角往下拉即可。

excel if函數用法

二、excel if函數嵌套用法

excel if函數嵌套用法也很簡單，和基本用法差不多，只是多了一層或多層IF函數而已。接下來我們一起來看看學習吧！

1、excel if函數語法格式：IF(條件1，值1，IF(條件2，值2，值3))

語法格式說明：

IF括弧中的逗號是英文下的逗號；當滿足條件1時，則返回值1；當不滿足條件1時，判斷條件2，如果滿足條件2，則返回值2，否則返回值3；excel if函數嵌套還可以多成嵌套。

2、實例

實例內容：將成績是否合格一列補充完整（小於60分的為不合格，大於或等於80分的優秀，其餘的為合格）。

操作步驟和上邊基本用法的操作一樣，只是在fx後輸入框中輸入的函數不一樣，應該輸入的是：「=IF(E2<60,"不合格",IF(E2>=80,"優秀","合格"))」。

2. EXCEL IF語句使用

1、電腦打開Excel表格。

3. excel中IF函數的使用方法

IF
全部顯示全部隱藏
根據對指定的條件計算結果為 TRUE 或 FALSE，返回不同的結果。
可以使用 IF 對數值和公式執行條件檢測。
語法
IF(logical_test,value_if_true,value_if_false)
Logical_test 表示計算結果為 TRUE 或 FALSE 的任意值或表達式。例如，A10=100 就是一個邏輯表達式；如果單元格 A10 中的值等於 100，表達式的計算結果為 TRUE；否則為 FALSE。此參數可使用任何比較運算符。
Value_if_true 是 logical_test 為 TRUE 時返回的值。例如，如果此參數是文本字元串「預算內」，而且 logical_test 參數的計算結果為 TRUE，則 IF 函數顯示文本「預算內」。如果 logical_test 為 TRUE 而 value_if_true 為空，則此參數返回 0（零）。若要顯示單詞 TRUE，請為此參數使用邏輯值 TRUE。Value_if_true 可以是其他公式。
Value_if_false 是 logical_test 為 FALSE 時返回的值。例如，如果此參數是文本字元串「超出預算」而 logical_test 參數的計算結果為 FALSE，則 IF 函數顯示文本「超出預算」。如果 logical_test 為 FALSE 而 value_if_false 被省略（即 value_if_true 後沒有逗號），則會返回邏輯值 FALSE。如果 logical_test 為 FALSE 且 value_if_false 為空（即 value_if_true 後有逗號並緊跟著右括弧），則會返回值 0（零）。Value_if_false 可以是其他公式。
註解
最多可以使用 64 個 IF 函數作為 value_if_true 和 value_if_false 參數進行嵌套以構造更詳盡的測試。（示例 3 是嵌套 IF 函數的一個例子。）此外，若要檢測多個條件，請考慮使用 LOOKUP、VLOOKUP 或 HLOOKUP 函數。（示例 4 是 LOOKUP 函數的一個例子。）
在計算參數 value_if_true 和 value_if_false 時，IF 會返回相應語句執行後的返回值。
如果函數 IF 的參數包含數組 （數組:用於建立可生成多個結果或可對在行和列中排列的一組參數進行運算的單個公式。數組區域共用一個公式；數組常量是用作參數的一組常量。），則在執行 IF 語句時，數組中的每一個元素都將計算。
Microsoft Excel 還提供了其他一些函數，它們可根據條件來分析數據。例如，如果要計算某單元格區域內某個文本字元串或數字出現的次數，則可使用 COUNTIF 和 COUNTIFS 電子表格函數。若要計算基於某區域內一個文本字元串或一個數值的總和，可使用 SUMIF 和 SUMIFS 工作表函數。
示例 1

如果將示例復制到一個空白工作表中，可能會更易於理解。

如何復制示例
創建一個空白工作簿或工作表。在幫助主題中選擇示例。 注釋 請不要選擇行或列標題。

從幫助中選擇示例按 Ctrl+C。在工作表中，選擇單元格 A1，然後按 Ctrl+V。若要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或在「公式」選項卡的「公式審核」組中，單擊「顯示公式」按鈕。

1
2
A
數據
50
公式 說明（結果）
=IF(A2<=100,"預算內","超出預算") 如果上面的數字小於等於 100，則公式將顯示「預算內」。否則，公式顯示「超出預算」。(預算內)
=IF(A2=100,SUM(B5:B15),"") 如果上面數字為 100，則計算單元格區域 B5:B15，否則返回空文本 ("")

示例 2

如果將示例復制到一個空白工作表中，可能會更易於理解。

如何復制示例
創建一個空白工作簿或工作表。在幫助主題中選擇示例。 注釋 請不要選擇行或列標題。

從幫助中選擇示例按 Ctrl+C。在工作表中，選擇單元格 A1，然後按 Ctrl+V。若要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或在「公式」選項卡的「公式審核」組中，單擊「顯示公式」按鈕。

1
2
3
4
A B
實際費用 預期費用
1500 900
500 900
500 925
公式 說明（結果）
=IF(A2>B2,"超出預算","OK") 檢查第一行是否超出預算 (超出預算)
=IF(A3>B3,"超出預算","OK") 檢查第二行是否超出預算 (OK)

示例 3

如果將示例復制到一個空白工作表中，可能會更易於理解。

如何復制示例
創建一個空白工作簿或工作表。在幫助主題中選擇示例。 注釋 請不要選擇行或列標題。

從幫助中選擇示例按 Ctrl+C。在工作表中，選擇單元格 A1，然後按 Ctrl+V。若要在查看結果和查看返回結果的公式之間切換，請按 Ctrl+`（重音符），或在「公式」選項卡的「公式審核」組中，單擊「顯示公式」按鈕。

1
2
3
4
A
成績
45
90
78
公式 說明（結果）
=IF(A2>89,"A",IF(A2>79,"B", IF(A2>69,"C",IF(A2>59,"D","F")))) 給第一個成績指定一個字母等級 (F)
=IF(A3>89,"A",IF(A3>79,"B", IF(A3>69,"C",IF(A3>59,"D","F")))) 給第二個成績指定一個字母等級 (A)
=IF(A4>89,"A",IF(A4>79,"B", IF(A4>69,"C",IF(A4>59,"D","F")))) 給第三個成績指定一個字母等級 (C)

在上例中，第二個 IF 語句同時也是第一個 IF 語句的參數 value_if_false。同樣，第三個 IF 語句是第二個 IF 語句的參數 value_if_false。例如，如果第一個 logical_test (Average > 89) 為 TRUE，則返回「A」；如果第一個 logical_test 為 FALSE，則計算第二個 IF 語句，以此類推。

用下列關鍵字指定數字的字母等級。

如果成績是 則返回
大於 89 A
80 到 89 B
70 到 79 C
60 到 69 D
低於 60 F