单片机控制时钟电路设计

A. 用单片机设计时钟电路

呵呵！我这有，有汇编的还有C语言的，显示方式为：00-00-00，按第一个键秒加一，按第二个分加一，第三个时加一，P0口控制数码管（共阴极）的位选，P3口控制段选，三个按键分别为：P1，0、P1，1、P1，2
汇编如下（不晓楼主意下如何）：
S_SET BIT P1.0 ;数字钟秒控制位
M_SET BIT P1.1 ;分钟控制位
H_SET BIT P1.2 ;小时控制位
SECOND EQU 30H
MINUTE EQU 31H
HOUR EQU 32H
TCNT EQU 34H
ORG 00H
SJMP START
ORG 0BH
LJMP INT_T0
START:MOV DPTR,#TABLE
MOV HOUR,#0 ;初始化
MOV MINUTE,#0
MOV SECOND,#0
MOV TCNT,#0
MOV TMOD,#01H
MOV TH0,#(65536-50000)/256 ;定时50毫秒
MOV TL0,#(65536-50000)MOD 256
MOV IE,#82H
SETB TR0
;****************************************************
;判断是否有控制键按下,是哪一个键按下
A1: LCALL DISPLAY
JNB S_SET,S1
JNB M_SET,S2
JNB H_SET,S3
LJMP A1
S1: LCALL DELAY ;去抖动
JB S_SET,A1

INC SECOND ;秒值加1
MOV A,SECOND
CJNE A,#60,J0 ;判断是否加到60秒
MOV SECOND,#0
LJMP K1
S2: LCALL DELAY
JB M_SET,A1

K1: INC MINUTE ;分钟值加1
MOV A,MINUTE
CJNE A,#60,J1 ;判断是否加到60分
MOV MINUTE,#0
LJMP K2
S3: LCALL DELAY
JB H_SET,A1

K2: INC HOUR ;小时值加1
MOV A,HOUR
CJNE A,#24,J2 ;判断是否加到24小时
MOV HOUR,#0
MOV MINUTE,#0
MOV SECOND,#0
LJMP A1
;****************************************************
;等待按键抬起
J0: JB S_SET,A1
LCALL DISPLAY
SJMP J0
J1: JB M_SET,A1
LCALL DISPLAY
SJMP J1
J2: JB H_SET,A1
LCALL DISPLAY
SJMP J2
;***********************************************
;定时器中断服务程序,对秒,分钟和小时的计数
INT_T0:MOV TH0,#(65536-50000)/256
MOV TL0,#(65536-50000)MOD 256
INC TCNT
MOV A,TCNT
CJNE A,#20,RETUNE ;计时1秒
INC SECOND
MOV TCNT,#0
MOV A,SECOND
CJNE A,#60,RETUNE
INC MINUTE
MOV SECOND,#0
MOV A,MINUTE
CJNE A,#60,RETUNE
INC HOUR
MOV MINUTE,#0
MOV A,HOUR
CJNE A,#24,RETUNE
MOV HOUR,#0
MOV MINUTE,#0
MOV SECOND,#0
MOV TCNT,#0
RETUNE:RETI
;******************************************
;显示控制子程序
DISPLAY:MOV A,SECOND ;显示秒
MOV B,#10
DIV AB
CLR P3.6
MOVC A,@A+DPTR
MOV P0,A
LCALL DELAY
SETB P3.6
MOV A,B
CLR P3.7
MOVC A,@A+DPTR
MOV P0,A
LCALL DELAY
SETB P3.7

CLR P3.5
MOV P0,#40H ;显示分隔符
LCALL DELAY
SETB P3.5

MOV A,MINUTE ;显示分钟
MOV B,#10
DIV AB
CLR P3.3
MOVC A,@A+DPTR
MOV P0,A
LCALL DELAY
SETB P3.3
MOV A,B
CLR P3.4
MOVC A,@A+DPTR
MOV P0,A
LCALL DELAY
SETB P3.4

CLR P3.2
MOV P0,#40H ;显示分隔符
LCALL DELAY
SETB P3.2

MOV A,HOUR ;显示小时
MOV B,#10
DIV AB
CLR P3.0
MOVC A,@A+DPTR
MOV P0,A
LCALL DELAY
SETB P3.0
MOV A,B
CLR P3.1
MOVC A,@A+DPTR
MOV P0,A
LCALL DELAY
SETB P3.1
RET

