單片機搶答器

『壹』 用51單片機做搶答器需要賣什麼東西

先使用proteus和uvision軟體設計好電路圖再進行模擬驗證，然後按照電路圖需要元件組裝出來PCB電路板，再使用燒錄器把程序燒錄進單片機去就可以了！

『貳』 基於單片機的電子搶答器會出現哪些常見問題，並如何解決。

主要就是對選手按鍵的時間先後，鑒別力不夠。

單片機速度太低，通常要隔十幾個微秒，才檢測一次按鍵，此期間，雖然有選手_先_後_按_鍵_，但是單片機卻是同時讀取，然後按照內定的程序報出一個選手的號碼。明顯有失公平。

如果使用電子電路構成搶答電路，可以將鑒別時間控制在納秒的級別。

『叄』 急求最簡單的單片機4人搶答器c51程序

;以下是以前做的八路搶答器程序，你參考一下。
ORG 0000H
JMP BEGIN
ORG 0030H
TABLE: ; 共陰極數碼管顯示代碼表
DB 3FH,06H,5BH,4FH,66H ;12345
DB 6DH,7DH,07H,7FH ;6789
DELAY: MOV R5,#20
LOOP4: MOV R6,#50H ;延時20X20ms
LOOP5: MOV R7,#100
DJNZ R7,$
DJNZ R6,LOOP5
DJNZ R5,LOOP4
RET
;---------------------------------------
BEGIN: MOV P2,#0FFH ;P2口置高電平，准備接收信號
MOV R4,#0
MOV A,R4 ;R4位標志值送A寄存器
AGAIN: MOV DPTR,#TABLE
MOVC A,@A+DPTR
MOV P1,A
LOOP1: MOV A,P3 ; 接收p3口的搶答信號
CPL A
JZ LOOP1
LOOP2: RRC A ;有人搶答信號則逐次移動判斷哪一位搶答
INC R4
JNC LOOP2
;********************
MOV A,R4
MOVC A,@A+DPTR ;找到相應位顯示代碼
MOV P1,A
LEDDIS:
MOV A,#0FFH
CLR C
LEDDIS1:
RLC A
DJNZ R4,LEDDIS1
MOV P0,A
LOOP3: JNB P2.2,BEGIN ;若主持人按下復位信號鍵，則轉向主程序
CPL P2.0 ;若沒按復位信號鍵，則通過p2.2口給出高低信號驅動蜂鳴器
LCALL DELAY ;調用延時子程序
SJMP LOOP3 ;p2.2口反復間隔0.4s變化，驅動蜂鳴器
END

『肆』 單片機八路搶答器程序

OK EQU 20H;搶答開始標志位
RING EQU 22H;響鈴標志位
ORG 0000H
AJMP MAIN
ORG 0003H
AJMP INT0SUB
ORG 000BH
AJMP T0INT
ORG 0013H
AJMP INT1SUB
ORG 001BH
AJMP T1INT
ORG 0040H
MAIN: MOV R1,#30;初設搶答時間為30s
MOV R2,#60;初設答題時間為60s
MOV TMOD,#11H;設置未定時器/模式1
MOV TH0,#0F0H
MOV TL0,#0FFH;越高發聲頻率越高,越尖
MOV TH1,#3CH
MOV TL1,#0B0H;50ms為一次溢出中斷
SETB EA
SETB ET0
SETB ET1
SETB EX0
SETB EX1;允許四個中斷,T0/T1/INT0/INT1
CLR OK
CLR RING
SETB TR1
SETB TR0;一開始就運行定時器,以開始顯示FFF.如果想重新計數,重置TH1/TL1就可以了
;=====查詢程序=====
START: MOV R5,#0BH
MOV R4,#0BH
MOV R3,#0BH
ACALL DISPLAY;未開始搶答時候顯示FFF
JB P3.0,NEXT;ddddddd
ACALL DELAY
JB P3.0,NEXT;去抖動,如果"開始鍵"按下就向下執行,否者跳到非法搶答查詢
ACALL BARK;按鍵發聲
MOV A,R1
MOV R6,A;送R1->R6,因為R1中保存了搶答時間
SETB OK;搶答標志位,用於COUNT只程序中判斷是否查詢搶答
MOV R7,#01H ;讀搶答鍵數據信號標志，這里表示只讀一次有用信號
MOV R3,#0AH;搶答只顯示計時,滅號數
AJMP COUNT;進入倒計時程序,"查詢有效搶答的程序"在COUNT裡面
NEXT: JNB P1.0,FALSE1
JNB P1.1,FALSE2
JNB P1.2,FALSE3
JNB P1.3,FALSE4
JNB P1.4,FALSE5
JNB P1.5,FALSE6
JNB P1.6,FALSE7
JNB P1.7,FALSE8
AJMP START
;=====非法搶答處理程序=====
FALSE1: MOV R3,#01H
AJMP ERROR
FALSE2: MOV R3,#02H
AJMP ERROR
FALSE3: MOV R3,#03H
AJMP ERROR
FALSE4: MOV R3,#04H
AJMP ERROR
FALSE5: MOV R3,#05H
AJMP ERROR
FALSE6: MOV R3,#06H
AJMP ERROR
FALSE7: MOV R3,#07H
AJMP ERROR
FALSE8: MOV R3,#08H
AJMP ERROR

