8051單片機匯編

❶ 求一個用匯編語言編寫一個8051單片機的時鍾程序（急急急啊）

給你當參缺春祥考...不足功能自己改...有問題再發問..

;P1.4小時調整伏搏 P1.5分種調整

CODE_SEG SEGMENT CODE
DATA_SEG SEGMENT DATA
STACK_SEG SEGMENT IDATA

K1 BIT P1.4
K2 BIT P1.5

RSEG DATA_SEG
KEY_S: DS 1
KEY_V: DS 1
DIS_DIGIT: DS 1
SEC: DS 1
DIS_INDEX: DS 1
HOUR: DS 1
MIN: DS 1
SEC100: DS 1
DIS_BUF: DS 8

BUF_HOUR_H EQU DIS_BUF ; 小時十位
BUF_HOUR_L EQU DIS_BUF+1 ; 小時個森氏位
BUF_MIN_H EQU DIS_BUF+3 ; 分十位
BUF_MIN_L EQU DIS_BUF+4 ; 分個位
BUF_SEC_H EQU DIS_BUF+6 ; 秒十位
BUF_SEC_L EQU DIS_BUF+7 ; 秒個位

RSEG STACK_SEG
STACK: DS 20

;===============================================================================

CSEG AT 0000H
JMP MAIN

CSEG AT 0000BH
LJMP TIMER0

CSEG AT 0001BH
LJMP TIMER1

;===============================================================================

RSEG CODE_SEG
MAIN:
USING 0

MOV SP, #(STACK-1) ;

MOV P0,#0FFH
MOV P2,#0FFH
MOV TMOD,#011H ; 定時器0, 1工作模式1, 16位定時方式
MOV TH0,#0FCH
MOV TL0,#017H
MOV TH1,#0DCH
CLR A
MOV TL1,A

MOV HOUR,#12 ;
CLR A ;
MOV MIN,A
MOV SEC,A
MOV SEC100,A

MOV A,HOUR
MOV B,#10
DIV AB
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_HOUR_H,A ; 時十位
MOV A,HOUR
MOV B,#10
DIV AB
MOV A,B
MOVC A,@A+DPTR
MOV BUF_HOUR_L,A ; 時個位
MOV A,MIN
MOV B,#10
DIV AB
MOVC A,@A+DPTR
MOV BUF_MIN_H,A ; 分十位
MOV A,MIN
MOV B,#10
DIV AB
MOV A,B
MOVC A,@A+DPTR
MOV BUF_MIN_L,A ; 分個位
MOV A,SEC
MOV B,#10
DIV AB
MOVC A,@A+DPTR
MOV BUF_SEC_H,A ; 秒十位
MOV A,SEC
MOV B,#10
DIV AB
MOV A,B
MOVC A,@A+DPTR
MOV BUF_SEC_L,A ; 秒個位

MOV BUF_HOUR_H+02H,#0BFH
MOV BUF_HOUR_H+05H,#0BFH

MOV DIS_DIGIT,#0FEH
CLR A
MOV DIS_INDEX,A

MOV IE,#08AH ; 使能timer0,1 中斷

SETB TR0
SETB TR1

MOV KEY_V,#03H

MAIN_LP:
LCALL SCAN_KEY ; 鍵掃描
JZ MAIN_LP ; 無鍵返回

MOV R7,#10 ; 延時10ms
LCALL DELAYMS ; 延時去抖動
LCALL SCAN_KEY ; 再次掃描
JZ MAIN_LP ; 無鍵返回

MOV KEY_V,KEY_S ; 保存鍵值
LCALL PROC_KEY ; 鍵處理
SJMP MAIN_LP ; 調回主循環

;===============================================================================
SCAN_KEY:
; 掃鍵掃描子程序
; 保存按鍵狀態到key_s
; 返回: A --- 按鍵是否按下(BOOL)

CLR A

MOV C,K1 ; 讀按鍵K1
MOV ACC.0,C
MOV C,K2 ; 讀按鍵K2
MOV ACC.1,C

MOV KEY_S,A ; 保存按鍵狀態到key_s
XRL A,KEY_V
RET

;===============================================================================
PROC_KEY:
; 鍵處理子程序
; 傳入參數: KEY_V --- 按鍵值
; 返回值: 無

CLR EA

MOV A,KEY_V
JNB ACC.0,PROC_K1
JNB ACC.1,PROC_K2
SJMP END_PROC_KEY

PROC_K1: ; 按鍵k1處理
LCALL INC_HOUR ; 小時加1
SJMP END_PROC_KEY

PROC_K2: ; 按鍵K2處理
INC MIN ; 分鍾加1

MOV A,MIN ;
SETB C
SUBB A,#59
JC K2_UPDATE_MIN ; 如果分鍾等於60,則分清0,小時加1

CLR A ;
MOV MIN,A