TABLE:DB 3FH,06H,5BH,4FH,66H
DB 6DH,7DH,07H,7FH,6FH
DELAY:MOV R6,#10
D1: MOV R7,#249
DJNZ R7,$
DJNZ R6,D1
RET

END

B. C51单片机电子时钟设计思路

用定时器，设置定时时间为20毫秒，50次累加=1秒，累加秒数据60次=1分，依次类推。每次中断完成累加和显示（动态，刷新频率50HZ，应该不会闪烁）

C. 时钟电路原理及原理图

一、时钟电路原理
时钟电路，就是产生象时钟一样准确的振荡电路。时钟电路主要由晶体振荡器、晶震控制芯片和电容三部分构成，具有价格低廉、接口简单、使用方便等特点，目前已有了很广泛的应用，如电子表的时钟电路、电脑的时钟电路、MP3/4的时钟电路等。目前流行的串行时钟电路有DS1302、DS1307、PCF8485等，其中，DS1302是DALLAS公司的一种具有涓细电流充电能力的电路，采用串行数据传输，并为掉电保护电源提供可编程的充电功能。本文我们就以DS1302为例来对时钟电路原理进行详细的讲解。

二、时钟电路原理- -引脚
实时时钟电路DS1302包括VCC1、VCC2、X1、X2、SCLK、I/O、RST、GND八个引脚。其中，VCC1用作主电源，VCC2用作备用电源，当满足VCC1>VCC2时，由主电源向DS1302供电，当满足VCC2>VCC1+0.2时，由备用电源向DS1302进行供电;X1和X2是32867Hz的晶振管脚，主要用于为芯片提供时钟脉冲;SCLK为串行时钟，主要用于提供时钟信号以控制数据的输入与输出;I/O为输入输出设备，用作三线接口时的双向数据线;RST主要提供复位功能，其在数据的读写过程中，必须保持为高电位;GND引脚用于和大地相连。

三、时钟电路原理
DS1302的控制字节的最高有效位即位7必须是逻辑1，若该位为0，则不能把该数据写入进DS1302中;位6为1表示存取RAM数据，为0表示存取日历时钟数据;位5至位1表示操作单元的地址;最低有效位即位0为1表示要进行读操作，为0表示要进行写操作;其控制字节总是从最低位开始进行输出。

在控制指令字输入后的下一个SCLK时钟的上升沿时，数据被写入DS1302，数据输入从最低有效位即位0开始。同样，在紧跟8位的控制指令字后的下一个SCLK脉冲的下降沿读出DS1302的数据，数据输出时也是从最低有效位即位0开始。

D. 采用单片机控制的时钟计时器的设计 内容： 以MCS-51单片机为核心，设计并制作时钟计时器，用6位LED数码管

KEYVAL EQU 30H
KEYTM EQU 31H
KEYSCAN EQU 32H
DAT EQU 33H
SCANLED EQU 39H
CLK EQU 77H
SEC EQU 78H
MIN EQU 79H
HOUR EQU 7AH
PAUSE BIT 00H
DOT BIT 01H
ORG 0000H
LJMP MAIN
ORG 000BH
LJMP T0ISR ;50ms定时
ORG 001BH
LJMP T1ISR ;扫描显示
ORG 0030H
MAIN:
MOV SP,#5FH
MOV TMOD,#11H
MOV TH0,#03CH
MOV TL0,#0B0H
MOV TH1,#0ECH
MOV TL1,#078H
MOV KEYVAL,#0
MOV SCANLED,#0
MOV 33H,#10H
MOV 34H,#10H
MOV 35H,#10H
MOV 36H,#10H
MOV 37H,#10H
MOV 38H,#10H
MOV SEC,#0
MOV MIN,#0
MOV HOUR,#0
MOV CLK,#0
CLR PAUSE
SETB EA
SETB ET1
SETB TR1
LOOP:
LCALL KEYSEL
MOV A,KEYVAL
CJNE A,#0FFH,LOOP1
SJMP LOOP
LOOP1:
CJNE A,#10,LOOP2 ;“ON”启动
SETB TR0
SETB ET0
SETB PAUSE
SJMP LOOP
LOOP2:
CJNE A,#11,LOOP3 ;“=”清零
MOV SEC,#0
MOV MIN,#0
MOV HOUR,#0
LCALL DISCHG
SJMP LOOP
LOOP3:
CJNE A,#15,LOOP4 ;“+”暂停
CLR TR0
CLR ET0
CLR PAUSE
SJMP LOOP
LOOP4:
CJNE A,#14,LOOP5 ;“-”清显示暂停
MOV 33H,#10H
MOV 34H,#10H
MOV 35H,#10H
MOV 36H,#10H
MOV 37H,#10H
MOV 38H,#10H
CLR TR0
CLR ET0
CLR PAUSE
SJMP LOOP
LOOP5:
CJNE A,#10,LOOP6 ;数字键
LOOP6:
JC LOOP7
LJMP LOOP
LOOP7:
JNB PAUSE,LOOP8 ;暂停状态可以输入数字键
LJMP LOOP
LOOP8:
MOV 33H,34H
MOV 34H,35H
MOV 35H,36H
MOV 36H,37H
MOV 37H,38H
MOV 38H,KEYVAL
MOV A,33H
SWAP A
ORL A,34H
LCALL BCDH
MOV HOUR,A
MOV A,35H
SWAP A
ORL A,36H
LCALL BCDH
MOV MIN,A
MOV A,37H
SWAP A
ORL A,38H
LCALL BCDH
MOV SEC,A
LJMP LOOP