;=====INT0(搶答時間R1調整程序)=====
INT0SUB:MOV A,R1
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY;先在兩個時間LED上顯示R1
JNB P3.4,INC0;P3.4為+1s鍵,如按下跳到INCO
JNB P3.5,DEC0;P3.5為-1s鍵,如按下跳到DECO
JNB P3.1,BACK0;P3.1為確定鍵,如按下跳到BACKO
AJMP INT0SUB
INC0: MOV A,R1
CJNE A,#63H,ADD0;如果不是99,R2加1,如果加到99,R1就置0，重新加起。
MOV R1,#00H
ACALL DELAY1
AJMP INT0SUB
ADD0: INC R1
ACALL DELAY1
AJMP INT0SUB
DEC0: MOV A,R1
JZ SETR1;如果R1為0, R1就置99，
DEC R1
ACALL DELAY1
AJMP INT0SUB
SETR1: MOV R1,#63H
ACALL DELAY1
AJMP INT0SUB
BACK0: RETI
;=====INT1(回答時間R2調整程序)=====
INT1SUB:MOV A,R2
MOV B,#0AH
DIV AB
MOV R5,A
MOV R4,B
MOV R3,#0AH
ACALL DISPLAY
JNB P3.4,INC1
JNB P3.5,DEC1
JNB P3.1,BACK1
AJMP INT1SUB
INC1: MOV A,R2
CJNE A,#63H,ADD1
MOV R2,#00H
ACALL DELAY1
AJMP INT1SUB
ADD1: INC R2
ACALL DELAY1
AJMP INT1SUB
DEC1: MOV A,R2
JZ SETR2
DEC R2
ACALL DELAY1
AJMP INT1SUB
SETR2: MOV R2,#63H
ACALL DELAY1
AJMP INT1SUB
BACK1: RETI
;=====倒計時程序(搶答倒計時和回答倒計時都跳到改程序)=====
REPEAT:MOV A,R2 ;使用錦囊時重新計時
MOV R6,A
CLR RING
COUNT: MOV R0,#00H;重置定時器中斷次數
MOV TH1,#3CH
MOV TL1,#0B0H;重置定時器
RECOUNT:MOV A,R6;R6保存了倒計時的時間,之前先將搶答時間或回答時間給R6
MOV B,#0AH
DIV AB;除十分出個位/十位
MOV 30H,A;十位存於(30H)
MOV 31H,B;個位存於(31H)
MOV R5,30H;取十位
MOV R4,31H;取個位
MOV A,R6
SUBB A,#07H
JNC LARGER;大於5s跳到LARGER,小於等於5s會提醒
MOV A,R0
CJNE A,#0AH,FULL;1s中0.5s向下運行
CLR RING
AJMP CHECK
FULL: CJNE A,#14H,CHECK;下面是1s的情況,響並顯示號數並清R0,重新計
SETB RING
MOV A,R6
JZ QUIT;計時完畢
MOV R0,#00H
DEC R6;一秒標志減1
AJMP CHECK
LARGER: MOV A,R0
CJNE A,#14H,CHECK;如果1s向下運行,否者跳到查"停/顯示"
DEC R6;計時一秒R6自動減1
MOV R0,#00H
CHECK: JNB P3.1,QUIT;如按下停止鍵退出
JNB OK,CHECKK ;只在回答倒計時才有效
AJMP NEXTT
CHECKK:JNB P3.0,REPEAT ;判斷是否使用錦囊
NEXTT: ACALL DISPLAY
JB OK,ACCOUT;如果是搶答倒計時,如是則查詢搶答,否者跳過查詢繼續倒數(這里起到鎖搶答作用)
AJMP RECOUNT
ACCOUT:
MOV A,36H
JNB ACC.0,TRUE1
JNB ACC.1,TRUE2
JNB ACC.2,TRUE3
JNB ACC.3,TRUE4
JNB ACC.4,TRUE5
JNB ACC.5,TRUE6
JNB ACC.6,TZ1
JNB ACC.7,TZ2
AJMP RECOUNT
TZ1:JMP TRUE7
TZ2:JMP TRUE8
QUIT: CLR OK;如果按下了"停止鍵"執行的程序
CLR RING
AJMP START
;=====正常搶答處理程序=====
TRUE1: ACALL BARK
MOV A,R2
MOV R6,A;搶答時間R2送R6
MOV R3,#01H
CLR OK;因為答題的計時不再查詢搶答,所以就鎖了搶答
AJMP COUNT
TRUE2:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#02H
CLR OK
AJMP COUNT
TRUE3:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#03H
CLR OK
AJMP COUNT
TRUE4:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#04H
CLR OK
AJMP COUNT
TRUE5:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#05H
CLR OK
AJMP COUNT
TRUE6: ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#06H
CLR OK
AJMP COUNT
TRUE7:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#07H
CLR OK
AJMP COUNT
TRUE8:ACALL BARK
MOV A,R2
MOV R6,A
MOV R3,#08H
CLR OK
AJMP COUNT
;=====犯規搶答程序=====
ERROR: MOV R0,#00H
MOV TH1,#3CH
MOV TL1,#0B0H
MOV 34H,R3;犯規號數暫存與(34H)
HERE: MOV A,R0
CJNE A,#06H,FLASH;0.3s向下運行->滅並停響
CLR RING
MOV R3,#0AH
MOV R4,#0AH
MOV R5,#0AH;三燈全滅
AJMP CHECK1
FLASH: CJNE A,#0CH,CHECK1;下面是0.8s的情況,響並顯示號數並清R0,重新計
SETB RING
MOV R0,#00H
MOV R3,34H;取回號數
MOV R5,#0BH
MOV R4,#0BH;顯示FF和號數
AJMP CHECK1
CHECK1: JNB P3.1,QUIT1
ACALL DISPLAY
AJMP HERE
QUIT1: CLR RING
CLR OK
AJMP START
;=====顯示程序=====
DISPLAY:MOV DPTR,#DAT1;查表顯示程序,利用P0口做段選碼口輸出/P2低三位做位選碼輸出,
MOV A,R3
MOVC A,@A+DPTR
MOV P2,#0feH
MOV P0,A
ACALL DELAY2
MOV DPTR,#DAT2
MOV A,R5
MOVC A,@A+DPTR
MOV P2,#0fdH
MOV P0,A
ACALL DELAY2
MOV A,R4
MOVC A,@A+DPTR
MOV P2,#0fbH
MOV P0,A
ACALL DELAY2
RET
DAT1:DB 00h,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H
;"滅","1","2","3","4","5","6","7","8","9","滅","F"
DAT2:DB 3fh,06h,5bh,4fh,66h,6dh,7dh,07h,7fh,6fh,00H,71H
;第一個為零,其他與上相同,因為十位如果為零顯示熄滅
;====加減時間延時(起到不會按下就加N個數)======
DELAY1: MOV 35H,#08H
LOOP0: ACALL DISPLAY
DJNZ 35H,LOOP0
RET
;=====延時4236個機器周期(去抖動用到)=====
DELAY: MOV 32H,#12H
LOOP: MOV 33H,#0AFH
LOOP1: DJNZ 33H,LOOP1
DJNZ 32H,LOOP
RET
;=====延時4236個機器周期(顯示用到)=====
DELAY2: MOV 32H,#43H
LOOP3: MOV 33H,#1EH
MOV A,R7 ;每隔60~70個機器周期讀一次P1口,全為1時為無效數據,繼續讀,有一個不為1時,轉到正常搶答處理
JNZ AAAA1 ;沒讀到有效數據時繼續轉到AAAA1
LOOP2: DJNZ 33H,LOOP2
DJNZ 32H,LOOP3
RET
;=====讀搶答按鍵數據口程序=====
;由於在讀搶答數據口的時候，單片機首先進入倒計時程序，再調用顯示程序，最後才檢測按鍵口
;然而在檢測按鍵口時動態掃描要調用三次(4ms)延時程序.這樣就會導致讀數據口出現滯後,造成1號優先最高.8號最低.
;故採用在延時子程序中加了讀數據口程序.保證了靈敏度和可靠性
AAAA1: MOV A,P1
CJNE A,#0FFH,AA1 ;當不全為1時的數據為有效數據
AA0: MOV 36H,A ;將有效數據送到36H暫存
AJMP LOOP2
AA1: DEC R7
AJMP AA0

