單片機紅綠燈實驗

⑴ 51單片機交通燈紅燈綠燈19秒黃燈閃爍三秒

51單片機交通燈紅燈綠燈19秒黃燈閃爍三秒可以採用4行4列的矩陣開關顯示。用單片機做一交通信號燈控制裝置，要求A東西綠燈亮5秒後閃2秒熄滅，黃燈閃2秒後熄滅，紅燈亮9秒，B南北綠燈亮5秒後閃2秒熄滅，黃燈閃2秒後熄滅，紅燈亮9秒C循環10個開關，2個控制交通燈，共輸出3種狀態紅、綠、黃、全滅。其中全滅開關狀態為00，黃燈開關狀態為01，綠燈開關狀態為10，紅燈狀態為11.8個開關控制兩位數碼管，數碼管採用7段數碼管，2位數碼管共14段顯示。可以採用4行4列的矩陣開關顯示。這樣正好需要8個開關。每個數碼管可顯示0-9.例如交通燈規律是綠燈40秒，閃爍4秒(也就是綠燈和全滅間隔顯示)，黃燈3秒，紅燈20秒。

⑵ 用51單片機製作紅綠燈，要求按鍵能控制整個電路的啟動和停止，用匯編語言怎麼編寫程序

交通路口紅綠燈自動控制器電路圖 如圖所示為交通路口紅綠燈自動控制電路。該控制器主要由四塊555(IC2～IC5)和一些阻容元件組成的四級單穩態延時電路首尾相連而成。輸入的8V電壓經78M05穩壓後為555提供VDD=+5V的電源電壓。 當剛接通電源時，觸發脈沖經IC1(CD4011)門電路和R1、C1延時，再經C2、R22微分後加到IC2②腳，觸發IC2輸出高電平，進入暫穩態，其暫穩態定時時間長短取決於K1的位置，延時td=1.1RC6，設定時間分別為60秒、45秒、30秒。暫穩態結束時，IC2③腳為低電平，其經C3、R23微分後，下降沿又觸發IC3，形成第二級單穩態延時。如此依次觸發定時，完成綠色燈亮-黃色燈亮(8秒、10秒、12秒)-紅色燈亮(60秒、45秒、30秒)的循環周期。 本控制器通過四級電路首尾相接，依次延時觸發，使交通燈依次出現綠-黃-紅(色)信號，指揮行人和車輛在十字路I=1有秩序地通行(綠)-提醒注意(黃)-禁止通行(紅)。 看看這個有用嗎？

⑶ 單片機中斷實驗交通燈的實驗原理

根據圖3.2電路，用單片機的IO口控制4組紅綠黃共12個發光二極體，使發光二極體按照一定規則與次序發光與閃亮以實現模擬交通燈的功能。假設初始狀態為：（南北通行狀態）南北綠燈、東西紅燈（25s）；後轉為過度狀態：南北黃燈、東西紅燈（5s）；再轉為東西通行狀態：東西綠燈、南北紅燈25（s）。再轉為過渡狀態：東西黃燈、南北紅燈(5s)，然後循環往復。

要求採用定時器實現所需要的定時時間。

2、鍵控交通燈。

按一下K1鍵

，保持南北通行狀態；按一下K2鍵

，保持東西通行狀態；按一下K3鍵

，保持正常交通燈。

要求在中斷中進行按鍵處理。

3、具有閃爍的交通燈。

在2的基礎上增加，綠燈最後5s閃爍，即亮0.5S滅0.5S閃爍。

四、實驗原理圖

圖3.2交通燈實驗電路原理圖
圖3.2共有4個按鍵K1、K2、K3、K4，分別連接到單片機P2.0、P2.1、P2.2、P2.3引腳，按鍵後對應引腳為低電平，通過4個二極體D17、D18、D19、D20連接到P3.2（外部中斷0），這是二極體構成的相與電路，即任意按一個鍵能在P3.2上產生一個低電平或下降，作為中斷觸發信號。

五、軟體設計思想

1、定時思想。

採用定時器T0或T1的方式1定時500ms，每500ms中斷進行計數，計數10次即0.5s，計數20次即1s，對秒計數實現所需要的定時時間。