;------------------
;BCD转换为十六进制
BCDH:
MOV B,#10H
DIV AB
MOV R7,B
MOV B,#10
MUL AB
ADD A,R7
RET
;------------------
;十六进制转换为BCD
HBCD:
MOV B,#10
DIV AB
SWAP A
ORL A,B
RET
;------------------
KEYSEL:
MOV KEYVAL,#0
MOV KEYSCAN,#0EFH
LCALL GETKEY
MOV A,KEYTM
JZ KEYS1
MOV KEYVAL,A
SJMP KEYRTN
KEYS1:
MOV KEYSCAN,#0DFH
LCALL GETKEY
MOV A,KEYTM
JZ KEYS2
CLR C
ADD A,#4
MOV KEYVAL,A
SJMP KEYRTN
KEYS2:
MOV KEYSCAN,#0BFH
LCALL GETKEY
MOV A,KEYTM
JZ KEYS3
CLR C
ADD A,#8
MOV KEYVAL,A
SJMP KEYRTN
KEYS3:
MOV KEYSCAN,#7FH
LCALL GETKEY
MOV A,KEYTM
JZ KEYRTN
CLR C
ADD A,#12
MOV KEYVAL,A
KEYRTN:
LCALL CHGKEY
RET
;--------------------
GETKEY:
MOV KEYTM,#0
MOV A,KEYSCAN
MOV P3,A
NOP
MOV A,P3
ANL A,#0FH
XRL A,#0FH
JZ NOKEY
MOV R2,#10
LCALL DELAY
MOV A,P3
ANL A,#0FH
XRL A,#0FH
JZ NOKEY
MOV A,P3
ANL A,#0FH
MOV R7,A
SF:
MOV A,P3
ANL A,#0FH
XRL A,#0FH
JNZ SF
MOV A,R7
CJNE A,#0EH,NK1
MOV KEYTM,#1
SJMP NOKEY
NK1:
CJNE A,#0DH,NK2
MOV KEYTM,#2
SJMP NOKEY
NK2:
CJNE A,#0BH,NK3
MOV KEYTM,#3
SJMP NOKEY
NK3:
CJNE A,#07H,NOKEY
MOV KEYTM,#4
NOKEY: RET
;--------------------
DELAY:
MOV R3,#50
DELAY1:
MOV R4,#100
DJNZ R4,$
DJNZ R3,DELAY1
DJNZ R2,DELAY
RET
;--------------------
T0ISR:
PUSH ACC
CLR TR0
MOV TH0,#3CH
MOV TL0,#0B0H
SETB TR0
INC CLK
MOV A,CLK
CJNE A,#20,T0ISRE
MOV CLK,#0
INC SEC
MOV A,SEC
CJNE A,#60,T0ISRE
MOV SEC,#0
INC MIN
MOV A,MIN
CJNE A,#60,T0ISRE
MOV MIN,#0
INC HOUR
MOV A,HOUR
CJNE A,#24,T0ISRE
MOV SEC,#0
MOV MIN,#0
MOV HOUR,#0
T0ISRE:
LCALL DISCHG
POP ACC
RETI
;--------------------
DISCHG:
MOV A,HOUR
LCALL HBCD
PUSH ACC
ANL A,#0FH
MOV 34H,A
POP ACC
ANL A,#0F0H
SWAP A
MOV 33H,A
MOV A,MIN
LCALL HBCD
PUSH ACC
ANL A,#0FH
MOV 36H,A
POP ACC
ANL A,#0F0H
SWAP A
MOV 35H,A
MOV A,SEC
LCALL HBCD
PUSH ACC
ANL A,#0FH
MOV 38H,A
POP ACC
ANL A,#0F0H
SWAP A
MOV 37H,A
RET
;--------------------
T1ISR:
PUSH ACC
CLR TR1
MOV TH1,#0ECH
MOV TL1,#78H
SETB TR1
MOV DPTR,#LEDTAB
T100:
MOV R0,#DAT
MOV A,SCANLED
ADD A,R0
MOV R0,A
MOV A,SCANLED
JNZ T101
MOV P2,#01H
CLR DOT
SJMP T1DIS
T101:
DEC A
JNZ T102
MOV P2,#02H
SETB DOT
SJMP T1DIS
T102:
DEC A
JNZ T103
MOV P2,#04H
CLR DOT
SJMP T1DIS
T103:
DEC A
JNZ T104
MOV P2,#08H
SETB DOT
SJMP T1DIS
T104:
DEC A
JNZ T105
MOV P2,#10H
CLR DOT
SJMP T1DIS
T105:
MOV P2,#20H
CLR DOT
T1DIS:
MOV A,@R0
MOVC A,@A+DPTR
JNB DOT,T1DIS1
ORL A,#01H
T1DIS1:
CPL A
MOV P0,A
INC SCANLED
MOV A,SCANLED
CJNE A,#6,T1END
MOV SCANLED,#0
T1END:
POP ACC
RETI
;--------------------
CHGKEY:
MOV A,KEYVAL
JZ KV16
DEC A
JNZ KV01
MOV KEYVAL,#7
RET
KV01:
DEC A
JNZ KV02
MOV KEYVAL,#4
RET
KV02:
DEC A
JNZ KV03
MOV KEYVAL,#1
RET
KV03:
DEC A
JNZ KV04
MOV KEYVAL,#10
RET
KV04:
DEC A
JNZ KV05
MOV KEYVAL,#8
RET
KV05:
DEC A
JNZ KV06
MOV KEYVAL,#5
RET
KV06:
DEC A
JNZ KV07
MOV KEYVAL,#2
RET
KV07:
DEC A
JNZ KV08
MOV KEYVAL,#0
RET
KV08:
DEC A
JNZ KV09
MOV KEYVAL,#9
RET
KV09:
DEC A
JNZ KV10
MOV KEYVAL,#6
RET
KV10:
DEC A
JNZ KV11
MOV KEYVAL,#3
RET
KV11:
DEC A
JNZ KV12
MOV KEYVAL,#11
RET
KV12:
DEC A
JNZ KV13
MOV KEYVAL,#12
RET
KV13:
DEC A
JNZ KV14
MOV KEYVAL,#13
RET
KV14:
DEC A
JNZ KV15
MOV KEYVAL,#14
RET
KV15:
DEC A
JNZ KV16
MOV KEYVAL,#15
RET
KV16:
MOV KEYVAL,#0FFH
RET
;--------------------
LEDTAB: DB 0FCH ;"0" 00H
DB 60H ;"1" 01H
DB 0DAH ;"2" 02H
DB 0F2H ;"3" 03H
DB 66H ;"4" 04H
DB 0B6H ;"5" 05H
DB 0BEH ;"6" 06H
DB 0E0H ;"7" 07H
DB 0FEH ;"8" 08H
DB 0F6H ;"9" 09H
DB 0EEH ;"A" 0AH
DB 3EH ;"B" 0BH
DB 9CH ;"C" 0CH
DB 7AH ;"D" 0DH
DB 9EH ;"E" 0EH
DB 8EH ;"F" 0FH
DB 00H ;" " 10H
;--------------------
END