;=====發聲程序=====
BARK: SETB RING
ACALL DELAY1
ACALL DELAY1
CLR RING;按鍵發聲
RET
;=====TO溢出中斷(響鈴程序)=====
T0INT: MOV TH0,#0ECH
MOV TL0,#0FFH
JNB RING,OUT;
CPL P3.6;RING標志位為1時候P3.6口不短取反使喇叭發出一定頻率的聲音
OUT: RETI
;=====T1溢出中斷(計時程序)=====
T1INT: MOV TH1,#3CH
MOV TL1,#0B0H
INC R0
RETI
END

『伍』 求大神做一個51單片機的四路搶答器，要匯編程序，電路圖，和分析過程,還有4天答辯，

有一個八路的發給你吧，供參考

ORG 0000H

JMP BEGIN

ORG0030H

TABLE: ;共陰極數碼管顯示代碼表

DB 3FH,06H,5BH,4FH,66H;12345

DB 6DH,7DH,07H,7FH ;6789

DELAY: MOV R5,#20

LOOP4: MOV R6,#50H ;延時20X20ms

LOOP5: MOV R7,#100

DJNZ R7,$

DJNZ R6,LOOP5

DJNZ R5,LOOP4

RET

;---------------------------------------

BEGIN: MOV P2,#0FFH ;P2口置高電平，准備接收信號