2、亮燈控制思想。

單片機控制燈引腳與燈對應如下，0點亮。

一共有四種狀態S0、S1、S2、S3，

a、南北通行S0狀態：

南北綠燈、東西紅燈，P0=11110111=0xf7，P1=10011110=0x9e；

南北通行S0
b、過渡狀態S1：

南北黃燈、東西紅燈，P0=11111011=0xfb，P1=10101110=0xae；​

過渡狀態S1
c、東西通行狀態S2：

東西綠燈、南北紅燈，P0=11111100=0xfc，P1=11110011=0xf3；​

東西通行狀態S2
d、過渡狀態S3：

東西黃燈、南北紅燈，P0=11111101=0xfd，P1=01110101=0x75；

過渡狀態S3
設置一個秒計數單元SEC每秒+1，設置兩個控制值變數a，b。

⑷ 用最基礎的定時和中斷做一個單片機紅綠燈程序，然後需要模擬

;程序實現功能

;西南北路口直行與轉彎交替通行，數碼管顯示直行通行倒計時，紅綠黃燈顯示包括人行道在內的道路交通狀態。

;某一方向道路擁擠時，可以人工控制調節東西南北方向通行時間。

;緊急情況時，各路口交通燈顯示紅燈，數碼管保持數據不變。

;工作寄存器及存儲單元分配

;1.工作寄存器

;R2設置為定時器定時中斷次數,R6、R7用於延時程序中的寄存器

;2.片內存儲單元

;30H、31H作為兩組數碼管顯示數據存儲單元;32H、33H作為交通燈初始狀態存儲單元

;40H、41H作為交通燈顯示數據存儲單元

;3.標志位

;00H：南北通行標志位 ; 01H：東西通行標志位;02H：緊急事件標志位

; *** *** ***

SNF EQU 00H ; 南北通行標志位

EWF EQU 01H ; 東西通行標志位

URF EQU 02H ; 緊急事件標志位

ORG 0000H

LJMP MAIN ; 上電轉主程序

ORG 000BH ; 定時中斷入口

LJMP DSZD

ORG 0003H ; 緊急中斷入口

LJMP URZD

ORG 0030H

MAIN: LCALL INIT ; 調用初始化子程序

LOOP: LCALL DIS ; 循環執行顯示子程序

AJMP LOOP

; *** *** *** 初始化程序

INIT: SETB SNF

SETB EWF

SETB URF

MOV R2,#20 ; 定時器中斷20次為1s

MOV TMOD,#01H ; 初始化定時器

MOV TL0,#0B0H

MOV TH0,#3CH

SETB EA ; 開定時中斷與緊急中斷

SETB ET0

SETB TR0

SETB EX0

SETB IT0 ; 設置中斷程式控制方式

MOV DPTR,#TAB ; 數值首地址放入DPTR中

MOV 40H,#40 ; 東南西北通行時間設置

MOV 41H,#40

MOV 30H,#40 ; 通行時間初始化

MOV 31H,#60

MOV P0,#4CH ; 初始化時南北通行並把交通燈狀態分別放在32H和33H中

MOV 32H,#4CH

MOV P2,#15H

MOV 33H,#15H

RET

; *** *** *** 顯示子程序

DIS: MOV P3,#0DFH ; 選中南北方向的十位數碼管

MOV A,30H ; 把顯示數據送人數碼管顯示

MOV B,#10

DIV AB

MOVC A,@A+DPTR

MOV P1,A ;

LCALL D1MS

MOV P3,#0EFH ; 選中南北方向的個位數碼管

MOV A,B ; 送入數碼管顯示

MOVC A,@A+DPTR

MOV P1,A

LCALL D1MS

MOV P3,#7FH ; 選中第東西方向的十位數碼管

MOV A,31H ; 送入數碼管顯示

MOV B,#10

DIV AB

MOVC A,@A+DPTR

MOV P1,A

LCALL D1MS

MOV P3,#0BFH ; 選中第東西方向的個位數碼管

MOV A,B

MOVC A,@A+DPTR

MOV P1,A

LCALL D1MS