K2_UPDATE_MIN: ; 更新分顯示緩沖區
MOV A,MIN
MOV B,#10
DIV AB ; A = MIN / 10
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_MIN_H,A ; 更新分十位

MOV A,MIN
MOV B,#10
DIV AB
MOV A,B ; A = MIN % 10
MOVC A,@A+DPTR
MOV BUF_MIN_L,A ; 更新分個位

END_PROC_KEY:
SETB EA
RET

;===============================================================================

USING 0
TIMER0:
; 定時器0中斷服程序, 用於數碼管的動態掃描
; DIS_INDEX --- 顯示索引, 用於標識當前顯示的數碼管和緩沖區的偏移量
; DIS_DIGIT --- 位選通值, 傳送到P2口用於選通當前數碼管的數值, 如等於0xfe時,
; 選通P2.0口數碼管
; DIS_BUF --- 顯於緩沖區基地址

PUSH ACC
PUSH PSW
PUSH AR0

MOV TH0,#0FCH
MOV TL0,#017H

MOV P2,#0FFH ; 先關閉所有數碼管

MOV A,#DIS_BUF ; 獲得顯示緩沖區基地址
ADD A,DIS_INDEX ; 獲得偏移量
MOV R0,A ; R0 = 基地址 + 偏移量
MOV A,@R0 ; 獲得顯示代碼
MOV P0,A ; 顯示代碼傳送到P0口

MOV P2,DIS_DIGIT

MOV A,DIS_DIGIT ; 位選通值左移, 下次中斷時選通下一位數碼管
RL A
MOV DIS_DIGIT,A

INC DIS_INDEX ; DIS_INDEX加1, 下次中斷時顯示下一位
ANL DIS_INDEX,#0x07 ; 當DIS_INDEX等於8(0000 1000)時, 清0

POP AR0
POP PSW
POP ACC

RETI

;===============================================================================
USING 0
TIMER1:
; 定時器1中斷服務程序, 產生時基信號10ms
;
;
PUSH PSW
PUSH ACC
PUSH B
PUSH DPH
PUSH DPL

MOV TH1,#0DCH

INC SEC100

MOV A,SEC100
CLR C
SUBB A,#100 ; 是否中斷100次(達到1s)
JC END_TIMER1 ; < 1S

MOV SEC100,#00H ; 達到1s
LCALL INC_SEC ; 秒加1

END_TIMER1:
POP DPL
POP DPH
POP B
POP ACC
POP PSW

RETI ;

;===============================================================================
INC_SEC:
INC SEC

MOV A,SEC
SETB C
SUBB A,#59 ;
JC UPDATE_SEC

CLR A
MOV SEC,A
LCALL INC_MIN

UPDATE_SEC:
MOV A,SEC
MOV B,#10
DIV AB ; A = SEC / 10
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR ;
MOV BUF_SEC_H,A ;

MOV A,SEC
MOV B,#10
DIV AB
MOV A,B ; A = SEC % 10
MOVC A,@A+DPTR
MOV BUF_SEC_L,A
RET

;===============================================================================

INC_MIN:
INC MIN ; 分鍾加1

MOV A,MIN ;
SETB C
SUBB A,#59
JC UPDATE_MIN ; 如果分鍾等於60,則分清0,小時加1

CLR A ;
MOV MIN,A
LCALL INC_HOUR ; 小時加1

UPDATE_MIN: ; 更新分顯示緩沖區
MOV A,MIN
MOV B,#10
DIV AB ; A = MIN / 10
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_MIN_H,A ; 更新分十位

MOV A,MIN
MOV B,#10
DIV AB
MOV A,B ; A = MIN % 10
MOVC A,@A+DPTR
MOV BUF_MIN_L,A ; 更新分個位

RET

;===============================================================================

INC_HOUR:
INC HOUR ; 小時加1
MOV A,HOUR
SETB C
SUBB A,#24
JC UPDATE_HOUR ; 如果小時等於24,則小時清0

CLR A
MOV HOUR,A ; 小時清0

UPDATE_HOUR:
MOV A,HOUR
SETB C
SUBB A,#10
JC UPDATE_HOUR1 ; 如果小時小於10,則十位0不顯示

MOV A,HOUR
MOV B,#10
DIV AB
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR ;
MOV BUF_HOUR_H,A
SJMP UPDATE_HOUR2

UPDATE_HOUR1:
MOV BUF_HOUR_H,#0FFH

UPDATE_HOUR2:
MOV A,HOUR
MOV B,#10
DIV AB
MOV A,B
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_HOUR_L,A
RET

;===============================================================================

DELAYMS:
; 延時子程序
; 傳入參數：R7 --- 延時值(MS)
; 返回值：無

MOV A,R7
JZ END_DLYMS
DLY_LP1:
MOV R6,#185
DLY_LP2:
NOP
NOP
NOP
DJNZ R6,DLY_LP2
DJNZ R7,DLY_LP1

