⑴ 請老師幫忙把（買入漲停指標）做成選股公式
A:=CLOSE/REF(CLOSE,3)>=1.1;
B:=BACKSET(A,3);
Q_3:=CROSS(EMA(C,19),EMA(C,7));
Q_4:=CROSS(EMA(C,7),EMA(C,19));
Z1:=L=LLV(L,BARSLAST(Q_3)+1);
Z2:=LLV(L,BARSLAST(Q_3)+1);
Z3:=H=HHV(H,BARSLAST(Q_4)+1);
Z4:=HHV(H,BARSLAST(Q_4)+1);
Q_A:=DRAWLINE(Z1,Z2,Z3,Z4,0);
Y1:=H=HHV(H,BARSLAST(Q_4)+1);
Y2:=HHV(H,BARSLAST(Q_4)+1);
Y3:=L=LLV(L,BARSLAST(Q_3)+1);
Y4:=LLV(L,BARSLAST(Q_3)+1);
Q_B:=DRAWLINE(Y1,Y2,Y3,Y4,0);
TJ:=IF(Q_B<REF(Q_B,1) AND Q_B=Q_A,1,0);
XG:(REF(TJ,1)=0 AND TJ>=1) OR (B AND COUNT(B,3)=1);
注意未來函數
⑵ 通達信技術指標公式改成選股公式如下，謝謝~
RSV:=(CLOSE - LLV(LOW,18))/(HHV(HIGH,18) - LLV(LOW,18))*100;
K:=EMA(RSV,3);
D:=EMA(K,3);
J:=(3*K-2*D);
火山:J<=0;
*********************************************
RSV:=(CLOSE - LLV(LOW,18))/(HHV(HIGH,18) - LLV(LOW,18))*100;
K:=EMA(RSV,3);
D:=EMA(K,3);
J:=(3*K-2*D);
KDJ1:=REF(COUNT(J<REF(J,1),5)>=3,1) AND REF(J,1)<20;
KDJ2:=J>REF(J,1);
反轉:FILTER(KDJ1 AND KDJ2,3);
⑶ 如何將技術指標修改成選股公式通達信
1、技術指標可以直接做為選股公式：功能——選股器——綜合選股——找到想用的指標。
2、如果想把技術指標公式修改為條件選股公式：右鍵技術指標公式——修改當前指標公式——復制完整公式（源碼）內容——打開公式編輯器——條件選股公式——新建——輸入公式名字——在主窗口粘貼技術指標公式源碼——修改多餘的公式輸出【因為選股公式只能有一個輸出】只保留選股需要的那項輸出（其餘輸出句的冒號「 ：」後面加個等號「 =」即可），最後保存就OK了。不明白之處歡迎追問，相互學習。
如果覺得對您有幫助，請記得採納答案，謝謝。
祝您投資愉快、股市好運。
⑷ 指標公式如何改寫成選股條件公式
【一品抄底】，是個副圖指標，既有線性輸出信號，也有買點提示信號，輸出類別眾多，就不是一個單獨的選股指標。如何修改、拆分出自己需要的【底部】選股信號，成為一個單獨的選股指標呢？如果還需要將【深坑】的信號，也單獨設置為選股指標，又該如何修改呢？在此先當做一個問題吧，繼續看了後面（二）、（三）小節的引路，相信你自己來就行了！
{一品抄底----創幻論壇一品茶緣編寫，通用副圖指標}
TYP := (HIGH + LOW + CLOSE)/3;
CCI:=(TYP-MA(TYP,14))/(0.015*AVEDEV(TYP,14));
A:=REF(C,1);
RSI:=SMA(MAX(C-A,0),6,1)/SMA(ABS(C-A),6,1)*100;
A1:=(C/MA(C,5)-1)*100<-10;
A2:=(C/MA(C,13)-1)*100<-10;
A3:=(C/MA(C,34)-1)*100<-15;
A4:=RSI<18;
A5:=CCI<-120;
A6:=COUNT(ABS(C/REF(C,1)-1)*100>=6,30)>=1;
底部:A1 AND A2 AND A3 AND A4 AND A5 AND A6,COLOR00FFFF,LINETHICK2;
CDSJ:=BARSLAST(底部);
ZF:=(C/REF(C,1)-1)*100;
深坑:IF(BETWEEN(CDSJ,0,5) AND L<=REF(C,CDSJ) AND ZF<=-5,-0.5,0),COLORFF0000,LINETHICK2;
機會:IF(CDSJ<=7 AND L<=REF(C,CDSJ),0.5,0),COLOR00FF00;
尋找選股信號的來源
所謂選股信號，多數都是屬於將已有的指標公式中具有買點類的信號特徵「剝離」出來。那麼，在指標中該保留哪些有用的源碼，刪除哪些無關的源碼呢？尋找選股信號的來源，就是最主要的過程。
尋找選股信號來源的方法，一般都是遵循從後往前尋找的原則。
具體步驟是：先找到發出指標信號的那行代碼，然後查看該行代碼中的所有條件，需要用到上面哪些源碼，再從後往前一一對應尋找出來；而其他無關的條件、修飾符號源碼，均可刪除。
舉例3：（本例子參考大慶老楊先生帖子，略有改動）
{股市馬經----副圖指標，源碼來自網路}
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A2:=(黑馬線-REF(黑馬線,1))/REF(黑馬線,1)*100;
A3:=EMA(C,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
A5:=(HHV(H,60)-C)/(HHV(H,60)-LLV(L,60))*100;
DRAWTEXT(FILTER(REF(黑馬線,1)>90 AND A2<0,7),黑馬線,'跑'),COLOR00FF00;
DRAWTEXT(CROSS(A1,黑馬線)AND 黑馬線<A5,黑馬線,'黑馬');
DRAWTEXT(CROSS(黑馬線,A5)AND 趨勢線<80,黑馬線,'追漲');
DRAWTEXT(CROSS(趨勢線,0)AND 黑馬線<40,5,'大黑馬');
底部:(A2<-10 AND A2>REF(A2,1))*25,colorred;
DRAWICON(底部 AND A3>REF(A3,1),25,4);
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1),COLORF00FF0;
大勢已去:IF(CROSS(黑馬線,A1)AND 黑馬線>70 AND 趨勢線>80,90,100),COLORFF0000;
公式中涉及「買」的信號有黑馬、追漲、大黑馬、底部和機會來臨五個明顯的，另外還有一個畫圖標信號。
假如我們提取其中的【機會來臨】，仔細分析後，就是一句話：
機會來臨:REF(IF((MA(C,5)-C)/C>0.04 AND (MA(C,10)-MA(C,5))/MA(C,5)>0.04,30,0),1);
這個可看作簡單提取。
如果提取【大黑馬】的話，從後向前推，涉及趨勢線和黑馬線兩個定義，這部分都有用：
A1:3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:EMA(A1,5),LINETHICK2,COLOR6600FF;
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2)),LINETHICK2,coloryellow;
DRAWTEXT(CROSS(趨勢線,0) AND 黑馬線<40,5,'大黑馬');
（三）修改選股指標的方法
根據以上選股公式的特徵，結合尋找選股信號來源的方法，自己動手修改選股信號，應該就沒有太大的難度了！
舉例4：繼續承接上面（二）的例子。
修改步驟：
①先將線性輸出的A1、黑馬線、A4、趨勢線均限制輸出，方法很簡單，就是在他們的冒號後面直接加上等號=；
②再刪去修飾符LINETHICK2,COLOR6600FF：
③將本來是文字輸出的「黑馬線」修改成信號輸出；先將「黑馬線」三個字移動到最前面，並加上冒號：；然後保留符合黑馬線的限制條件CROSS(趨勢線,0) AND 黑馬線<40；同時刪除其餘無關的代碼，包括文字輸出函數DRAWTEXT、位置、括弧（）等。
修改成選股指標後的源碼如下：
A1:=3*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1)-2*SMA((C-LLV(L,55))/(HHV(H,55)-LLV(L,55))*100,5,1);
黑馬線:=EMA(A1,5);
A4:=((C-LLV(L,21))/(HHV(H,21)-LLV(L,21)))*100;
趨勢線:=(MA(3*SMA(A4,6,1)-2*SMA(SMA(A4,5,1),5,1),2));
大黑馬:CROSS(趨勢線,0) AND 黑馬線<40;
舉例5：
下面附圖指標【大三浪】中，如何選出出現「買」字提示信號的選股指標？
{大三浪----創幻論壇一品茶緣編寫，通用副圖指標}
{大三浪指標使用說明:
均線粘合且多頭,長期未漲庄吸籌;
目標鎖定先跟蹤,出擊買入等豐收!}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
多頭粘合:IF(多頭 AND 粘合,1,0),COLORFF00FF,POINTDOT,LINETHICK0;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
跟蹤:IF(目標,BARSLAST(CROSS(目標,0))+1,0),COLOR00FF00,POINTDOT,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
MJSJ:=BARSLAST(出擊>0);
漲幅:IF(MJSJ<=120,(C/REF(C,MJSJ)-1)*100,0),COLOR0000FF,POINTDOT,LINETHICK0;
日漲:IF(MJSJ<=120,漲幅/MJSJ,0),COLORFFFFFF,POINTDOT,LINETHICK0;
TPX:=MIN(MA65*1.15,MA21*1.13);
突破:IF(CROSS(C,TPX) AND 粘合 AND MA65>REF(MA65,1),10,0),COLOR0000FF,LINETHICK2;
{以下設置副圖顯示方式}
STICKLINE(多頭粘合,0,1,8,0),COLORFF00FF;
STICKLINE(庄股,0,MACD*10,8,0),COLORFFFF00;
DRAWTEXT(出擊=8,10,'★買'),COLOR00FFFF;
VERTLINE(CROSS(漲幅,20) AND COUNT(CROSS(漲幅,20),MJSJ)=1,2),COLOR0000FF; 根據選股指標的步驟，一步一步來：
①首先找到出現「★買」提示的一行代碼，發現她其實就是「出擊」的信號；
②從後往前，找到「出擊」信號的條件，發現他與「目標」、MACD有關；
再次往前尋找，又發現「目標」信號的條件，與「多頭」、「粘合」、「庄股」三個條件有關，由此，保留相關條件代碼，其餘刪除，如下：
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:COUNT(MACD<0,10)=10,COLORFFFF00,POINTDOT,LINETHICK0;
目標:IF(多頭 AND 粘合 AND 庄股,5,0),COLORFFFFFF,LINETHICK2;
出擊:IF(CROSS(0.1,目標) AND CROSS(MACD,0),8,0),COLOR00FFFF,LINETHICK2;
③限制輸出數量，只保留「出擊」信號的輸出，其他的輸出信號均加上等號=加以限制輸出；
④刪除多餘的修飾符號，如：COLORFFFF00,POINTDOT,LINETHICK0等。
⑤IF格式也可簡化，只保留需要的條件，輸出信號自動為1。「出擊」兩字也可修改為「買」。
修改完最後保留的源碼如下：
{大三浪----選股指標}
{N:30,120,65;}
MA5:=MA(CLOSE,5);
MA21:=MA(CLOSE,21);
MA65:=MA(CLOSE,N);
多頭:=COUNT(MA21>MA65,10)=10;
GX:=MAX(MA5,MAX(MA21,MA65));
DX:=MIN(MA5,MIN(MA21,MA65));
粘合:=ABS(GX/DX-1)*100<=15;
DIFF:=EMA(CLOSE,12) - EMA(CLOSE,26);
DEA:=EMA(DIFF,9);
MACD:=2*(DIFF-DEA);
庄股:=COUNT(MACD<0,10)=10;
目標:=IF(多頭 AND 粘合 AND 庄股,5,0);
買:CROSS(0.1,目標) AND CROSS(MACD,0); 導入選股指標的途徑
①修改完後的選股指標源碼，想做成選股指標，並非放在指標系統之下的【技術指標】分類，一般是放入【條件選股】分類；便於設置預警、自動選股。
②還可將選股指標加入交易系統中，但需要注意的是：輸出信號必須為英文單詞的買入ENTERLONG、賣出EXITLONG信號。在應用時，飛狐軟體輸入該交易系統指標名稱，即可在主圖自動顯示買賣信號的提示。
源碼如下：
ENTERLONG:CROSS(MA(C,3),MA(C,8));----表示輸出多頭買入信號。
EXITLONG:CROSS(MA(C,8),MA(C,3));----表示輸出空頭賣出信號。
⑸ 請高手幫我把通達信技術指標公式改成選股公式，謝謝
VAR2:=(((CLOSE - MA(CLOSE,6)) / MA(CLOSE,6)) * 100);
VAR3:=(((CLOSE - MA(CLOSE,12)) / MA(CLOSE,12)) * 100);
VAR4:=(((CLOSE - MA(CLOSE,24)) / MA(CLOSE,24)) * 100);
VAR5:=(((VAR2 + (2 * VAR3)) + (3 * VAR4)) / 6);
VAR6:=MA(VAR5,3);
VAR1:=EMA(EMA(CLOSE,3),1);
控盤:=(VAR1-REF(VAR1,1))/REF(VAR1,1)*1000;
VAR6 <= - 10 AND 控盤>-20;