SETB P3.0

SETB P3.1

JNB P3.0,DIS_S ; 查詢是否第一個按鍵按下

JNB P3.1,DIS_E ; 查詢是否第二個按鍵按下

AJMP DIS_R ; 沒有鍵按下則返回

DIS_S:LCALL D5MS ; 按鍵去抖

JNB P3.0,DIS_SN

AJMP DIS_R

DIS_SN:MOV 40H,#50 ; 對通行時間從新分配，南北通行時間加長

MOV 41H,#30

AJMP DIS_R

DIS_E:LCALL D5MS ; 按鍵去抖

JNB P3.1,DIS_EW

AJMP DIS_R

DIS_EW:MOV 40H,#30 ; 東西通行時間加長

MOV 41H,#50

DIS_R:RET

; *** *** *** 定時中斷處理程序

DS_C: LJMP DS_R ; 接力跳轉

DSZD: PUSH ACC ; 保護現場

PUSH PSW

CLR TR0 ; 關定時器及中斷標志位並重新賦值

CLR TF0

MOV TL0,#0B0H

MOV TH0,#3CH

DJNZ R2,DS_C ; 判斷1m時間是否到達

MOV R2,#20 ; 到達重新賦值

DEC 30H ; 南北方向通行時間減一

MOV A,30H ; 把減一後的時間送入顯示存儲單元

; *** *** *** 南北通行到達最後4秒時黃燈閃爍

DS_10:CJNE A,#4,DS_11 ; 如果通行時間剩餘4秒

JNB SNF,DS_11 ; 判斷是否是南北通行

MOV P0,#8AH

MOV 32H, #8AH ; 把交通燈狀態存入存儲單元（後面類似）

DS_11:CJNE A,#3,DS_12 ; 不是剩餘3秒，返回

JNB SNF,DS_12 ; 不是南北通行時間，返回

MOV P0,#88H

MOV 32H, #88H

DS_12:CJNE A,#2,DS_13

JNB SNF,DS_13

MOV P0,#8AH

MOV 32H, #8AH

DS_13:CJNE A,#1,DS_14

JNB SNF,DS_14

MOV P0,#88H

MOV 32H, #88H

; *** *** ***

DS_14:JNZ DS_NE ; 通行時間沒有結束轉向改變東西方向的數碼管

CPL SNF ; 如果通行時間結束則對標志位取反

JNB SNF,DS_1 ; 判斷是否南北通行

MOV 30H,40H ; 是，點亮相應的交通燈

MOV P0,#4CH

MOV 32H,#4CH ; 存儲交通燈狀態

MOV P2,#15H

MOV 33H, #15H ; 存儲交通燈狀態

DS_NE:DEC 31H ; 東西方向通行時間減一

MOV A,31H ; 把通行剩餘時間送入顯示存儲單元

; *** *** *** 東西方向通行時間剩餘4秒鍾黃燈閃爍（程序注釋與南北方向類似 略）

DS_20:CJNE A,#4,DS_21

JB EWF,DS_21

MOV P0,#51H

MOV 32H, #51H

DS_21:CJNE A,#3,DS_22

JB EWF,DS_22

MOV P0,#41H

MOV 32H, #41H

DS_22:CJNE A,#2,DS_23

JB EWF,DS_23

MOV P0,#51H

MOV 32H, #51H

DS_23:CJNE A,#1,DS_24

JB EWF,DS_24

MOV P0,#41H

MOV 32H, #41H

; *** *** ***

DS_24:JNZ DS_R ; 東西方向時間沒有結束，返回

CPL EWF ; 對通行狀態取反

JNB EWF,DS_2 ; 東西方向通行時間到來，跳轉

MOV 31H,#80 ; 東西方向通行結束，重新顯示時間

MOV P0,#89H ; 點亮相應的交通燈

MOV 32H, #89H

MOV P2,#29H

MOV 33H, #29H

AJMP DS_R

DS_1: MOV 30H,#80 ; 南北通行時間結束，重新對顯示存儲單元賦值

MOV P0,#89H ; 執行轉彎狀態1

MOV 32H, #89H

MOV P2,#26H