END_DLYMS:
RET

; END OF DELAYMS

;===============================================================================

DIS_CODE:
DB 0C0H
DB 0F9H
DB 0A4H
DB 0B0H
DB 099H
DB 092H
DB 082H
DB 0F8H
DB 080H
DB 090H
DB 0FFH

END

❷ 51單片機編程題，用匯編語言怎麼做

在8051單片機的時鍾頻率為6MHz，那麼定時器的計數脈沖周期就是 2uS；

sbit CP=P1^0;

void Timer0_init()

{

TMOD |=0x01; //T0定時器，方式1，採用16位定時器

TH0 = (65536-500)/256; //定時器裝初值500, 即 1000uS 中斷一次

TL0 = (65536-500)%256;

EA=1; ET0=1; TR0=1;

}

void timer0() interrupt 1

{

TH0 = (65536-500)/256; //定時器裝初值500, 1mS 中斷一次

TL0 = (65536-500)%256;

CP=~CP; //改變脈沖信號的輸出狀態

}

void main()

{

Timer0_init();

CP=0;

while(1) { }

}

匯編語言，才看到，算了，你別人的回答吧

❸ 8051單片機的匯編程序編程問題！！！

既然向我求助,那我就寫一下大概的思路和C語言程序,至於匯編語言,兄弟可自己由C語言翻譯,我今天的確沒太有時間.
周期為2個ms的方波,也就是說半個周期為1ms,也就是說,P1.2每1ms翻轉一次;
同理,P1.3每3.5ms翻轉一次,因為只能用一個定時器,所以,取1ms和3.5ms的最大公約數,是0.5ms,也就是說,讓定時器0.5ms中斷一次,然後每兩個中斷,翻轉一次P1.2,每7個中斷翻轉一次P1.3;
這就是編程思路,那麼我們來看具體的編程細節;
6Mhz,也就是指令周期是2us,0.5ms需要250個計數,250<256,為了速度和效率,我們讓定時器1工作在自動重載模式下,也就是模式2;

C語言整個程序編程如下;

#include <reg52.h>
bit P1_2_Turn_Cnt = 0; //----用於P1.2的計數翻轉,因為只有兩次,大可不必用unsigned char類型的
unsigned char P1_3_Turn_Cnt = 0; //----用於P1.3的計數翻轉,因為要7次,所以用unsigned char
sbit P1_3 = P1^3;
sbt P1_2 = P1^2;
void main(void)
{
//----初始化定時器,工作在模式2,自動重載,開中斷,每0.5ms中斷一次
TH1 = 256 - 250; //----設置定時器,250 X 2us = 500us = 0.5ms
TL1 = 256 -250;
TMOD = 0x20; //----定時器/計數器1 工作在模式2下;
ET1 = 1; //----開定時器1中斷
TR1 = 1; //-----啟動定時器
EA = 1; //----開總中斷
while(1); //----定時器初始化完成,方波工作在定時器內部完成;
}

void ISR_Timer1(void) interrupt 3
{
P1_2_Turn_Cnt = ~P1_2_Turn_Cnt;//---P1_2翻轉計數,由於初始化為0,所以第1次會翻轉為1;
//---由此推論,奇數次翻轉後狀態為1,偶數次中斷會翻轉為
//---0,所以當P1_2_Turn_Cnt = 0時,P1_2翻轉.
if(P1_2_Turn_Cnt == 0)
{
P1_2 = ~P1_2;
}
P1_3_Turn_Cnt++;
if(P1_3_Turn_Cnt >= 7)
{
P1_3_Turn_Cnt = 0;
P1_3 = ~P1_3;
}
}

以上就是這個程序實現的全部過程,你可以自己手動翻譯成匯編語言,也可以用Keil的Debug模式自動翻譯,因為我時間有限,所以就不給你翻譯了,請見諒!

❹ 請教8051匯編指令

MCS-51數據傳送指令

數據傳送指令共有29條，數據傳送指令一般的操作是把源操作數傳送到目的操作數，指令執行完成後，源操作數不變，目的操作數等於源操作數。如果要求在進行數據傳送時，目的操作數不丟失，則不能用直接傳送指令，而採用交換型的數據傳送指令，數據傳送指令不影響標志C,AC和OV，但可能會對奇偶標志P有影響。

[1]. 以累加器A為目的操作數類指令（4條）
這4條指令的作用是把源操作數指向的內容送到累加器A。有直接、立即數、寄存器和寄存器間接定址方式：

MOV A,data ;（data）→（A） 直接單元地址中的內容送到累加器A
MOV A,#data ;#data→（A） 立即數送到累加器A中
MOV A,Rn ;（Rn）→（A） Rn中的內容送到累加器A中
MOV A,@Ri ;（（Ri））→（A） Ri內容指向的地址單元中的內容送到累加器A