MOV R4,#0

MOV A,R4 ;R4位標志值送A寄存器

AGAIN: MOV DPTR,#TABLE

MOVC A,@A+DPTR

MOV P1,A

LOOP1: MOV A,P3 ;接收p3口的搶答信號

CPL A

JZ LOOP1

LOOP2: RRC A ;有人搶答信號則逐次移動判斷哪一位搶答

INC R4

JNC LOOP2

;********************

MOV A,R4

MOVC A,@A+DPTR ;找到相應位顯示代碼

MOV P1,A

LEDDIS:

MOVA,#0FFH

CLRC

LEDDIS1:

RLCA

DJNZR4,LEDDIS1

MOVP0,A

LOOP3: JNBP2.2,BEGIN;若主持人按下復位信號鍵，則轉向主程序

CPL P2.0 ;若沒按復位信號鍵，則通過p2.2口給出高低信號驅動蜂鳴器

LCALLDELAY ;調用延時子程序

SJMP LOOP3 ;p2.2口反復間隔0.4s變化，驅動蜂鳴器

END

『陸』 單片機八人搶答器程序設計

;------------------------------------------
KAI BIT P3.7 ;開始
;------------------------------------------
ORG 0000H
JMP START
START:
;----------------------;下面是清零(復位)
MOV P0, #0C0H ;顯示0
MOV P2, #255 ;熄燈
MOV R4, #0
;----------------------;下面等待按下"開始"鍵
KAISHI:
JB KAI, KAISHI ;沒有按"開始"，就循環
CALL DELAY ;延時
JB KAI, KAISHI ;消抖
JNB KAI, $ ;等待釋放
;----------------------
MOV P0, #0CH ;顯示P
WAIT: ;等待搶答
MOV A, P1
CPL A
JZ WAIT ;繼續等待
;----------------------
XS: ;查找選手按鍵的位置
CPL A
MOV P2, A
JNB ACC.0, J0
JNB ACC.1, J1
JNB ACC.2, J2
JNB ACC.3, J3
JNB ACC.4, J4
JNB ACC.5, J5
JNB ACC.6, J6
; JMP J7
J7: INC R4
J6: INC R4
J5: INC R4
J4: INC R4
J3: INC R4
J2: INC R4
J1: INC R4
J0: INC R4
MOV A, R4
MOV DPTR, #D_TAB
MOVC A, @A + DPTR
MOV P0, A
;----------------------;下面等待按下復位鍵
W_FW:
JB KAI, W_FW ;沒有按，則轉
CALL DELAY ;延時
JB KAI, W_FW ;消抖
JNB KAI, $ ;等待釋放
JMP START
;------------------------
D_TAB:
DB 0C0H,0F9H,0A4H,0B0H, 99H ;共陽極0-9
DB 92H, 82H,0F8H, 80H, 90H,0BFH ;-
;------------------------------------------
DELAY: ;延時約10ms
MOV R6, #20
DJNZ R7, $
DJNZ R6, $ - 2
RET
;==========================================
END