MOV 33H, #26H

AJMP DS_NE

DS_2: MOV 31H,41H ; 東西方向開始通行，賦值予顯示存儲單元

MOV P0,#61H ; 點亮相應的交通燈

MOV 32H, #61H

MOV P2,#15H

MOV 33H, #15H

DS_R: SETB TR0

POP PSW ; 恢復現場

POP ACC

RETI

; *** *** *** 緊急中斷處理程序

URZD: PUSH ACC ; 保護現場

PUSH PSW

CLR IE0 ; 清除中斷標志位

CLR TR0 ; 關定時器

CPL URF ; 緊急事件標志位

JB URF,UR_CON ; 緊急結束；跳轉

MOV P0,#49H ; 各路口燈全顯示紅燈亮

MOV P2,#15H

AJMP UR_R

UR_CON:SETB TR0 ; 恢復正常交通

MOV A,32H

MOV P0,A

MOV A,33H

MOV P2,A

UR_R: POP PSW ; 恢復現場

POP ACC

RETI

; *** *** *** 查表指令0,1,2,3,4,5,6,7,8,9

TAB: DB 3FH, 06H, 5BH, 4FH, 66H, 6DH

DB 7DH, 07H, 7FH, 6FH

; *** *** *** 延時5ms與1ms

D5MS: MOV R7,#5

D1MS: MOV R7,#10

MOV R6,#50

L1: DJNZ R6,$

DJNZ R7,L1

RET

⑸ 跪求用單片機8051晶元設計的交通信號燈，那位大哥，大姐，幫下小弟

單片機課程設計與總結報告

摘要
近年來隨著科技的飛速發展，單片機的應用正在不斷地走向深入，同時帶動傳統控制檢測日新月益更新。在實時檢測和自動控制的單片機應用系統中，單片機往往是作為一個核心部件來使用，僅單片機方面知識是不夠的，還應根據具體硬體結構，以及針對具體應用對象特點的軟體結合，加以完善。交通信號燈的出現，使交通得以有效管制，對於疏導交通流量、提高道路通行能力，減少交通事故有明顯效果。本系統採用單片機AT89C51為中心器件來設計交通燈控制器，系統實用性強、操作簡單、擴展性強。
目錄

一．設計任務…………………………

二．交通燈的設計程序框圖………………

三．交通燈程序的主程序 ………………

四．系統硬體電路的設計……………………

五．原理圖………………

六．檢測與調試…………………………….

七．總結與體會……………………………….

八.致謝……………………………….

一．設計任務
（一）、功能及技術指標要求
設計交通燈的基本要求 ： 設計一個交通燈，要應用DVCC實驗系統。
（二）、設計內容
按設計技術指標進行交通燈的硬體和軟體設計。
（三）設計思路及關鍵技術
一個完整的交通燈相當於一個簡單的單片機系統，該系統有交通燈設置電路、單片機、顯示電路等構成。單片機是集成的IC晶元，只需根據實際設計要求選型。其他部分都需要根據應用要求和性能指標自行設計。
基於單片機的交通燈的設計時要充分的認識以下兩個問題：
1.因為本實驗是交通燈控制實驗，所以要先了解實際交通燈的變化規律。假設一個十字路仿橡口為東西南北走向。初始狀態0為東西紅燈，南北紅燈。然後轉狀態1南北綠燈通車，東西紅燈。過一段時間轉狀態2，南北綠燈閃幾次轉亮黃燈，延時幾秒，東西仍然紅燈。再轉狀態3，東西綠燈通車，南北紅燈。過一段時間轉狀態4，東西綠燈閃幾次轉亮黃燈，延時幾秒，南北仍然紅燈。最後循環至狀態1。
2.雙色LED是由一個紅色LED管芯和一個綠色LED管芯封裝在一起，公用負端。當紅色正端加高電平，綠色正端加低電平時，紅燈亮；紅色正端加低電平，綠色正端加高電平時，綠燈亮；兩端都加高電平時，黃燈亮。
二. 交通燈的設計程序框圖