[2]. 以寄存器Rn為目的操作數的指令（3條）
這3條指令的功能是把源操作數指定的內容送到所選定的工作寄存器Rn中。有直接、立即和寄存器定址方式：

MOV Rn,data ;（data）→（Rn） 直接定址單元中的內容送到寄存器Rn中
MOV Rn,#data ;#data→（Rn） 立即數直接送到寄存器Rn中
MOV Rn,A ;（A）→（Rn） 累加器A中的內容送到寄存器Rn中

[3]. 以直接地址為目的操作數的指令（5條）
這組指令的功能是把源操作數指定的內容送到由直接地址data所選定的片內RAM中。有直接、立即、寄存器和寄存器間接4種定址方式：

MOV data,data ;（data）→（data） 直接地址單元中的內容送到直接地址單元
MOV data,#data ;#data→（data） 立即數送到直接地址單元
MOV data,A ;（A）→（data） 累加器A中的內容送到直接地址單元
MOV data,Rn ;（Rn）→（data） 寄存器Rn中的內容送到直接地址單元
MOV data,@Ri ;（（Ri））→（data） 寄存器Ri中的內容指定的地址單元中數據送到直接地址單元

[4]. 以間接地址為目的操作數的指令（3條）
這組指令的功能是把源操作數指定的內容送到以Ri中的內容為地址的片內RAM中。有直接、立即和寄存器3種定址方式：

MOV @Ri,data ;（data）→（（Ri）） 直接地址單元中的內容送到以Ri中的內容為地址的RAM單元
MOV @Ri,#data ;#data→（（Ri）） 立即數送到以Ri中的內容為地址的RAM單元
MOV @Ri,A ;（A）→（（Ri）） 累加器A中的內容送到以Ri中的內容為地址的RAM單元

[5]. 查表指令（2條）
這組指令的功能是對存放於程序存儲器中的數據表格進行查找傳送，使用變址定址方式：

MOVC A,@A+DPTR ;（（A））+（DPTR）→（A） 表格地址單元中的內容送到累加器A中
MOVC A,@A+PC ;（（PC））+1→（A），（（A））+（PC）→（A） 表格地址單元中的內容送到累加器A中

[6]. 累加器A與片外數據存儲器RAM傳送指令（4條）
這4條指令的作用是累加器A與片外RAM間的數據傳送。使用寄存器定址方式：

MOVX @DPTR,A ;（A）→（（DPTR）） 累加器中的內容送到數據指針指向片外RAM地址中
MOVX A, @DPTR ;（（DPTR））→（A） 數據指針指向片外RAM地址中的內容送到累加器A中
MOVX A, @Ri ;（（Ri））→（A） 寄存器Ri指向片外RAM地址中的內容送到累加器A中
MOVX @Ri,A ;（A）→（（Ri）） 累加器中的內容送到寄存器Ri指向片外RAM地址中

[7]. 堆棧操作類指令（2條）
這4類指令的作用是把直接定址單元的內容傳送到堆棧指針SP所指的單元中，以及把SP所指單元的內容送到直接定址單元中。這類指令只有兩條，下述的第一條常稱為入棧操作指令，第二條稱為出棧操作指令。需要指出的是，單片機開機復位後，（SP）默認為07H，但一般都需要重新賦值，設置新的SP首址。入棧的第一個數據必須存放於SP+1所指存儲單元，故實際的堆棧底為SP+1所指的存儲單元。

PUSH data ;（SP）+1→（SP），（data）→（SP） 堆棧指針首先加1，直接定址單元中的數據送到堆棧指針SP所指的單元中
POP data ;（SP）→（data）（SP）-1→（SP）， 堆棧指針SP所指的單元數據送到直接定址單元中，堆棧指針SP再進行減1操作

[8]. 交換指令（5條）
這5條指令的功能是把累加器A中的內容與源操作數所指的數據相互交換。

XCH A,Rn ;（A）←→（Rn）累加器與工作寄存器Rn中的內容互換
XCH A,@Ri ;（A）←→（（Ri））累加器與工作寄存器Ri所指的存儲單元中的內容互換
XCH A,data ;（A）←→（data）累加器與直接地址單元中的內容互換
XCHD A,@Ri ;（A 3-0 ）←→（（Ri） 3-0 ）累加器與工作寄存器Ri所指的存儲單元中的內容低半位元組互換
SWAP A ;（A 3-0 ）←→（A 7-4 ）累加器中的內容高低半位元組互換

[9]. 16位數據傳送指令（1條）
這條指令的功能是把16位常數送入數據指針寄存器。

MOV DPTR,#data16 ;#dataH→（DPH），#dataL→（DPL）16位常數的高8位送到DPH，低8位送到DPL

MCS-51算術運算指令