E. 单片机的电路怎么设计

单片机的电路要实现控制LED灯，需要以单片机最小系统的方式来实现，单片机最小系统由2部分构成：
第1部分：单片机复位电路。硬件组成：电容+电阻构成复位电路。
第2部分：单片机时钟电路。电阻组成：12MHz晶振+11pF陶瓷电容，提供单片机的工作周期。
完成单片机最小系统后再完成LED灯的控制，LED灯与单片机的IO端口连接时，需要将LED灯串联220Ω的电阻限流。然后单片机的一组IO口最多串联2个LED灯，如果要多个LED灯，那最多可以在单片机的IO口并联4组2个串接在一起的LED灯。单片机有32个IO口，如此算下来，你一个IO口做多可以控制8个LED灯，那么32个IO口，单片机可以控制256个LED灯。
关于LED的一闪一闪的问题，这个采用单片机的内部定时器即可，51单片机内部有T0、T1供给2个定时器，可以根据需要自行设定。
生活不止有眼前的苟且，还有诗和远方

头像账号也是腾讯账号。有问题可以添加@

F. 51单片机控制的电子时钟系统 毕业设计

可以用1302做
我有现成的
LCD1602
显示的，51做的
基本思路是用单片机读取1302里面的信息，处理，然后送LCD1602显示。
有兴趣可以去我博客看，里面还上传了之前我做的实物图片和PCB，可以照着做。

