❶ 你好，麻煩給我看看這個ANSYS命令中註明出該怎麼理解，為什麼這么做
因為每次的CM都是不同的，所以每次用cmsel選擇的線段也不同，後面這個是定義不同的屬穗飢性：mat,real,type,從後處理可以看出，這部分不單是為了區分材料和單元屬性的不同，而且後處猜旦返理的時候遲改也用到，這樣做更有利於選擇不同的cm分別進行顯示計算結果。
❷ 高分求ANSYS命令流
涉及接觸以及螺栓預緊
finish
/clear
!!!!!!!!!!!!!!!!環境設置!!!!!!!!!!!!!!!!!!!!!!!!!
/filn,flange
/title,flang_bolt
!設定結構基本參數，單位N,mm,MPa．密度為tons/mm3
*SET,PN,4 !工作壓力
!結構尺寸參數遵循圖形
*SET,DN,900
*SET,D,1115
*SET,D1,1055
*SET,D2,1010
*SET,D3,1000
*SET,D4,997
*SET,dta,86
*SET,H,170
*SET,xh,42
*SET,a,3
*SET,a1,3
*SET,dta1,24
*SET,dta2,36
*SET,R,15
*SET,xd,33
*SET,h1,225
*SET,h2,50
*SET,L,2.5*((DN/2+0.5*dta1)*dta1)**0.5 !筒體長
*SET,N,360/96 !法蘭分度數
*SET,nut_rad,50.85/2 !螺母半徑
*SET,nut_h,25.6 !螺母高度
*SET,bolt_h,250 !螺栓高度廳絕薯
*SET,forc_bolt,35000 !螺栓預緊力
/prep7 !進入前處理器
et,1,solid45 !實體單元
et,2,TARGE170 !3D接觸目標面單元170
et,3,CONTA174 !3D接觸接觸面單元174
keyopt,3,9,0 !包含初始化穿透
*AFUN,DEG !設定角度單位為度數
!定義法蘭材料1
mp,ex,1,2.16e5 !設定彈性模量
mp,nuxy,1,0.3 !定義泊松比
mp,dens,1,7.85e-9 !定義密度
!定義螺栓材料2
mp,ex,2,2.11e5 !設定彈性模宏掘量
mp,nuxy,2,0.3 !定義泊松比
mp,dens,2,7.85e-9 !定義密度
!定義摩擦系數為材料3
mp,mu,3,0.3
!!!!!!!!!!!!!!創建上法蘭!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!創建關鍵點
k,1,DN/2,a+H
k,2,DN/2+dta1,a+H
k,3,DN/2+dta1,a+xh+dta
k,4,DN/2+dta2,a+dta
k,5,D1/扮者2,a+dta
k,6,D/2,a+dta
k,7,D/2,a
k,8,D1/2,a
k,9,D4/2,a
k,10,D4/2,0
k,11,DN/2,0
k,12,DN/2,a+dta
k,13,DN/2,a+dta+xh
!通過關鍵點連線
*do,ii,1,12
l,ii,ii+1
*enddo
l,1,13
lfillt,2,3,R !創建倒角
lfillt,3,4,R !創建倒角
l,13,14
l,12,17
l,17,9
l,5,8
!連線構面
al,1,2,16,13
al,16,14,3,15,17,12
al,17,18,9,10,11
al,4,19,8,18
al,5,6,7,19
cm,flang_up,area !創建上法蘭面積組件
!!!!!!!!!!!!!上法蘭創建完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!創建下法蘭!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!創建關鍵點
k,18,DN/2,a-a1
k,19,D3/2,a-a1
k,20,D3/2,a
k,21,D1/2,a
k,22,D/2,a
k,23,D/2,a-a1-dta
k,24,D1/2,a-a1-dta
k,25,D3/2,a-a1-dta
k,26,DN/2+dta2,a-a1-dta
k,27,DN/2+dta1,a-a1-dta-xh
k,28,DN/2+dta1,a-a1-H
k,29,DN/2,a-a1-H
k,30,DN/2,a-a1-dta-xh
k,31,DN/2,a-a1-dta
!通過關鍵點連線
*do,ii,18,30
l,ii,ii+1
*enddo
l,18,31
lfillt,27,28,R
lfillt,28,29,R
l,30,35
l,31,32
l,21,24
l,19,25
!連線構面
al,29,30,31,36
al,35,36,32,37,34,28
al,20,39,27,37,33
al,21,22,38,26,39
al,23,24,25,38
asel,u,area,,flang_up !選擇除flang_up之外的所有面
cm,flang_down,area !創建下法蘭面積組件
!!!!!!!!!!!!!下法蘭創建完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!創建橢圓封頭!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
k,,0,a+H+h2 !創建封頭所處位置關鍵點
circle,36,1 !創建單位長圓
KWPAVE,36 !將工作平面移置於新設定點
CSYS,4 !激活隨工作平面的坐標系
lsscale,40,43,1,DN/2+dta1,h1+dta1,,,1 !對單位圓按照橢圓比例進行縮放(外表面)
lsscale,40,43,1,DN/2,h1,,,1 !對單位圓按照橢圓比例進行縮放（內表面）
ldele,49,51,1,1 !刪除多餘的線段
ldele,45,47,1,1
ldele,40,43,1,1
wpstyl,defa !恢復工作平面至默認狀態
l,45,41 !連接封頭端、尾
l,42,46
l,1,45 !連接封頭與法蘭
l,2,41
!由線構成封頭面
al,40,42,1,43
al,44,40,48,41
asel,u,area,,flang_down !選擇構成封頭的所有面
cm,coping,area !創建封頭面積組件
!!!!!!!!!!!!!封頭創建完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!!創建筒體!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
allsel
k,,DN/2,a-a1-H-L !創建筒體底端位置點
k,,DN/2+dta1,a-a1-H-L
a,28,29,37,38 !連接筒體與下法蘭，構成面
asel,u,area,,flang_up
asel,u,area,,flang_down
asel,u,area,,coping !排除筒體之外的所有面
cm,pot,area !創建筒體面積組件
!!!!!!!!!!!!!筒體創建完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!布爾操作，將面與面之間粘接!!!!!!!!!!!!!
asel,s,area,,flang_up
asel,a,area,,coping
aglue,all !將封頭與上法蘭面粘接
asel,s,area,,flang_down
asel,a,area,,pot
aglue,all !將筒體與下法蘭面粘接
kdele,36 !刪除建模過程中輔助點
!!!!!!!!!!!!!布爾操作完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
allsel
vrotat,all,,,,,,42,46,N !將所有的面繞y軸旋轉N度,創建體
!!!!!!!!!!!!!創建螺栓!!!!!!!!!!!!!
KL,76,0.5, , !設定關鍵點平分線76，該點為螺栓中心所在
KWPAVE,77 !將工作平面移動至該點
wprota,0,90 !將工作平面繞x軸旋轉90度
cyl4,,,xd/2,,,,bolt_h !創建螺栓
!將與螺栓相交的體組成一個組件，以便選取
vsel,s,volu,,4,5,1
vsel,a,volu,,9,10,1
cm,buer,volu !創建與螺栓相交的體積組件buer
allsel
bopt,numb,off
vsbv,buer,14 !將組件buer與螺栓進行布爾操作，挖出螺栓孔洞
cyl4,,,xd/2,,,,bolt_h !創建螺栓,體積編號為4
VGEN,,4,,,,,-(bolt_h/2-dta-a),,,1 !將螺栓平移至合適位置
rpr4,6,,,nut_rad,,-nut_h !創建螺母
vgen,2,5,,,,,2*dta+a1+nut_h,,,0 !復制螺母至合適位置
!!!!!!!!!!!!!螺栓創建完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!創建各部分體積組件方便選擇!!!!!!!!!!!!!
vsel,s,volu,,4,5,1
vsel,a,volu,,9
vptn,all
cm,bvolu,volu !創建螺栓組件
allsel
wpstyl,defa
vsel,s,loc,y,-H-L,a1
vsel,u,volu,,bvolu
cm,flang_dvolu,volu !創建下法蘭組件
allsel
vsel,s,loc,y,a1,H
vsel,u,volu,,bvolu
cm,flang_upvolu,volu !創建上法蘭組件
allsel
vsel,s,loc,y,H+a,H+h1+dta1
cm,cop_volu,volu !創建封頭組件
!!!!!!!!!!!!!!!劃分網格!!!!!!!!!!!!!!!!!!!!!!!!!!!!
mat,1 !指定材料
esize,5 !指定單元大小
cmsel,s,cop_volu !選中封頭組件
vsweep,all !對封頭分網
esize,5 !指定單元大小
cmsel,s,flang_dvolu !選中下法蘭組件
vsweep,all !對下法蘭分網
cmsel,s,flang_upvolu !選中上法蘭組件
vsweep,all !對上法蘭分網
esize,4 !指定單元大小
mat,2 !指定材料
cmsel,s,bvolu !選中螺栓組件
vsweep,all !對螺栓分網
!!!!!!!!!!!!!網格劃分完畢!!!!!!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!對模型節點進行壓縮合並!!!!!!!!!!!!!!!!!!!!!
!合並上法蘭節點
allsel
vsel,s,loc,y,0,2*H
vsel,u,volu,,bvolu
nslv,s,1
nummrg,node
!合並下法蘭節點
allsel
vsel,s,loc,y,-(H+L),a1
vsel,u,volu,,bvolu
nslv,s,1
nummrg,node
!!!!!!!!!!!!!節點合並完畢!!!!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!!建立螺栓預緊單元!!!!!!!!!!!!!!!!!!!!!
allsel
!在0號坐標系下，對螺栓1(14號體積)建立預緊單元，secid為1,name為bolt1
!預緊單元方向為y軸，位置為y向0位置處，同時將預緊單元存儲於bolt_1單元組件中，預緊單元pretention179無需預先定義
psmesh,1,bolt1,,volu,14,0,y,0,,,,bolt_1
!!!!!!!!!!!!!螺栓預緊單元建立完畢!!!!!!!!!!!!!!!!!!
!!!!!!!!!!!!創建接觸!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
!創建凹面接觸單元
cmsel,s,flang_upvolu !選擇上法蘭體積組件
aslv !選擇依附於體上的面
asel,r,loc,y,0 !通過坐標選擇法蘭上的接觸面
cm,as_up,area !建立上法蘭接觸面組件as_up
allsel
cmsel,s,flang_dvolu !選擇下法蘭體積組件
aslv !選擇依附於體上的面
asel,r,loc,y,a-a1 !通過坐標選擇法蘭上的接觸面
asel,r,loc,x,0,D3/2
cm,as_down,area !建立下法蘭接觸面組件as_down
r,1 !定義接觸實常數1
real,1 !指定實常數1
mat,3 !指定材料3
cmsel,s,as_up !選擇上法蘭接觸面組件as_up
type,2 !指定單元接觸類型2
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
allsel
cmsel,s,as_down !選擇下法蘭接觸面組件as_down
type,3 !指定單元接觸類型3
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
!創建凸面接觸單元
allsel
cmsel,s,flang_upvolu !選擇上法蘭體積組件
aslv !選擇依附於體上的面
asel,r,loc,y,a !通過坐標選擇法蘭上的接觸面
cm,as_up1,area !建立上法蘭接觸面組件as_up1
allsel
cmsel,s,flang_dvolu !選擇下法蘭體積組件
aslv !選擇依附於體上的面
asel,r,loc,y,a !通過坐標選擇法蘭上的接觸面
cm,as_down1,area !建立下法蘭接觸面組件as_down1
et,5,TARGE170 !定義目標單元170
et,6,CONTA174 !定義接觸單元174
keyopt,6,9,0 !包含初始化穿透
r,2 !定義接觸實常數2
real,2 !指定實常數2
mat,3 !指定材料3
cmsel,s,as_up1 !選擇上法蘭接觸面組件as_up1
type,5 !指定單元接觸類型5
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
allsel
cmsel,s,as_down1 !選擇下法蘭接觸面組件as_down1
type,6 !指定單元接觸類型6
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
!創建螺母與上法蘭接觸
allsel
cmsel,s,bvolu !選擇螺栓體積組件
KWPAVE,77 !將工作平面移至77點
wprota,0,90 !將工作平面繞x軸旋轉90度
aslv !選擇依附於體上的面
asel,r,loc,z,0 !通過坐標選擇螺栓上的接觸面
asel,u,area,,104 !刪除螺栓柱面，保留螺母面
cm,b_up,area !創建螺母與上法蘭接觸面組件b_up
cmsel,s,flang_upvolu !選擇上法蘭體積組件
aslv !選擇依附於體上的面
asel,r,loc,z,0 !通過坐標選擇上法蘭上的目標面
asel,r,loc,x,-(D-D1)/2,(D-D1)/2
cm,f_up,area !創建上法蘭與螺母目標面組件f_up
cmsel,s,bvolu !選擇螺栓體積組件
aslv !選擇依附於體上的面
asel,r,loc,z,2*dta+a1 !通過坐標選擇螺栓與下法蘭的接觸面
asel,u,area,,108 !刪除螺栓柱面，保留螺母面
cm,b_down,area !創建螺母與下法蘭接觸面組件b_down
cmsel,s,flang_dvolu !選擇下法蘭體積組件
aslv !選擇依附於體上的面
asel,r,loc,z,2*dta+a1 !通過坐標選擇螺栓與下法蘭的目標面
asel,r,loc,x,-(D-D1)/2,(D-D1)/2
cm,f_down,area !創建螺母與下法蘭目標面組件f_down
et,7,TARGE170 !定義目標單元170
et,8,CONTA174 !定義接觸單元174
keyopt,8,9,0 !包含初始化穿透
r,3 !定義接觸實常數3
real,3 !指定實常數3
mat,3 !指定材料3
cmsel,s,b_up !選擇螺母與上法蘭接觸面組件b_up
type,7 !指定單元接觸類型7
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
allsel
cmsel,s,f_up !選擇上法蘭與螺母目標面組件f_up
type,8 !指定單元接觸類型8
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
!創建螺母與下法蘭接觸
et,9,TARGE170 !定義目標單元170
et,10,CONTA174 !定義接觸單元174
keyopt,10,9,0 !包含初始化穿透
r,4 !定義接觸實常數4
real,4 !指定實常數4
mat,3 !指定材料3
cmsel,s,b_down !選擇螺母與下法蘭接觸面組件b_down
type,9 !指定單元接觸類型9
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
allsel
cmsel,s,f_down !選擇螺母與下法蘭目標面組件f_down
type,10 !指定單元接觸類型10
nsla,s,1 !選擇接觸面上的所有節點，包括邊界點
esln,s,0 !選擇依附於這些節點的單元
esurf,all !構建接觸單元
!!!!!!!!!!!!接觸創建完畢!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
FINISH
/SOL !進入求解處理器
allsel
lsclear,all !清空所有載荷
NROPT,Full !激活完全Newton-Raphson
pred,on !打開變形預測
lnsrch,on !激活線性搜索
antype,0 !靜態分析
autots,1 !自動時間步長
nsubst,25,100,1 !設置載荷步
outres,all,all !輸出所有結果
eqslv,pcg,1e-8 !採用pcg演算法，對於大模型接觸演算法很有效
wpstyl,defa !將工作平面恢復至默認狀態
csys,5 !激活柱坐標系（以y軸為旋轉軸）
asel,s,loc,y,0 !通過坐標選擇角度為0的面
asel,a,loc,y,-N !通過坐標選擇角度為－N的面
da,all,symm !施加對稱邊界條件
csys,0 !激活笛卡爾坐標系
cmsel,s,flang_dvolu !選擇下法蘭體積組件
nslv,r,1 !選擇依附於體積上的節點
nsel,r,loc,y,a-a1-H-L !選擇筒體底端節點
d,all,uy !施加y向位移約束
allsel
sload,1,9,lock,forc,forc_bolt,1,2 !在螺栓中施加螺栓預緊
!第一載荷步中施載入荷大小為forc_bolt的預緊力，在第二個載荷步中鎖住其位移，最終產生預緊效果
time,10 !設置時間步長為10
allsel
lswrite,1 !寫出第一個載荷步文件
time,20 !設置時間步至20
lswrite,2 !寫出第二個載荷步文件
!對容器壁施加內壓
asel,s,area,,68 !選中編號為68的面
nsla,s,1 !選擇依附於面上的節點
csys,5 !激活柱坐標系（以y軸為旋轉軸）
nsel,a,loc,x,DN/2 !通過坐標選擇內壁上的節點
sf,all,pres,PN !對內壁施加壓強,大小為PN
allsel
time,30 !設置時間步至30
lswrite,3 !寫出第三個載荷步文件
lssolve,1,3,1 !計算載荷步1-3
/post1 !進入通用後處理
set,last !讀取最後結果
PLNSOL,S,EQV,0,1 !輸出Von Mises應力結果
cmsel,s,bvolu !選擇螺栓組件
eslv,s,1 !選中依附於體積的單元
nslv,s,1 !選中依附於體積的節點
PLNSOL,S,EQV,0,1 !輸出Von Mises應力結果
cmsel,s,flang_dvolu !選擇下法蘭組件
eslv,s,1 !選中依附於體積的單元
nslv,s,1 !選中依附於體積的節點
PLNSOL,S,EQV,0,1 !輸出Von Mises應力結果
❸ 向大俠請教：ansys，APDL命令：CMSEL,S,ZHULIANG 什麼意思
cmsel是選擇組命令。如題，cmsel,s,zhuliang的意思是選擇名字為zhuliang的組。zhuliang這個組一定是拆襪早在使用這個命令旅雀之前建立的組好橋。
❹ ansys中的mat和cmsel倆命令咋用
mat命令用於給告絕單元賦予屬性，通常是把前邊mp命令中定義的材料屬性賦予用E或EN直接建模的單元；
cmsel =components select用於選中辯猛前邊定義的組件。所謂組件，就是為了方便操作而定義的幾何襪灶姿集合或者有限元集合。
❺ 關於ANSYS cmsel命令的一點疑問（cmsel後跟s或者a到底是什麼意思）
CMSEL, Type, Name, Entity
Type
Label identifying the type of select:
S -- Select a new set (default).
R -- Reselect a set from the current set.
A -- Additionally select a set and extend the current set.
U -- Unselect a set from the current set.
ALL -- Also select all components.
NONE -- Unselect all components.
❻ ansys中的mat和cmsel倆命令咋用
舉例說明
mat，2 （早氏吵劃分網格前定義材料類型核冊為2）
cmsel，s，name defined by you，area （選陸侍擇面組）
❼ ANSYS命令流問題
這個只要你把不會的命令在幫助裡面查一下就行了吧。翻譯是沒用的
❽ ansys網格劃分命令流解釋
這段命令流可能是復制有誤,或者不完整.從這個命令來看,在劃分單元的時候是GUI操作,當同時選擇多個對象進行操作時,程序自己生成了組件,我認為剛剛學軟體時大可不必糾結這個問題吧,知道這么一過程就OK了.前面設置了ESIZE,4,是人為設定網格大小,後面又設置SMRT,1,這又讓程序自己智能劃分,沖突了,當然有警告,但是不影響網格劃分,暫時可以不用理會.但是整體來說,您這命令真有點亂,應該從簡單的模型開始練習,由簡單的開始比較好吧.部分命令解釋如下:
vsel,s,,,5 !選擇5號體
smrt,off !關閉程序智能劃分功能,即接下來通過人為設置單元尺寸
LESIZE,53,,,40 !53號線劃分成40份
lesize,58,,,40 !58號線劃分成40份
ESIZE,,4 !指定單元份數
MSHK,1 !似乎應該是MSHKEY,1,使用映射網格
MSHA,0,3D !指定單元為三維六面體形狀
VMESH,all !開始劃分
smrt,1 !打開自動劃分
vsel,s,,,6,7,1 !選擇6和7號體
MSHAPE,1,3D !指定單元為三維四面體形狀
MSHKEY,0 !自由劃分
vmesh,all !開始劃分
!below mesh
vsel,s,,,1,4,1 !選擇1,2,3,4號體
vmesh,all
SMRT,1
MSHAPE,1,3D
MSHKEY,0
!*
CM,_Y,VOLU !這個是程序自己生成的組件吧,體組件名_Y,包括1-4號體
VSEL, , , , 1,4,1
CM,_Y1,VOLU
CHKMSH,'VOLU'
CMSEL,S,_Y
!*
vsel,s,,,2 !似乎有誤,此時再選擇2號體,那前面的白選了
vmesh,all
vsel,s,,,9 !!!!!!似乎是操作不當,有誤
vlis
tCM,_Y,VOLU
VSEL, , , , 9 !以下是對9號體劃分
CM,_Y1,VOLU
CHKMSH,'VOLU'
CMSEL,S,_Y
!*
VMESH,_Y1
!*
CMDELE,_Y
CMDELE,_Y1
CMDELE,_Y2
!*
Alls
FINISH
❾ 幫忙翻譯一下ansys命令流
!以下命令是劃分網格時自動生成的命令流，現分句解釋如下：
TYPE, 1 !設置單元類型為1
MAT, 1!設置材料屬性為1
REAL, !設置實常數，默認
ESYS, 0 !設置單元坐標系為0
SECNUM, !設置截面編號，默認
!*
MSHAPE,0,3D !設置劃分單元類型，為3D，即體單元
MSHKEY,1!設置劃分網格方法，1為採用映射網格劃分方法
!*
FLST,5,2,6,ORDE,2 ! 以下8句為軟體自己生成的命令，作用是選擇被劃分的體並自定義組件
FITEM,5,1
FITEM,5,-2
CM,_Y,VOLU
VSEL, , , ,P51X
CM,_Y1,VOLU
CHKMSH,'VOLU'
CMSEL,S,_Y
!*
VMESH,_Y1 !劃分網格
!*
CMDELE,_Y !以下三句為刪除自定義的組件
CMDELE,_Y1
CMDELE,_Y2
!*
❿ 求大神幫忙翻譯一下ANSYS命令流
LSEL,S,TAN1,X！選擇所有與x軸垂直的線添加到新選擇集
LSEL,R,TAN2,Y !在現在的選擇集中（就剛才選的）重新選擇與y軸垂直的線，別的不要了
lplot !把選中的線繪制出來
LESIZE,ALL,0.05 ！ 剛才選得那些，設置線的單元尺寸為0.05
ALLSEL ! 相當於恢復默認了，全部選中
GPLOT ！ 全部繪制
LSEL，Type，Item，Comp，VMIN，VMAX，VINC，KSWP！額，這是lsel命令的參數，沒什麼要解釋得
lsel,s,loc,x,-0.05 !選擇受拉鋼筋，選擇方式為x軸坐標為-0.05的線
lsel,a,loc,x,-0.1 ！同上，舉一反三
lsel,r,loc,y,0.025
lplot
cm,lja,line !定義組件(將幾何元素分組加入組件即component方便後面選擇。CM, cname, entity（定義組元，將幾何元素分組形成組元）
cname: 由字母數字組成的組元名
entity: 組元的類型（volu, area, line, kp, elem, node））
latt,2,2,2 !定義屬性
lsel,s,loc,y,0.025 !選擇中間鋼筋
lsel,r,loc,x,0
cm,ljc,line
latt,2,3,2
lsel,all !選擇之前創建的所有組
cmsel,s,lja
cmsel,a,ljc
cm,gl,line
lmesh,all !為所有鋼筋劃分網格
/eshape,1
eplot
allsel
lsel,s,loc,z,0
lplot
lesize,all,0.025
vsel,s,loc,y,0,0.5
vplot
vatt,1,1,1 !為混凝土賦屬性
mshkey,1
vmesh,all