算術運算指令共有24條，算術運算主要是執行加、減、乘、除法四則運算。另外MCS-51指令系統中有相當一部分是進行加、減1操作，BCD碼的運算和調整，我們都歸類為運算指令。雖然MCS-51單片機的算術邏輯單元ALU僅能對8位無符號整數進行運算，但利用進位標志C，則可進行多位元組無符號整數的運算。同時利用溢出標志，還可以對帶符號數進行補碼運算。需要指出的是，除加、減1指令外，這類指令大多數都會對PSW（程序狀態字）有影響。這在使用中應特別注意。

[1]. 加法指令（4條）
這4條指令的作用是把立即數，直接地址、工作寄存器及間接地址內容與累加器A的內容相加，運算結果存在A中。

ADD A,#data ;（A）+#data→（A） 累加器A中的內容與立即數#data相加，結果存在A中
ADD A,data ;（A）+（data）→（A） 累加器A中的內容與直接地址單元中的內容相加，結果存在A中
ADD A,Rn ;（A）+（Rn）→（A） 累加器A中的內容與工作寄存器Rn中的內容相加，結果存在A中
ADD A,@Ri ;（A）+（（Ri））→（A） 累加器A中的內容與工作寄存器Ri所指向地址單元中的內容相加，結果存在A中

[2]. 帶進位加法指令（4條）
這4條指令除與[1]功能相同外，在進行加法運算時還需考慮進位問題。

ADDC A,data ;（A）+（data）+（C）→（A） 累加器A中的內容與直接地址單元的內容連同進位位相加，結果存在A中
ADDC A,#data ;（A）+#data +（C）→（A） 累加器A中的內容與立即數連同進位位相加，結果存在A中
ADDC A,Rn ;（A）+Rn+（C）→（A） 累加器A中的內容與工作寄存器Rn中的內容、連同進位位相加，結果存在A中
ADDC A,@Ri ;（A）+（（Ri））+（C）→（A） 累加器A中的內容與工作寄存器Ri指向地址單元中的內容、連同進位位相加，結果存在A中

[3]. 帶借位減法指令（4條）
這組指令包含立即數、直接地址、間接地址及工作寄存器與累加器A連同借位位C內容相減，結果送回累加器A中。
這里我們對借位位C的狀態作出說明，在進行減法運算中，CY=1表示有借位，CY=0則無借位。OV=1聲明帶符號數相減時，從一個正數減去一個負數結果為負數，或者從一個負數中減去一個正數結果為正數的錯誤情況。在進行減法運算前，如果不知道借位標志位C的狀態，則應先對CY進行清零操作。

SUBB A,data ;（A）-（data） - （C）→（A） 累加器A中的內容與直接地址單元中的內容、連同借位位相減，結果存在A中
SUBB A,#data ;（A）-#data -（C）→（A） 累加器A中的內容與立即數、連同借位位相減，結果存在A中
SUBB A,Rn ;（A）-（Rn） -（C）→（A） 累加器A中的內容與工作寄存器中的內容、連同借位位相減，結果存在A中
SUBB A,@Ri ;（A）-（（Ri）） -（C）→（A） 累加器A中的內容與工作寄存器Ri指向的地址單元中的內容、連同借位位相減，結果存在A中

[4]. 乘法指令（1條）
這個指令的作用是把累加器A和寄存器B中的8位無符號數相乘，所得到的是16位乘積，這個結果低8位存在累加器A，而高8位存在寄存器B中。如果OV=1，說明乘積大於FFH，否則OV=0，但進位標志位CY總是等於0。

MUL AB ;（A）×（B）→（A）和（B） 累加器A中的內容與寄存器B中的內容相乘，結果存在A、B中

[5]. 除法指令（1條）
這個指令的作用是把累加器A的8位無符號整數除以寄存器B中的8位無符號整數，所得到的商存在累加器A，而余數存在寄存器B中。除法運算總是使OV和進位標志位CY等於0。如果OV=1，表明寄存器B中的內容為00H，那麼執行結果為不確定值，表示除法有溢出。

DIV AB ;（A）÷（B）→（A）和（B） 累加器A中的內容除以寄存器B中的內容，所得到的商存在累加器A，而余數存在寄存器B中。

[6]. 加1指令（5條）
這5條指令的的功能均為原寄存器的內容加1，結果送回原寄存器。上述提到，加1指令不會對任何標志有影響，如果原寄存器的內容為FFH，執行加1後，結果就會是00H。這組指令共有直接、寄存器、寄存器減間址等定址方式：

INC A ;（A）+1→（A） 累加器A中的內容加1，結果存在A中
INC data ;（data）+1→（data） 直接地址單元中的內容加1，結果送回原地址單元中
INC @Ri ;（（Ri））+1→（（Ri）） 寄存器的內容指向的地址單元中的內容加1，結果送回原地址單元中
INC Rn ;（Rn）+1→（Rn）寄存器Rn的內容加1，結果送回原地址單元中
INC DPTR ;（DPTR）+1→（DPTR）數據指針的內容加1，結果送回數據指針中