G. 用单片机设计一个时钟，可显示时和分，可以调时间，也要有闹钟功能，要有设计的电路图

其实不用定时中断也能实现功能：
#include<reg51.h> 主函数
unsigned char tab[]={0xc0,0xf9,0xa4,0xb0,0x99,0x92,0x82,0xf8,0x80,0x90};定义0-9数组
unsigned int tmp;定义变量
void delay(unsigned int xms)定义延时函数
{unsigned int j,i;
for(i=0;i<xms;i++)
for(j=0;j<100;j++);
}
void disp()定义子函数
{
P1=tmp;
delay(1);
P2=0xff;
tmp=tmp<<1;
}
void main( )
{

unsigned char z,s=00,m=00,h=00;给时钟初始值
while(1)
{
for(z=0;z<100;z++)
{
tmp=0x01;
P2=tab[h/10];小时显示

disp();
P2=tab[h%10];

disp();
P2=tab[m/10];分钟显示

disp();
P2=tab[m%10];

disp();
P2=tab[s/10];秒显示

disp();
P2=tab[s%10];

disp();

}
s++;
while(s==60)秒进一位，到60清0
{
m++;
s=00;
}
while(m==60)分钟进一位，到60清0

{
h++;
m=00;
}
while(h==24)小时进一位，到24清0
{
h=00;
}

}

}

H. 51单片机 可编程作息时间控制器设计

本设计是可编程作息时间控制器设计，由单片机AT89C51芯片和LCD、LED显示器，辅以必要的电路，构成一个单片机四路可调闹钟。电子钟可采用数字电路实现，也可以采用单片机来完成。LCD显示“时”，“分”，LED亮灯来表示闹钟的到来，定时时间到能发出警报声。现在是自动化高度发达的时代，特别是电子类产品都是靠内部的控制电路来实现对产品的控制，达到自动运行的目的，这就需要我们这里要做的设计中的电器元件及电路的支持。
在这次设计中主要是用AT89S51来进行定时，也结合着其他辅助电路实施控制，在定时的时候，按一下控制小时的键对小时加一；按一下控制分钟的键对分钟加一；到达预设的时间，此电路就会发出报警声音提示已经到点。
自从人类学会计时开始，计时方式由在木棍和骨头上刻标记，随着人类智慧的发展，到后面使用计时工具不断改进，从最开始的圭表、日冕、漏壶、漏箭、机械闹钟、秒表、沙漏、怀表、自摆钟、石英钟等。现在，高精度的计时工具大多数采用石英晶体振荡器，走时精度高，稳定性好，使用方便，不需要经常调校。而后经发展，数字式电子钟采用集成电路设计时，译码代替机械式传动，LED显示器代替指针显示时间，减少计时误差。这种电子时钟具备实现时、分、秒功能，同时进行校对。外观时尚，使用方便，深受消费者青睐。

I. 单片机时钟程序编写及电路设计方面的一些问题