;以上程序已經調好。

『柒』 單片機C51搶答器的原理圖和程序 萬分感謝 急！SOS

#include <reg52.h>
#define uchar unsigned char
#define uint unsigned int
///數碼管位選管腳定義
#define wei P0
///數碼管段選管腳定義
#define an P2
///短延時時間宏定義
#define short_delay 1
///搶答開始標志位
#define start 0
#define not_start 1
///八組參賽者搶答按鍵
#define key0 P1^0
#define key1 P1^1
#define key2 P1^2
#define key3 P1^3
#define key4 P1^4
#define key5 P1^5
#define key6 P1^6
#define key7 P1^7
///主持人加分鍵
#define key8 P3^6
///主持人搶答開始按鍵
#define key9 P3^7
///主持人數碼管位選管腳定義
sbit zhuchi_dis1=P3^0;
sbit zhuchi_dis2=P3^1;
///蜂鳴器輸出管腳定義
sbit ring=P3^4;
uchar cnt=20;
uchar person=0;//主持台前搶答者編號顯示
///數碼管位碼表
uchar wei_dis[]={0x00,0x01,0x02,0x03,0x04,0x05,0x06,0x07,0x08,0x09,0x0a,0x0b,0x0c,0x0d,0x0e,0x0f};
///數碼管斷碼表
uchar table[]={
0x3f,0x06,0x5b,0x4f,
0x66,0x6d,0x7d,0x07,
0x7f,0x6f,0x40
};
volatile uchar fenshu1,fenshu2,fenshu3,fenshu4,fenshu5,fenshu6,fenshu7,fenshu8;//八組成員分數緩沖寄存器
uchar jishi_flag=1; //倒計時標志位
uchar start_flag=not_start;//開始搶答標志位
///*********************蜂鳴器初始化****************************///
void ring_init()
{
ring=0;
}
///*********************記分牌分數初始化****************************///
void init_fenshu()
{
fenshu1=0;
fenshu2=0;
fenshu3=0;
fenshu4=0;
fenshu5=0;
fenshu6=0;
fenshu7=0;
fenshu8=0;
}
///*********************定時器0初始化****************************///
void timer0_init()
{
TMOD=0x01;
TH0=(65535-50000)/256;
TL0=(65535-50000)%256;
ET0=1;//開定時器0中斷
//TR0=1;//定時器0開始計數
}
///*********************外部中斷0初始化****************************///
void int0_init()
{
EX0=1;//外部中斷0使能
IT0=0;//負邊沿觸發方式
EA=1; //總中斷使能
}
///*********************外部中斷1初始化****************************///
void int1_init()
{
EX1=1;//外部中斷0使能
IT1=0;//負邊沿觸發方式
EA=1; //總中斷使能
}
///*********************設備初始化****************************///
void int_device()
{
timer0_init();
int0_init();
int1_init();
init_fenshu();
ring_init();
}

///*********************延時子函數****************************///
void delay(uint z)
{
uint x,y;
for(x=z;x>0;x--)
for(y=110;y>0;y--);
}