在INC data這條指令中，如果直接地址是I/O，其功能是先讀入I/O鎖存器的內容，然後在CPU進行加1操作，再輸出到I/O上，這就是「讀—修改—寫」操作。

[7]. 減1指令（4條）
這組指令的作用是把所指的寄存器內容減1，結果送回原寄存器，若原寄存器的內容為00H，減1後即為FFH，運算結果不影響任何標志位，這組指令共有直接、寄存器、寄存器間址等定址方式，當直接地址是I/O口鎖存器時，「讀—修改—寫」操作與加1指令類似。

DEC A ;（A）-1→（A）累加器A中的內容減1，結果送回累加器A中
DEC data ;（data）-1→（data）直接地址單元中的內容減1，結果送回直接地址單元中
DEC @Ri ;（（Ri））-1→（（Ri））寄存器Ri指向的地址單元中的內容減1，結果送回原地址單元中

DEC Rn ;（Rn）-1→（Rn）寄存器Rn中的內容減1，結果送回寄存器Rn中

[8]. 十進制調整指令（1條）
在進行BCD碼運算時，這條指令總是跟在ADD或ADDC指令之後，其功能是將執行加法運算後存於累加器A中的結果進行調整和修正。

DA A

MCS-51邏輯運算及移位指令

邏輯運算和移位指令共有25條，有與、或、異或、求反、左右移位、清0等邏輯操作，有直接、寄存器和寄存器間址等定址方式。這類指令一般不影響程序狀態字（PSW）標志。

[1]. 循環移位指令（4條）
這4條指令的作用是將累加器中的內容循環左或右移一位，後兩條指令是連同進位位CY一起移位。

RL A ;累加器A中的內容左移一位
RR A ;累加器A中的內容右移一位
RLC A ;累加器A中的內容連同進位位CY左移一位
RRC A ;累加器A中的內容連同進位位CY右移一位

[2]. 累加器半位元組交換指令（1條）
這條指令是將累加器中的內容高低半位元組互換，這在上一節中內容已有介紹。

SWAP A ; 累加器中的內容高低半位元組互換

[3]. 求反指令（1條）
這條指令將累加器中的內容按位取反。

CPL A ; 累加器中的內容按位取反

[4]. 清零指令（1條）
這條指令將累加器中的內容清0。

CLR A ; 0→（A），累加器中的內容清0

[5]. 邏輯與操作指令（6條）
這組指令的作用是將兩個單元中的內容執行邏輯與操作。如果直接地址是I/O地址，則為「讀—修改—寫」操作。

ANL A,data ;累加器A中的內容和直接地址單元中的內容執行與邏輯操作。結果存在寄存器A中。
ANL data,#data ;直接地址單元中的內容和立即數執行與邏輯操作。結果存在直接地址單元中。
ANL A,#data ;累加器A的內容和立即數執行與邏輯操作。結果存在累加器A中。
ANL A,Rn ;累加器A的內容和寄存器Rn中的內容執行與邏輯操作。結果存在累加器A中。
ANL data,A ;直接地址單元中的內容和累加器A的內容執行與邏輯操作。結果存在直接地址單元中。
ANL A,@Ri ;累加器A的內容和工作寄存器Ri指向的地址單元中的內容執行與邏輯操作。結果存在累加器A中。

[6]. 邏輯或操作指令（6條）
這組指令的作用是將兩個單元中的內容執行邏輯或操作。如果直接地址是I/O地址，則為「讀—修改—寫」操作。

ORL A,data ;累加器A中的內容和直接地址單元中的內容執行邏輯或操作。結果存在寄存器A中。
ORL data,#data ;直接地址單元中的內容和立即數執行邏輯或操作。結果存在直接地址單元中。
ORL A,#data ;累加器A的內容和立即數執行邏輯或操作。結果存在累加器A中。
ORL A,Rn ;累加器A的內容和寄存器Rn中的內容執行邏輯或操作。結果存在累加器A中。
ORL data,A ;直接地址單元中的內容和累加器A的內容執行邏輯或操作。結果存在直接地址單元中。
ORL A,@Ri ;累加器A的內容和工作寄存器Ri指向的地址單元中的內容執行邏輯或操作。結果存在累加器A中。

[7]. 邏輯異或操作指令（6條）
這組指令的作用是將兩個單元中的內容執行邏輯異或操作。如果直接地址是I/O地址，則為「讀—修改—寫」操作。

XRL A,data ;累加器A中的內容和直接地址單元中的內容執行邏輯異或操作。結果存在寄存器A中。
XRL data,#data ;直接地址單元中的內容和立即數執行邏輯異或操作。結果存在直接地址單元中。
XRL A,#data ;累加器A的內容和立即數執行邏輯異或操作。結果存在累加器A中。
XRL A,Rn ;累加器A的內容和寄存器Rn中的內容執行邏輯異或操作。結果存在累加器A中。
XRL data,A ;直接地址單元中的內容和累加器A的內容執行邏輯異或操作。結果存在直接地址單元中。
XRL A,@Ri ;累加器A的內容和工作寄存器Ri指向的地址單元中的內容執行邏輯異或操作。結果存在累加器A中。