单片机简介可以说，二十世纪跨越了三个“电”的时代，即电气时代、电子时代和现已进入的电脑时代。不过，这种电脑，通常是指个人计算机，简称PC机。它由主机、键盘、显示器等组成。还有一类计算机，大多数人却不怎么熟悉。这种计算机就是把智能赋予各种机械的单片机（亦称微控制器）。顾名思义，这种计算机的最小系统只用了一片集成电路，即可进行简单运算和控制。因为它体积小，通常都藏在被控机械的“肚子”里。它在整个装置中，起着有如人类头脑的作用，它出了毛病，整个装置就瘫痪了。现在，这种单片机的使用领域已十分广泛，如智能仪表、实时工控、通讯设备、导航系统、家用电器等。各种产品一旦用上了单片机，就能起到使产品升级换代的功效，常在产品名称前冠以形容词——“智能型”，如智能型洗衣机等。现在有些工厂的技术人员或其它业余电子开发者搞出来的某些产品，不是电路太复杂，就是功能太简单且极易被仿制。究其原因，可能就卡在产品未使用单片机或其它可编程逻辑器件上。
学习单片机是否很困难呢？应当说，对于已经具有电子电路，尤其是数字电路基本知识的读者来说，不会有太大困难，如果你对PC机有一定基础，学习单片机就更容易。为使绝大多数读者能用上单片机。我们这里将尽量按深入浅出、删繁就简、理论联系实际的原则把单片机的基本工作原理、使用方法交给读者，以达到把大家领进单片机之“门”的目的。不过，单片机和PC机一样，是实践性很强的一门技术，有人说“计算机是玩出来的”，单片机亦一样，只有多“玩”，也就是多练习、多实际操作，才能真正掌握它。因此，本讲座会提供各种练习和实验，并介绍一些适用于初学者且性价比较高的单片机和开发系统的货源。你只有认真完成成这些实践环节，才能为进一步深造，打好基础。

