單片機串口匯編

㈠ 單片機串口用T2做定時器 晶振為：22。1184 比特率：115200 匯編程序怎麼寫

初始化程序如下:
MOV SCON, #50H ;設置串口方式1，允許接收.
MOV T2CON, #00110100B ;設置T2
MOV T2MOD, #0
MOV RCAP2H, #0FFH
MOV RCAP2L, #0FAH
MOV TH2, #0FFH
MOV TL2, #0FAH
……

㈡ 51單片機匯編語言寫串口程序

ORG 0000H
SJMP 0050H
ORG 0023H
LJMP S_INT
TAB:DB 20H,49H,20H,47H,45H,54H,20H,'NULL'
ORG 0050H
MOV TMOD,#20H
MOV TH1,#0FDH
MOV TL1,#0FDH
SETB TR1
SETB SM1
CLR SM0
SETB EA
SETB ES
MOV R0,#30H
MOV A,#1H
MAIN:SETB REN
ACALL DELAY
JNZ MAIN
MOV R2,#0
MOV DPTR,#TAB
MOV R7,#7
SEND:MOV A,R2
MOVC A,@A+DPTR
CLR ES
MOV SBUF,A
JNB TI,$
CLR TI
INC R2
DJNZ R7,SEND
MOV R0,#30H
SHOW:MOV A,@R0
MOV SBUF,A
JNB TI,$
CLR TI
INC R0
CJNE A,#40H,SHOW
SETB ES
MOV A,#1
MOV R0,#30H
SJMP MAIN

S_INT:CLR RI

MOV A,SBUF
MOV @R0,A
CJNE A,#40H,NEXT
MOV A,#0
NEXT:INC R0
RETI
DELAY:MOV 7DH,#200
LOOP1:MOV 7EH,#40
DJNZ 7EH,$
DJNZ 7DH,LOOP1
RET
END
這個是方式一的

㈢ 51單片機串口通信（匯編）

HERE: AJMP HERE
SINT: MOV P1,R0
JB RI,RECV
JB TI,SEND
AJMP HERE

中斷裡面直接用這種方式直接跳到主程序，我以前還是真沒試過，不過估計能行吧。 我一直用RETI 返回堆棧地址位置的。

但下面這地方肯定有錯的，就是執行MOV SBUF,A 後沒有等待！！
正確的順序是： CLR TI ;清發送標記
MOV SBUF,A ;發送
JNB TI,$ ; 這里是如果TI沒有被置1就等待，因為送數可能還沒有完成。。就去執行別的動作，可能會有問題。
接收也一樣要等待:
MOV A,SBUF
JNB RI,$ ;等待接收完成標志。

另外：
CPL P1.7 有問題，我猜你是用P1.7來觀察接收次數，
但由於CPL P1.7取反命令是讀一下P1.7再取反輸出的，如果你的p1.7外接電路不科學，不合理，可能會出現你每次不管發1,還是發0，p1.7都是低電平，比如你將p1.7直接接在npn三管基極就會一直是0V或0.7V ， P1.7的讀入值會總為0，CPL 輸出會總是為1
你可以用內部（非P口的位地址過度一下），比如： CPL 01H
MOV C，01H
MOV P1.7，C
你先試驗吧。。。

㈣ 求一個51單片機匯編語言 串口輸出一行中文的程序

;下載程序以後,聯接好串口線
;然後打開串口調試軟體，按照您連接的串口，設置好串口特性(注意波特率)
;然後發送數據給下面的機器，並接受下面發送上來的數據！

beep bit p3.7 ;蜂鳴器定義

org 00h
jmp main
org 23h ;串列中斷入口地址
jmp com_int ;串列中斷服務程序

;*********** 主程序開始 *******************
org 30h
main: mov sp,#30h ;設置堆棧
lcall rest ;初始化
lcall comm ;串口初始化
jmp $ ;原地等待

; ************* 初始化 *********************
rest: mov p0,#00h ;禁止數碼管顯示
mov p2,#255
clr beep ;禁止蜂鳴器
mov p1,#255 ;禁止LED顯示
RET ;返回

; ************** 串口初始化 *****************
;設置串列口工作方式1，定時器1作為波特率發生器
;波特率設置為 2400 ;

comm: mov tmod,#20h ;設置定時器T1工作方式2
mov tl1,#0f4h ;定時器計數初值，波特率 2400
mov th1,#0f4h ;定時器重裝值
setb ea ;允許總的中斷
setb es ;允許串列中斷
mov pcon,#00h ;波特率不倍增
mov scon,#50h ;設置串口工作方式1,REN = 1 允許接收
setb tr1 ;定時器開始工作
ret ;返回
;*************** 串口中斷服務程序 ***********
; 如果接收 0FF 表示上位機需要聯機信號，單片機發送 0FFH作為
; 應答信號,如果接收到 數字 1~ n，表示相應的功能；
; 這里，如果收到 1 ，則單片機向計算機發送字元 'H';
; 如果收到 2 ，則單片機向計算機發送字元 'e';
; 如果收到其他的數據，則發送 'J';
com_int: clr es ;禁止串列中斷
clr ri ;清除接收標志位
mov a,sbuf ;從緩沖區取出數據
mov p1,a
mov dptr,#tab
cjne a,#0ffh,in_1 ;檢查數據
mov sbuf,#255 ;收到聯機信號，發送聯機信號
jnb ti,$ ;等待發送完畢
clr ti ;清除發送標志
setb es ;允許串列中斷
reti ;中斷返回
in_1: cjne a,#1H, in_2 ;如果收到1
movc a,@a+dptr
mov sbuf,a ;發送 'h'
jnb ti,$ ;等待發送完畢
clr ti ;清除發送中斷標志
setb es ;允許串列中斷
reti ;中斷返回
in_2: cjne a,#2,in_3 ;接收到 2
movc a,@a+dptr
mov sbuf,a ;發送 'e'
jnb ti,$ ;等待發送完畢
clr ti ;清除發送中斷
setb es ;允許串列中斷
reti ;中斷返回
in_3: mov a,#03h
movc a,@a+dptr
mov sbuf,a ;發送 'j'
jnb ti,$ ;等待發送完畢
clr ti ;清除發送中斷標志
setb es ;允許串列中斷
reti ;返回
tab: db '2','h','e','j'
end

㈤ 單片機串口通信問題（匯編語言）

這倆程序，執行到最後邊，都是 RET，返回指令。

返回到何處去呀？

呵呵，還是，先解決程序結構的問題。

㈥ 求單片機高手編寫一個串口通信接受字元程序，用匯編語言. 急急急！！！！

ORG 00H

AJMP MAIN

ORG 23H

AJMP URT;串口中斷

ORG 30H

MAIN:

MOV SP,#60H

MOV R0,#50H

MOV TMOD,#20H;T1工作方式2

SETB EA;開總中斷

ACALL URTINIT;串口初始化

AJMP $ ;等待串口中斷

URT: ;串口中斷每次只收1個位元組，未完繼續進入中斷，接收。

PUSH ACC

JNB RI,URT1

URT0:

CLR ES

CLR RI

MOV A,SBUF

MOV @R0,A;先保存

INC R0

CJNE R0,#60H,URT1

CLR EA

URT1:

SETB ES

POP ACC

RTI: RETI

URTINIT:

MOV SCON,#50H;串口工作方式1,接收

MOV TH1,#0F4H;11.0592M2400BPS

MOV TL1,TH1

SETB TR1;開啟定時器

SETB ES;開啟串口中斷

RET