MCS-51控制轉移指令

控制轉移指令用於控製程序的流向，所控制的范圍即為程序存儲器區間，MCS-51系列單片機的控制轉移指令相對豐富，有可對64kB程序空間地址單元進行訪問的長調用、長轉移指令，也有可對2kB位元組進行訪問的絕對調用和絕對轉移指令，還有在一頁范圍內短相對轉移及其它無條件轉移指令，這些指令的執行一般都不會對標志位有影響。

[1]. 無條件轉移指令（4條）
這組指令執行完後，程序就會無條件轉移到指令所指向的地址上去。長轉移指令訪問的程序存儲器空間為16地址64kB，絕對轉移指令訪問的程序存儲器空間為11位地址2kB空間。

LJMP addr16 ;addr16→（PC），給程序計數器賦予新值（16位地址）

AJMP addr11 ;（PC）+2→（PC），addr11→（PC 10-0 ）程序計數器賦予新值（11位地址），（PC 15-11 ）不改變

SJMP rel ;（PC）+ 2 + rel→（PC）當前程序計數器先加上2再加上偏移量給程序計數器賦予新值

JMP @A+DPTR ;（A）+ （DPTR）→（PC），累加器所指向地址單元的值加上數據指針的值給程序計數器賦予新值

[2]. 條件轉移指令（8條）
程序可利用這組豐富的指令根據當前的條件進行判斷，看是否滿足某種特定的條件，從而控製程序的轉向。

JZ rel ; A=0,（PC）+ 2 + rel→（PC）,累加器中的內容為0，則轉移到偏移量所指向的地址，否則程序往下執行

JNZ rel ; A≠0,（PC）+ 2 + rel→（PC）,累加器中的內容不為0，則轉移到偏移量所指向的地址，否則程序往下執行

CJNE A, data, rel ; A≠（data）,（PC）+ 3 + rel→（PC）,累加器中的內容不等於直接地址單元的內容，則轉移到偏移量所指向的地址，否則程序往下執行

CJNE A, #data, rel ; A≠#data,（PC）+ 3 + rel→（PC）,累加器中的內容不等於立即數，則轉移到偏移量所指向的地址，否則程序往下執行

CJNE Rn, #data, rel ; A≠#data,（PC）+ 3 + rel→（PC）,工作寄存器Rn中的內容不等於立即數，則轉移到偏移量所指向的地址，否則程序往下執行

CJNE @Ri, #data, rel ; A≠#data,（PC）+ 3 + rel→（PC）,工作寄存器Ri指向地址單元中的內容不等於立即數，則轉移到偏移量所指向的地址，否則程序往下執行

DJNZ Rn, rel ; （Rn）-1→（Rn),（Rn)≠0,（PC）+ 2 + rel→（PC）工作寄存器Rn減1不等於0，則轉移到偏移量所指向的地址，否則程序往下執行

DJNZ data, rel ; （Rn）-1→（Rn),（Rn)≠0,（PC）+ 2 + rel→（PC）直接地址單元中的內容減1不等於0，則轉移到偏移量所指向的地址，否則程序往下執行

[3]. 子程序調用指令（1條）
子程序是為了便於程序編寫，減少那些需反復執行的程序佔用多餘的地址空間而引入的程序分支，從而有了主程序和子程序的概念，需要反復執行的一些程序，我們在編程時一般都把它們編寫成子程序，當需要用它們時，就用一個調用命令使程序按調用的地址去執行，這就需要子程序的調用指令和返回指令。

LCALL addr16 ; 長調用指令，可在64kB空間調用子程序。此時（PC）+ 3→（PC），（SP）+ 1→（SP），（PC 7-0 ）→（SP），（SP）+ 1→（SP），（PC 15-8 ）→（SP），addr16→（PC），即分別從堆棧中彈出調用子程序時壓入的返回地址

ACALL addr11 ; 絕對調用指令，可在2kB空間調用子程序，此時（PC）+ 2→（PC），（SP）+ 1→（SP），（PC 7-0 ）→（SP），（SP）+ 1→（SP），（PC 15-8 ）→（SP），addr11→（PC 10-0 ）

RET ; 子程序返回指令。此時（SP）→（PC 15-8 ），（SP）- 1→（SP），（SP）→（PC 7-0 ），（SP）- 1→（SP）

RETI ; 中斷返回指令，除具有RET功能外，還具有恢復中斷邏輯的功能，需注意的是，RETI指令不能用RET代替