单片机的组成
单片机要自动完成计算，它应该具有哪些最重要的部分呢？
我们以打算盘为例计算一道算术题。例：36＋163×156－166÷34。现在要进行运算，首先需要一把算盘，其次是纸和笔。我们把要计算的问题记录下来，然后第一步先算163×156，把它与36相加的结果记在纸上，然后计算166÷34，再把它从上一次结果中减去，就得到最后的结果。
现在，我们用单片机来完成上述过程，显然，它首先要有代替算盘进行运算的部件，这就是“运算器”；其次，要有能起到纸和笔作用的器件，即能记忆原始题目、原始数据和中间结果，还要记住使单片机能自动进行运算而编制的各种命令。这类器件就称为“存贮器”。此外，还需要有能代替人作用的控制器，它能根据事先给定的命令发出各种控制信号，使整个计算过程能一步步地进行。但是光有这三部分还不够，原始的数据与命令要输入，计算的结果要输出，都需要按先后顺序进行，有时还需等待。如上例中，当在计算163×156时，数字36就不能同时进入运算器。因此就需要在单片机上设置按控制器的命令进行动作的“门”，当运算器需要时，就让新数据进入。或者，当运算器得到最后结果时，再将此结果输出，而中间结果不能随便“溜出”单片机。这种对输入、输出数据进行一定管理的“门”电路在单片机中称为“口”（Port）。在单片机中，基本上有三类信息在流动，一类是数据，即各种原始数据（如上例中的36、163等）、中间结果（如166÷34所得的商4、余数30等）、程序（命令的集合）等。这样要由外部设备通过“口”进入单片机，再存放在存贮器中，在运算处理过程中，数据从存贮器读入运算器进行运算，运算的中间结果要存入存贮器中，或最后由运算器经“出入口”输出。用户要单片机执行的各种命令（程序）也以数据的形式由存贮器送入控制器，由控制器解读（译码）后变为各种控制信号，以便执行如加、减、乘、除等功能的各种命令。所以，这一类信息就称为控制命令，即由控制器去控制运算器一步步地进行运算和处理，又控制存贮器的读（取出数据）和写（存入数据）等。第三类信息是地址信息，其作用是告诉运算器和控制器在何处去取命令取数据，将结果存放到什么地方，通过哪个口输入和输出信息等。
存贮器又分为只读存贮器和读写存贮器两种，前者存放调试好的固定程序和常数，后者存放一些随时有可能变动的数据。顾名思义，只读存贮器一旦将数据存入，就只能读出，不能更改（EPROM、E2PROM等类型的ROM可通过一定的方法来更改、写入数据——编者注）。而读写存贮器可随时存入或读出数据。
实际上，人们往往把运算器和控制器合并称为中央处理单元——CPU。单片机除了进行运算外，还要完成控制功能。所以离不开计数和定时。因此，在单片机中就设置有定时器兼计数器，其基本结构与本连载之（二）中的举例类似。到这里为止，我们已经知道了单片机的基本组成，即单片机是由中央处理器（即CPU中的运算器和控制器）、只读存贮器（通常表示为ROM）、读写存贮器（又称随机存贮器通常表示为RAM）、输入/输出口（又分为并行口和串行口，表示为I/O口）等等组成。实际上单片机里面还有一个时钟电路，使单片机在进行运算和控制时，都能有节奏地进行。另外，还有所谓的“中断系统”，这个系统有“传达室”的作用，当单片机控制对象的参数到达某个需要加以干预的状态时，就可经此“传达室”通报给CPU，使CPU根据外部事态的轻重缓急来采取适当的应付措施。
现在，我们已经知道了单片机的组成，余下的问题是如何将它们的各部分连接成相互关联的整体呢？实际上，单片机内部有一条将它们连接起来的“纽带”，即所谓的“内部总线”。此总线有如大城市的“干道”，而CPU、ROM、RAM、I/O口、中断系统等就分布在此“总线”的两旁，并和它连通。从而，一切指令、数据都可经内部总线传送，有如大城市内各种物品的传送都经过干道进行。
单片机的指令系统和汇编语言程序
前面已经讲述了单片机的几个主要组成部分，这些部分构成了单片机的硬件。所谓硬件（Hardware），就是看得到，摸得到的实体。但是，光有这样的硬件，还只是有了实现计算和控制功能的可能性。单片机要真正地能进行计算和控制，还必须有软件（Software）的配合。软件主要指的是各种程序。只有将各种正确的程序“灌入”（存入）单片机，它才能有效地工作。单片机所以能自动地进行运算和控制，正是由于人把实现计算和控制的步骤一步步地用命令的形式，即一条条指令（Instruction）预先存入到存贮器中，单片机在CPU的控制下，将指令一条条地取出来，并加以翻译和执行。就以两个数相加这一简单的运算来说，当需要运算的数已存入存贮器后，还需要进行以下几步: 第一步：把第一个数从它的存贮单元（Location）中取出来，送至运算器。
第二步：把第二个数从它所在的存贮单元中取出来，送至运算器；
第三步：相加；
第四步：把相加完的结果，送至存贮器中指定的单元。
所有这些取数、送数、相加、存数等等都是一种操作（Operation），我们把要求计算机执行的各种操作用命令的形式写下来，这就是指令。但是怎样才能辨别和执行这些操作呢？这是在设计单片机时由设计人员赋予它的指令系统所决定的。一条指令，对应着一种基本操作；单片机所能执行的全部指令，就是该单片机的指令系统（Iustruction Set），不同种类的单片机，其指令系统亦不同。
使用单片机时，事先应当把要解决的问题编成一系列指令。这些指令必须是选定的单片机能识别和执行的指令。单片机用户为解决自己的问题所编的指令程序，称为源程序（Source Program）。指令通常分为操作码（Opcode）和操作数（Operand）两大部分。操作码表示计算机执行什么操作，即指令的功能；操作数表示参加操作的数或操作数所在的地址（即操作数所存放的地方编号）。因为单片机是一种可编程器件，只“认得”二进码（0、1）。要单片机运作，单片机系统中的所有指令，都必须以二进制编码的形式来表示。例如，在Intel公司的MCS－51系列单片机中，从存贮器中取出一数到CPU中的累加器（在运算器中，参与运算、存放运算结果的专用寄存器）的指令代码为74H，累加器内容加立即数的代码为24H，再加上立即数代码，累加器送数到内部RAM存贮器的代码为F6H～F7H等。这些指令是用十六进制表示二进制的机器码。MCS－51单片机的字长为8位，有时，要完成某些操作用一个字节尚不能充分表达。所以，在指令系统中有单字节指令，也有多字节指令。机器码是由一连串的0和1组成，没有明显的特征，不好记忆，不易理解，易出错。所以，直接用它来编写程序十分困难。因而，人们就用一些助记符（Mue monic）——通常是指令功能的英文缩写来代替操作码，如MCS－51中数的传送常用MOV（Move的缩写）、加法用Add(Addition的缩写）来作为助记符。这样，每条指令有明显的动作特征，易于记忆和理解，也不容易出错。用助记符来编写的程序称为汇编语言程序。但是，助记符编写的程序便于人理解，可单片机却只认识二进制机器代码，因此，为了让单片机能“读懂”汇编语言程序必须再转换成由二进制机器码构成的程序，这种转换过程，就称为“汇编”。汇编可借助于人工查表法来实现，也可借助PC机通过所谓“交叉汇编程序”来完成。由机器码构成的用户程序一旦“进入”了单片机，再“启动”单片机，就可让它执行输入程序所规定的任务。
MCS-51的CPU和存储器
CPU结构
单片机8051的CPU由运算器和控制器组成。
一、运算器
运算器以完成二进制的算术/逻辑运算部件ALU为核心，再加上暂存器TMP、累加器ACC、寄存器B、程序状态标志寄存器PSW及布尔处理器。累加器ACC是一个八位寄存器，它是CPU中工作最频繁的寄存器。在进行算术、逻辑运算时，累加器ACC往往在运算前暂存一个操作数（如被加数），而运算后又保存其结果（如代数和）。寄存器B主要用于乘法和除法操作。标志寄存器PSW也是一个八位寄存器，用来存放运算结果的一些特征，如有无进位、借位等。其每位的具体含意如下所示。PSW
CY AC FO RS1 RS0 OV － P对用户来讲，最关心的是以下四位。
1�进位标志CY（PSW�7）。它表示了运算是否有进位（或借位）。如果操作结果在最高位有进位（加法）或者借位（减法），则该位为1，否则为0。
2�辅助进位标志AC。又称半进位标志，它反映了两个八位数运算低四位是否有半进位，即低四位相加（或减）有否进位（或借位），如有则AC为1状态，否则为0。
3�溢出标志位OV。MCS－51反映带符号数的运算结果是否有溢出，有溢出时，此位为1，否则为0。
4�奇偶标志P。反映累加器ACC内容的奇偶性，如果ACC中的运算结果有偶数个1（如11001100B，其中有4个1），则P为0，否则，P=1。
PSW的其它位，将在以后再介绍。由于PSW存放程序执行中的状态，故又叫程序状态字.运算器中还有一个按位（bit）进行逻辑运算的逻辑处理机（又称布尔处理机）。其功能在介绍位指令时再说明。
二、控制器
控制器是CPU的神经中枢，它包括定时控制逻辑电路、指令寄存器、译码器、地址指针DPTR及程序计数器PC、堆栈指针SP等。这里程序计数器PC是由16位寄存器构成的计数器。要单片机执行一个程序，就必须把该程序按顺序预先装入存储器ROM的某个区域。单片机动作时应按顺序一条条取出指令来加以执行。因此，必须有一个电路能找出指令所在的单元地址，该电路就是程序计数器PC。当单片机开始执行程序时，给PC装入第一条指令所在地址，它每取出一条指令（如为多字节指令，则每取出一个指令字节），PC的内容就自动加1，以指向下一条指令的地址，使指令能顺序执行。只有当程序遇到转移指令、子程序调用指令，或遇到中断时（后面将介绍），PC才转到所需要的地方去。8051CPU通过指定的地址，从ROM相应单元中取出指令字节放在指令寄存器中寄存，然后，指令寄存器中的指令代码被译码器译成各种形式的控制信号，这些信号与单片机时钟振荡器产生的时钟脉冲在定时与控制电路中相结合，形成按一定时间节拍变化的电平和时钟，即所谓控制信息，在CPU内部协调寄存器之间的数据传输、运算等操作。

http://www.elemcu.com/mcu%20de%20zhou%20%20cheng.htm
http://www..com/?word=%B5%A5%C6%AC%BB%FA%CA%B1%D6%D3%B3%CC%D0%F2&tn=myie2dg

J. 8051单片机时钟电路

8051单片机时钟电路如下所示：

电容C2、C3对频率有微调的作用，电容容量的选择范围在30pF±10pF。震荡频率的选择范围为1.2-12MHz。时钟周期=石英振荡器频率的倒数。

单片机是一种集成电路芯片，是采用超大规模集成电路技术把具有数据处理能力的中央处理器CPU、随机存储器RAM、只读存储器ROM、多种I/O口和中断系统、定时器/计数器等功能（可能还包括显示驱动电路、脉宽调制电路、模拟多路转换器、A/D转换器等电路）集成到一块硅片上构成的一个小而完善的微型计算机系统，在工业控制领域广泛应用。