開始
↓
四個路口紅燈亮
↓
東西綠燈亮，南北紅燈亮，延時
↓
東西黃燈閃爍，南北紅燈亮，延時
↓
東西紅燈亮，南北綠燈亮，延時
↓
東西紅燈亮，南北黃燈閃爍，延時
↓
三．交通燈程序的主程序
程序如下：
ORG 0000H
SJMP A3 ;四盞紅燈亮
A3:MOV SP,#60H
MOV A, #24H
MOV P1, A
CLR P3.4
CLR P3.3
SETB P3.5
SETB P3.2 ;顯示5秒
MOV R4,#05H
LOOP1:MOV R2,#03H
LCALL xian ;調顯示子程序
DJNZ R4,LOOP1
MOV R4,#00H
MOV R2,#03H
LCALL xian
;東西綠燈亮，南北紅燈亮
A2:MOV A,#0CH
CLR P3.5
MOV P1,A
SETB P3.3
CLR P3.4
SETB P3.2 ;顯示20秒衡搜
MOV R4,#14H
LOOP2 :MOV R2,#03H
LCALL xian ;調顯示子程序
DJNZ R4,LOOP2
MOV R4,#00H
MOV R2,#03H
LCALL xian ;調顯示子程序
SETB P3.2
CLR P3.3 ; 顯示5秒
MOV R4 ,#05H ;東西黃燈亮，南北紅燈亮
LOOP9:MOV A,#14H
MOV P1 ,A
CLR P3.5
SETB P3.4
MOV R2,#02H
LCALL xian ;調顯示子程序
MOV R2,#01H ;定時
LCALL DELAY ;調延時子程序
;南北紅燈亮
備攔旁MOV A ,#04H
MOV P1 ,A
CLR P3.4
CLR P3.5
MOV R2,#01H ;定時
LCALL DELAY ;調延時子程序
DJNZ R4,LOOP9
MOV R4,#00H
MOV R2,#03H
LCALL xian ;調顯示子程序
;東西紅燈亮，南北綠燈亮
A8: MOV A, #61H
MOV P1,A
CLR P3.4
CLR P3.3
CLR P3.2
SETB P3.5 ; 顯示20秒
MOV R4,#14H
LOOP3: MOV R2,#03H
LCALL xian ;調顯示子程序
DJNZ R4,LOOP3
MOV R4,#00H
MOV R2,#03H
LCALL xian ;調顯示子程序
SETB P3.5
MOV R4 ,#05H
LOOP10: MOV R2,#02H
LCALL xian ;調顯示子程序
; 東西紅燈亮，南北黃燈亮
A0:MOV A,#0A2H
MOV P1,A
CLR P3.4
CLR P3.3
CLR P3.2
MOV R2,#01H ;定時
LCALL DELAY ;調延時子程序
; 東西紅燈亮
MOV A,#20H
MOV P1,A
CLR P3.4
CLR P3.3
CLR P3.2
MOV R2,#01H ;定時
LCALL DELAY ;調延時子程序
DJNZ R4,LOOP10
MOV R4,#00H
MOV R2,#03H
LCALL xian ;調顯示子程序
LJMP A2 ;延時子程序
DELAY:PUSH 2
PUSH 1
PUSH 0
DELAY1: MOV 1,#00H
DELAY2:MOV 0,#0B2H
DJNZ 0,$
DJNZ 1,DELAY2
DJNZ 2,DELAY1
POP 0
POP 1
POP 2
DJNZ R2 ,DELAY
RET
;顯示子程序
xian: MOV A,R4
MOV B,#10
DIV AB
MOV R6,A
MOV DPTR,#TAB
MOV A,B
MOVC A,@A+DPTR
MOV SBUF,A
MOV R7,#0FH
H55S:DJNZ R7,H55S
MOV A,R6
MOVC A,@A+DPTR
MOV SBUF,A
MOV R7,#0FH
H55S1:DJNZ R7,H55S1
LCALL DELAY
RET
TAB:DB 0fch,60h,0dah,0f2h,66h,0b6h,0beh,0e0h
DB 0feh,0f6h,0eeh,3eh,9ch,7ah,9eh,8eh
END
四．系統硬體電路的設計
（1）晶元由DVCC實驗系統提供（AT89C51）
1．主要特性：
•與MCS-51 兼容
•4K位元組可編程閃爍存儲器
壽命：1000寫/擦循環
數據保留時間：10年
•全靜態工作：0Hz-24Hz
•三級程序存儲器鎖定
•128*8位內部RAM
•32可編程I/O線
•兩個16位定時器/計數器
•5個中斷源
•可編程串列通道
•低功耗的閑置和掉電模式
•片內振盪器和時鍾電路
2．管腳說明：
VCC：供電電壓。
GND：接地。
P0口：P0口為一個8位漏級開路雙向I/O口，每腳可吸收8TTL門電流。當P1口的管腳第一次寫1時，被定義為高阻輸入。P0能夠用於外部程序數據存儲器，它可以被定義為數據/地址的第八位。在FIASH編程時，P0 口作為原碼輸入口，當FIASH進行校驗時，P0輸出原碼，此時P0外部必須被拉高。
P1口：P1口是一個內部提供上拉電阻的8位雙向I/O口，P1口緩沖器能接收輸出4TTL門電流。P1口管腳寫入1後，被內部上拉為高，可用作輸入，P1口被外部下拉為低電平時，將輸出電流，這是由於內部上拉的緣故。在FLASH編程和校驗時，P1口作為第八位地址接收。
P2口：P2口為一個內部上拉電阻的8位雙向I/O口，P2口緩沖器可接收，輸出4個TTL門電流，當P2口被寫「1」時，其管腳被內部上拉電阻拉高，且作為輸入。並因此作為輸入時，P2口的管腳被外部拉低，將輸出電流。這是由於內部上拉的緣故。P2口當用於外部程序存儲器或16位地址外部數據存儲器進行存取時，P2口輸出地址的高八位。在給出地址「1」時，它利用內部上拉優勢，當對外部八位地址數據存儲器進行讀寫時，P2口輸出其特殊功能寄存器的內容。P2口在FLASH編程和校驗時接收高八位地址信號和控制信號。
P3口：P3口管腳是8個帶內部上拉電阻的雙向I/O口，可接收輸出4個TTL門電流。當P3口寫入「1」後，它們被內部上拉為高電平，並用作輸入。作為輸入，由於外部下拉為低電平，P3口將輸出電流（ILL）這是由於上拉的緣故。P3口也可作為AT89C51的一些特殊功能口，如下表所示：
口管腳 備選功能
P3.0 RXD（串列輸入口） P3.1 TXD（串列輸出口）
P3.2 /INT0（外部中斷0） P3.3 /INT1（外部中斷1）
P3.4 T0（記時器0外部輸入） P3.5 T1（記時器1外部輸入）
P3.6 /WR（外部數據存儲器寫選通） P3.7 /RD（外部數據存儲器讀選通）
P3口同時為閃爍編程和編程校驗接收一些控制信號。
RST：復位輸入。當振盪器復位器件時，要保持RST腳兩個機器周期的高電平時間。
ALE/PROG：當訪問外部存儲器時，地址鎖存允許的輸出電平用於鎖存地址的地位位元組。在FLASH編程期間，此引腳用於輸入編程脈沖。在平時，ALE端以不變的頻率周期輸出正脈沖信號，此頻率為振盪器頻率的1/6。因此它可用作對外部輸出的脈沖或用於定時目的。然而要注意的是：每當用作外部數據存儲器時，將跳過一個ALE脈沖。如想禁止ALE的輸出可在SFR8EH地址上置0。此時， ALE只有在執行MOVX，MOVC指令是ALE才起作用。另外，該引腳被略微拉高。如果微處理器在外部執行狀態ALE禁止，置位無效。
/PSEN：外部程序存儲器的選通信號。在由外部程序存儲器取指期間，每個機器周期兩次/PSEN有效。但在訪問外部數據存儲器時，這兩次有效的/PSEN信號將不出現。
/EA/VPP：當/EA保持低電平時，則在此期間外部程序存儲器（0000H-FFFFH），不管是否有內部程序存儲器。注意加密方式1時，/EA將內部鎖定為RESET；當/EA端保持高電平時，此間內部程序存儲器。在FLASH編程期間，此引腳也用於施加12V編程電源（VPP）。
XTAL1：反向振盪放大器的輸入及內部時鍾工作電路的輸入。
XTAL2：來自反向振盪器的輸出。
3．振盪器特性： XTAL1和XTAL2分別為反向放大器的輸入和輸出。該反向放大器可以配置為片內振盪器。石晶振盪和陶瓷振盪均可採用。如採用外部時鍾源驅動器件，XTAL2應不接。有餘輸入至內部時鍾信號要通過一個二分頻觸發器，因此對外部時鍾信號的脈寬無任何要求，但必須保證脈沖的高低電平要求的寬度。
4．晶元擦除： 整個PEROM陣列和三個鎖定位的電擦除可通過正確的控制信號組合，並保持ALE管腳處於低電平10ms 來完成。在晶元擦操作中，代碼陣列全被寫「1」且在任何非空存儲位元組被重復編程以前，該操作必須被執行。
此外，AT89C51設有穩態邏輯，可以在低到零頻率的條件下靜態邏輯，支持兩種軟體可選的掉電模式。在閑置模式下，CPU停止工作。但RAM，定時器，計數器，串口和中斷系統仍在工作。在掉電模式下，保存RAM的內容並且凍結振盪器，禁止所用其他晶元功能，直到下一個硬體復位為止。
(2) 完整的DVCC實驗箱面板