[4]. 空操作指令（1條）
這條指令將累加器中的內容清0。

NOP ; 這條指令除了使PC加1，消耗一個機器周期外，沒有執行任何操作。可用於短時間的延時

MCS-51布爾變數操作指令

布爾處理功能是MCS-51系列單片機的一個重要特徵，這是出於實際應用需要而設置的。布爾變數也即開關變數，它是以位（bit）為單位進行操作的。

在物理結構上，MCS-51單片機有一個布爾處理機，它以進位標志做為累加位，以內部RAM可定址的128個為存儲位。

既然有布爾處理機功能，所以也就有相應的布爾操作指令集，下面我們分別談論。

[1]. 位傳送指令（2條）
位傳送指令就是可定址位與累加位CY之間的傳送，指令有兩條。

MOV C,bit ;bit→CY，某位數據送CY

MOV bit,C ;CY→bit，CY數據送某位

[2]. 位置位復位指令（4條）
這些指令對CY及可定址位進行置位或復位操作，共有四條指令。

CLR C ; 0→CY,清CY

CLR bit ; 0→bit,清某一位

SETB C ; 1→CY,置位CY

SETB bit ; 1→bit,置位某一位

[3]. 位運算指令（6條）
位運算都是邏輯運算，有與、或、非三種指令，共六條。

ANL C,bit ;(CY)∧(bit)→CY

ANL C,/bit ;(CY)∧( )→CY

ORL C,bit ;(CY)∨(bit)→CY

ORL C,/bit ;(CY)∧( )→CY

CPL C ;( )→CY

CPL bit ;( )→bir

[4]. 位控制轉移指令（5）
位控制轉移指令是以位的狀態作為實現程序轉移的判斷條件，介紹如下：

JC rel ; (CY)=1轉移，（PC）+2+rel→PC，否則程序往下執行，（PC）+2→PC。

JNC rel ; (CY)=0轉移，（PC）+2+rel→PC，否則程序往下執行，（PC）+2→PC。

JB bit, rel ; 位狀態為1轉移。

JNB bit, rel ; 位狀態為0轉移。

JBC bit, rel ; 位狀態為1轉移，並使該位清「0」。

後三條指令都是三位元組指令，如果條件滿足，（PC）+3+rel→PC，否則程序往下執行，（PC）+3→PC

❺ 8051單片機匯編程序請教

你的第二次修改，還有一處不足：
……
;CLR C
MOV DPTR,#TABLE
LOOP:
CLR A ;這里少了一句，下面每次讀出的，
;就不知道是什麼了
MOVC A,@A+DPTR
JNZ CONT_P
INC R2
SJMP NEXT
……

可以正常計數的程序如下。
;=========================================
ORG 0H
MOV A,#00H
MOV R2,A
MOV R3,A
MOV R4,A
MOV R6,A
MOV R5,#40
;CLR C
MOV DPTR,#TABLE
LOOP:
CLR A
MOVC A,@A+DPTR
JNZ CONT_P
; CJNE A,#00H,CONT_P
INC R2
SJMP NEXT
CONT_P:
JB ACC.7, CONT_N
INC R3
SJMP NEXT
CONT_N:
INC R4
NEXT:
INC DPTR
DJNZ R5, LOOP
MOV P0,R4
SJMP $
; 實際個數 保存單元 統計個數
;零個數 14 R2 21
;正數個數 19 R3 19
;負數個數: 7 R4 0
;其實是零和負數沒有分開統計,請高手指教一下,謝謝!

ORG 400H
TABLE:
DB 01H, 15H, 22H,0FFH, 00H, 02H, 09H,0F9H, 00H, 00H
DB 01H, 15H, 22H,0FFH, 00H, 02H, 09H,0F9H, 00H, 00H
DB 01H, 15H, 22H,0FFH, 00H, 02H, 09H,0F9H, 00H, 00H
DB 02H, 05H, 00H,0FFH, 26H, 34H, 00H, 00H, 00H, 00H
END

❻ 8051怎麼讀取rom中的內容

假設您使用的是8051單片機，下面是一種可能的匯編語言代碼實現，將ROM 2000H單元中的內容傳送到內部RAM 20H單元中：

cssCopy codeMOV DPTR,#2000H ; 將ROM地址2000H的內容存儲到DPTR寄存器中
MOV A,@DPTR ; 將DPTR寄存器中地址對應的ROM中的值傳送到累加器A中
MOV @20H,A ; 將累加器A中的值傳送到內部RAM 20H單元中

解釋：

• MOV DPTR,#2000H：將ROM地址2000H存儲到DPTR寄存器中。

• MOV A,@DPTR：將DPTR寄存器中地址對應的ROM中的值傳送到累加器A中。

• MOV @20H,A：將累加器A中的值傳送到內部RAM 20H單元中。

需要注意的是，具體的實現方式可能會因單片機型號、編譯器等因素而有所不同。