///*********************數碼管顯示子函數****************************///
void led_display(uchar z)
{
///*********************主持人****************************///
zhuchi_dis1=0;
an=table[z/10];
delay(short_delay);
zhuchi_dis1=1;

zhuchi_dis2=0;
an=table[z%10];
delay(short_delay);
zhuchi_dis2=1;

///*********************第一組****************************///
wei=wei_dis[0];
an=table[fenshu1/10];
delay(short_delay);
wei=wei_dis[1];
an=table[fenshu1%10];
delay(short_delay);
///*********************第二組****************************///
wei=wei_dis[2];
an=table[fenshu2/10];
delay(short_delay);
wei=wei_dis[3];
an=table[fenshu2%10];
delay(short_delay);
///*********************第三組****************************///
wei=wei_dis[4];
an=table[fenshu3/10];
delay(short_delay);
wei=wei_dis[5];
an=table[fenshu3%10];
delay(short_delay);
///*********************第四組****************************///
wei=wei_dis[6];
an=table[fenshu4/10];
delay(short_delay);
wei=wei_dis[7];
an=table[fenshu4%10];
delay(short_delay);
///*********************第五組****************************///
wei=wei_dis[8];
an=table[fenshu5/10];
delay(short_delay);
wei=wei_dis[9];
an=table[fenshu5%10];
delay(short_delay);
///*********************第六組****************************///
wei=wei_dis[10];
an=table[fenshu6/10];
delay(short_delay);
wei=wei_dis[11];
an=table[fenshu6%10];
delay(short_delay);
///*********************第七組****************************///
wei=wei_dis[12];
an=table[fenshu7/10];
delay(short_delay);
wei=wei_dis[13];
an=table[fenshu7%10];
delay(short_delay);
///*********************第八組****************************///
wei=wei_dis[14];
an=table[fenshu8/10];
delay(short_delay);

wei=wei_dis[15];
an=table[fenshu8%10];
delay(5);
}

///*********************主函數****************************///
void main()
{
//fenshu1=12;
uchar second=15;
int_device();
while(1)
{

if(start_flag==start)
TR0=1;
else
TR0=0;

if(jishi_flag)
{
if(cnt==0) //定時已達到一秒
{
cnt=20;
second--;
if(second<=0)
{
jishi_flag=0;
second=0;
}
}
led_display(second);
}
else
led_display(person);
}
}
///*********************外部中斷0服務子函數****************************///
void int0() interrupt 0
{
if( start_flag==not_start)
ring=1;
if(start_flag==start)
ring=0;
switch(P1)
{
case 0xfe: {person=1;jishi_flag=0;} break;
case 0xfd: {person=2;jishi_flag=0;} break;
case 0xfb: {person=3;jishi_flag=0;} break;
case 0xf7: {person=4;jishi_flag=0;} break;
case 0xef: {person=5;jishi_flag=0;} break;
case 0xdf: {person=6;jishi_flag=0;} break;
case 0xbf: {person=7;jishi_flag=0;} break;
case 0x7f: {person=8;jishi_flag=0;} break;
//case 0xfd: person=2; break;
}

}
///*********************外部中斷1服務子函數****************************///
void int1() interrupt 2
{
if(key8==0)
{
delay(300);
switch(person)
{
case 1:{fenshu1+=5;if(fenshu1>=99) fenshu1=0;}break;
case 2:{fenshu2+=5;if(fenshu2>=99) fenshu2=0;}break;
case 3:{fenshu3+=5;if(fenshu3>=99) fenshu3=0;}break;
case 4:{fenshu4+=5;if(fenshu4>=99) fenshu4=0;}break;
case 5:{fenshu5+=5;if(fenshu5>=99) fenshu5=0;}break;
case 6:{fenshu6+=5;if(fenshu6>=99) fenshu6=0;}break;
case 7:{fenshu7+=5;if(fenshu7>=99) fenshu7=0;}break;
case 8:{fenshu8+=5;if(fenshu8>=99) fenshu8=0;}break;
}
}

if(key9==0)
{
start_flag=start;
}

}
///*********************定時器0中斷服務子函數****************************///
void timer0() interrupt 1
{
TH0=(65535-50000)/256;
TL0=(65535-50000)%256;
cnt--;
}

『捌』 單片機搶答器的的缺陷

單片機運行cpu資源是唯一的的，如果將搶答響應設定成中斷形式，那麼如果兩人同時按搶答器，這是單片機不能正確判斷出誰先按了搶答器。

『玖』 搶答器所用單片機原型是什麼

「搶答器」實際上就是一種簡單的邏輯電路，可以通過應用現成的單片機通過編寫程序簡單實現而已。

『拾』 用單片機設計一個8位競賽搶答器程序怎麼寫

我有這個程序，需要不？，現成的，