（3）硬體電路連接說明

五．原理圖

六．檢測與調試
1、硬體調試：
硬體調試是利用DVCC實驗與開發系統、基本測試儀器（萬用表、示波器等），檢查用戶系統硬體中存在的故障。
硬體調試可分為靜態調試與動態調試兩步進行。
靜態調試是在用戶系統未工作時的一種硬體檢測。
第一步：目測。檢查外部的各種元件或者是電路是否有斷點。
第二步用萬用表測試。先用萬用表復核目測中有疑問的連接點，再檢測各種電源線與地線之間是否有短路現象。
第三步加電檢測。給板加電，檢測所有插座或是器件的電源端是否符合要求的值
第四步是聯機檢查。因為只有用單片機開發系統才能完成對用戶系統的調試。
動態調試是在用戶系統工作的情況下發現和排除用戶系統硬體中存在的器件內部故障、器件連接邏輯錯誤等的一種硬體檢查。動態調試的一般方法是由近及遠、由分到合。由分到合是指首先按邏輯功能將用戶系統硬體電路分為若干塊，當調試電路時，與該元件無關的 器件全部從用戶系統中去掉，這樣可以將故障范圍限定在某個局部的電路上。當各塊電路無故障後，將各電路逐塊加入系統中，在對各塊電路功能及各電路間可能存在的相互聯系進行調試。由分到合的調試既告完成。由近及遠是將信號流經的各器件按照距離單片機的邏輯距離進行由近及遠的分層，然後分層調試。調試時，仍採用去掉無關元件的方法，逐層調試下去，就會定位故障元件了。
2、軟體調試：
軟體調試是通過對程序的匯編、連接、執行來發現程序中存在的語法錯誤與邏輯錯誤並加以排除糾正的過程。
七．總結與體會
本系統是以單片機AT89C51晶元為核心部件，實現了能根據實際車流量通過AT89C51晶元設置紅、綠燈燃亮時間的功能。此次在軟體上是花費時間最多的，我們上網找資料，上圖書館，盡可能的了解有關於交通燈這方面的知識。通過這次畢業設計，使我得到了一次用專業知識、專業技能分析和解決問題全面系統的鍛煉。使我在單片機的基本原理、單片機應用系統開發過程，以及在常用編程設計思路技巧（特別是匯編語言）的掌握方面都能向前邁了一大步。
八．致謝
通過本次畢業設計，我在塗老師和王老師的精心指導和嚴格要求下，獲得了豐富的理論知識，極大地提高了實踐能力，單片機領域這對我今後進一步學習計算機方面的知識有極大的幫助。在此，忠心感謝塗老師和王老師以及許多同學的指導和支持。

要圖的話，多給我點分，我發到你郵箱里！