① 求单片机C51红外线收发方案(最好有详细解释)
红外线遥控器解码程序
2007-02-07 18:52 红外线遥控是目前使用最广泛的一种通信和遥控手段。由于红外线遥控装置具有体积小、功耗低、功能强、成本低等特点，因而，继彩电、录像机之后，在录音机、音响设备、空凋机以及玩具等其它小型电器装置上也纷纷采用红外线遥控。现在工业设备中，也已经广泛在使用。。。。。
1 红外遥控系统
通用红外遥控系统由发射和接收两大部分组成，应用编/解码专用集成电路芯片来进行控制操作，如图1所示。发射部分包括键盘矩阵、编码调制、LED红外发送器；接收部分包括光、电转换放大器、解调、解码电路。
2 遥控发射器及其编码
遥控发射器专用芯片很多，根据编码格式可以分成脉冲宽度调制和脉冲相位调制两大类，这里我们以运用比较广泛，解码比较容易的脉冲宽度调制来加以说明，现以3310组成发射电路为例说明编码原理。当发射器按键按下后，即有遥控码发出，所按的键不同遥控编码也不同。这种遥控码具有以下特征：
采用脉宽调制的串行码，以脉宽为0.565ms、间隔0.56ms、周期为1.125ms的组合表示二进制的“0”；以脉宽为0.565ms、间隔1.685ms、周期为2.25ms的组合表示二进制的“1”
上述“0”和“1”组成的42位二进制码经38kHz的载频进行二次调制以提高发射效率，达到降低电源功耗的目的。然后再通过红外发射二极管产生红外线向空间发射，
3310产生的遥控编码是连续的42位二进制码组，其中前26位为用户识别码，能区别不同的红外遥控设备，防止不同机种遥控码互相干扰。后16位为8位的操作码和8位的操作反码用于核对数据是否接收准确。
当遥控器上任意一个按键按下超过36ms时，LC7461芯片的振荡器使芯片激活，将发射一个特定的同步码头，对于接收端而言就是一个9ms的低电平,和一个4.5ms的高电平，这个同步码头可以使程序知道从这个同步码头以后可以开始接收数据。
解码的关键是如何识别“0”和“1”，从位的定义我们可以发现“0”、“1”均以0.56ms的低电平开始，不同的是高电平的宽度不同，“0”为0.56ms,“1”为1.68ms,所以必须根据高电平的宽度区别“0”和“1”。如果从0.56ms低电平过后，开始延时，0.56ms以后，若读到的电平为低，说明该位为“0”，反之则为“1”，为了可靠起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为“0”，读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可靠，一般取0.84ms左右即可。
根据红外编码的格式，程序应该等待9ms的起始码和4.5ms的结果码完成后才能读码。
接收器及解码
LT0038是塑封一体化红外线接收器，它是一种集红外线接收、放大、整形于一体的集成电路，不需要任何外接元件，就能完成从红外线接收到输出与TTL电平信号兼容的所有工作，没有红外遥控信号时为高电平，收到红外信号时为低电平，而体积和普通的塑封三极管大小一样，它适合于各种红外线遥控和红外线数据传输。
下面是一个对51ISP编程实验开发板配套的红外线遥控器的解码程序，它可以把红外遥控器每一个按键的键值读出来，并且通过实验板上P1口的8个LED显示出来，在解码成功的同时并且能发出“嘀嘀嘀”的提示音。
ORG 0000H
AJMP MAIN;转入主程序
ORG 0003H ;外部中断P3.2脚INT0入口地址
AJMP INT ;转入外部中断服务子程序（解码程序）
;以下为主程序进行CPU中断方式设置
MAIN:SETB EA ;打开CPU总中断请求
SETB IT0 ;设定INT0的触发方式为脉冲负边沿触发
SETB EX0 ;打开INT0中断请求
;以下对单片机的所有引脚进行初始化，全部设置成高电平
MOV P2,#11111111B
AJMP $
;以下为进入P3.2脚外部中断子程序，也就是解码程序
INT: CLR EA ;暂时关闭CPU的所有中断请求
MOV R6,#10
SB: ACALL YS1;调用882微秒延时子程序
JB P3.2,EXIT;延时882微秒后判断P3.2脚是否出现高电平如果有就退出解码程序
DJNZ R6, SB;重复10次，目的是检测在8820微秒内如果出现高电平就退出解码程序
;以上完成对遥控信号的9000微秒的初始低电平信号的识别。
JNB P3.2, $ ;等待高电平避开9毫秒低电平引导脉冲
ACALL YS2 ;延时4.74毫秒避开4.5毫秒的结果码
MOV R7,#26;忽略前26位系统识别码
JJJJA:JNB P3.2,$;等待地址码第一位的高电平信号
LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
JNC UUUA;如果为0就跳转到UUUA
LCALL YS3;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUUA: DJNZ R7,JJJJA
MOV R1,#1AH ;设定1AH为起始RAM区
MOV R2,#2;接收从1AH到1BH的2个内存,用于存放操作码和操作反码
PP: MOV R3,#8;每组数据为8位
JJJJ: JNB P3.2,$;等待地址码第一位的高电平信号
LCALL YS1;高电平开始后用882微秒的时间尺去判断信号此时的高低电平状态
MOV C,P3.2;将P3.2引脚此时的电平状态0或1存入C中
JNC UUU;如果为0就跳转到UUU
LCALL YS3;检测到高电平1的话延时1毫秒等待脉冲高电平结束
UUU: MOV A,@R1;将R1中地址的给A
RRC A;将C中的值0或1移入A中的最低位
MOV @R1,A;将A中的数暂时存放在R1数值的内存中
DJNZ R3,JJJJ;接收满8位换一个内存
INC R1;对R1中的值加1，换下一个RAM
DJNZ R2,PP ;接收完8位数据码和8位数据反码，存放在1AH/1BH中
MOV A,1AH
CPL A;对1AH取反后和1BH比较
CJNE A,1BH,EXIT;如果不等表示接收数据发生错误,放弃
MOV P1,1AH;将按键的键值通过P1口的8个LED显示出来!
CLR P2.0;蜂鸣器鸣响－嘀嘀嘀－的声音，表示解码成功
LCALL YS2
LCALL YS2
LCALL YS2
SETB P2.0;蜂鸣器停止（使用时可以将J2的YINYUE脚用跳线接J4 的XS1脚才可以使用蜂鸣器）可以看原理图
EXIT: SETB EA ;允许中断
RETI ;退出解码子程序
YS1: MOV R4,#20 ;延时子程序1，精确延时882微秒
D1: MOV R5,#20
DJNZ R5,$
DJNZ R4,D1
RET
YS2: MOV R4,#10 ;延时子程序2，精确延时4740微秒
D2: MOV R5,#235
DJNZ R5,$
DJNZ R4,D2
RET
YS3: MOV R4,#2;延时程序3，精确延时1000微秒
D3:MOV R5,#248
DJNZ R5,$
DJNZ R4,D3
RET
END
以上程序紧供参考。
0A 01
11 12 13 14
15 16 17 18
19 10 1A 1B
0E 02 03 1C
06 04 05 0C
0D 08 09 1D
00 1F 1E 0B
07 0F
这是按照红外遥控器按键的实际位置给出的32个按键的键值（16进制）
② 单片机红外发送数据,为什么接收到的都是一样的东西
单片机红外发送数据，如果接收到的都是一样的东西，
那么说明发送或者接收阶段，或者你编的单片机的原始程序出了问题。
你可以先分步测试自己的程序，如果没有问题，再测试发送和接收是否正常。
对应红外接收，误码率处理不好还是很高的，距离越远对于时间间隔的误差越大，接收时是1还是0，要允许的误差大一点，如固定数据位之间的间隔为560us，但实际可能为580us，随着距离加大可能变成700,800us都有可能，这就要求我们程序的允许误差要大些，这个要根据实际调整。
③ 51单片机红外接收端的程序怎么写,我想知道写的方法和原理,最好有一个具体的模版,好让我参考.
这是采用STC12C5A60S2单片机的红外解码程序及其说明。
;采用脉宽调制的串行码，以脉宽为0.565ms、间隔0.56ms、周期为1.125ms的组合表示二进制的"0"；
;以脉宽为0.565ms、间隔1.685ms、周期为2.25ms的组合表示二进制的"1
;上述"0"和"1"组成的32位二进制码经38kHz的载频进行二次调制以提高发射效率，
;达到降低电源功耗的目的。然后再通过红外发射二极管产生红外线向空间发射
;遥控编码是连续的32位二进制码组，其中前16位为用户识别码，能区别不同的电器设备，
;防止不同机种遥控码互相干扰。该芯片的用户识别码固定为十六进制01H
;后16位为8位操作码（功能码）及其反码。
;当一个键按下超过36ms，振荡器使芯片激活，将发射一组108ms的编码脉冲,这108ms发射代码由一个起始码（9ms）,
;一个结果码（4.5ms）,低8位地址码（9ms~18ms）,高8位地址码（9ms~18ms）,8位数据码（9ms~18ms）
;和这8位数据的反码（9ms~18ms）组成。如果键按下超过108ms仍未松开，
;接下来发射的代码（连发代码）将仅由起始码（9ms）和结束码（2.5ms）组成。
;
;解码的关键是如何识别"0"和"1"，接收端而言，"0"是0.56ms的高+0.56ms的低。"1"是1.68ms的高+0.56ms的低。
;所以可以根据高电平的宽度区别"0"和"1"。当高电平出现时开始延时，0.56ms以后，若读到的电平为低，
;说明该位为"0"，反之则为"1"，为了可靠起见，延时必须比0.56ms长些，但又不能超过1.12ms,否则如果该位为"0"，
;读到的已是下一位的高电平，因此取（1.12ms+0.56ms）/2=0.84ms最为可靠，一般取0.84ms左右均可。
;为了共用引导部分延时程序，这里用0.9ms延时。
;-------------红外解码程序---------------------------
EXINT0:
PUSH ACC
PUSH PSW
PUSH 1
PUSH 2
PUSH 6
CLR EA ;暂时关闭中断请求
MOV R6,#10
EXINT10:
LCALL DELAY09MS ;调用900us延时子程序
JB IRIN,INTOUT1 ;判断P3.2是否有高电平，如果有就退出解码程序
DJNZ R6,EXINT10 ;循环10次，检测在900微妙中是否存在高电平。以上完成对遥控信号的9000微秒的初始低电平信号的识别。
JNB IRIN,$ ;等待高电平避开9毫秒低电平引导脉冲
LCALL DELAY45MS ;延时4.5毫秒
;-------------接受32位代码--------------------------
MOV R1,#IRUSERL
MOV R2,#04H
EXINT101:
MOV R6,#08H ;每组数据位8位
EXINT102:
JNB IRIN,$ ;等待地址码第一组数据的高电平信号
LCALL DELAY09MS ;高电平开始后延时判断信号此时的高/低状态
MOV C,IRIN ;将P3.2引脚此时的电平状态0或1存入C中
JNC INT1OUT ;如果为0跳出
LCALL DELAY1MS
INT1OUT:
MOV A,@R1
RRC A ;将C中的数据0/1移入A中最低位
MOV @R1,A ;将A中的数据暂存在R1
DJNZ R6,EXINT102 ;接受完8位代码
INC R1
DJNZ R2,EXINT101 ;接受完4组32位代码
;--------------数据码比较-------------------------------
MOV A,IRDATAL
; LCALL SENDRXDAT
MOV A,IRDATAL
CPL A
CJNE A,IRDATAH,INTOUT1 ;判断数码正误，不等退出
MOV IR_DAT,IRDATAL ;相等则保存正确数据
MOV A,IR_DAT
; LCALL SENDRXDAT
SETB IRBIT
INTOUT1:
LCALL DELAY45MS
SETB EA ;允许中断
POP 6
POP 2
POP 1
POP PSW
POP ACC
RETI
;;*****************11.0592*900=9953******************
DELAY09MS: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#20 ;2
DLY900:
MOV R3,#122 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY900 ;4
MOV R4,#11 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;TOTAL=9952
;;*****************11.0592*560=6193******************
DELAY056: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#12 ;2
DLY5600:
MOV R3,#122 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY5600 ;4
MOV R4,#71 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;TOTAL=6194
;;*****************11.0592*4500=49766****************
DELAY45MS: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#52 ;2
DLY45:
MOV R3,#236 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY45 ;4
MOV R4,#85 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;;TOTAL=49768
;;*****************11.0592*1000=11059****************
DELAY1MS: ;6
PUSH 4 ;4
PUSH 3 ;4
MOV R4,#20 ;2
DLY1MS:
MOV R3,#136 ;2
DJNZ R3,$ ;4
DJNZ R4,DLY1MS ;4
MOV R4,#8 ;2
DJNZ R4,$ ;4
POP 3 ;3
POP 4 ;3
RET ;4
;TOTAL=11060
;;***************************************************
DELAY100US: ;6
PUSH 4 ;4
MOV R4,#140 ;2
DJNZ R4,$ ;4
MOV R4,#131 ;2
DJNZ R4,$ ;4
POP 4 ;3
RET ;4
;TOTAL=1105
;;***************************************************
④ 单片机红外发射
#include<reg52.h> //包含头文件，一般情况不需要改动，头文件包含特殊功能寄存器的定义
#include"1602.h"
#include"delay.h"
sbit IR=P3^2; //红外接口标志
char code Tab[16]="0123456789ABCDEF";
unsigned char irtime;//红外用全局变量
bit irpro_ok,irok;
unsigned char IRcord[4];
unsigned char irdata[33];
unsigned char TempData[16];
/*------------------------------------------------
函数声明
------------------------------------------------*/
void Ir_work(void);
void Ircordpro(void);
/*------------------------------------------------
定时器0中断处理
------------------------------------------------*/
void tim0_isr (void) interrupt 1 using 1
{
irtime++; //用于计数2个下降沿之间的时间
}
/*------------------------------------------------
外部中断0中断处理
------------------------------------------------*/
void EX0_ISR (void) interrupt 0 //外部中断0服务函数
{
static unsigned char i; //接收红外信号处理
static bit startflag; //是否开始处理标志位
if(startflag)
{
if(irtime<63&&irtime>=33)//引导码 TC9012的头码，9ms+4.5ms
i=0;
irdata[i]=irtime;//存储每个电平的持续时间，用于以后判断是0还是1
irtime=0;
i++;
if(i==33)
{
irok=1;
i=0;
}
}
else
{
irtime=0;
startflag=1;
}
}
/*------------------------------------------------
定时器0初始化
------------------------------------------------*/
void TIM0init(void)//定时器0初始化
{
TMOD=0x02;//定时器0工作方式2，TH0是重装值，TL0是初值
TH0=0x00; //重载值
TL0=0x00; //初始化值
ET0=1; //开中断
TR0=1;
}
/*------------------------------------------------
外部中断0初始化
------------------------------------------------*/
void EX0init(void)
{
IT0 = 1; //指定外部中断0下降沿触发，INT0 (P3.2)
EX0 = 1; //使能外部中断
EA = 1; //开总中断
}
/*------------------------------------------------
键值处理
------------------------------------------------*/
void Ir_work(void)
{
TempData[0] = Tab[IRcord[0]/16]; //处理客户码
TempData[1] = Tab[IRcord[0]%16];
TempData[2] = '-';
TempData[3] = Tab[IRcord[1]/16]; //处理客户码
TempData[4] = Tab[IRcord[1]%16];
TempData[5] = '-';
TempData[6] = Tab[IRcord[2]/16]; //处理数据码
TempData[7] = Tab[IRcord[2]%16];
TempData[8] = '-';
TempData[9] = Tab[IRcord[3]/16]; //处理数据反码
TempData[10] = Tab[IRcord[3]%16];
LCD_Write_String(5,1,TempData);
irpro_ok=0;//处理完成标志
}
/*------------------------------------------------
红外码值处理
------------------------------------------------*/
void Ircordpro(void)//红外码值处理函数
{
unsigned char i, j, k;
unsigned char cord,value;
k=1;
for(i=0;i<4;i++) //处理4个字节
{
for(j=1;j<=8;j++) //处理1个字节8位
{
cord=irdata[k];
if(cord>7)//大于某值为1，这个和晶振有绝对关系，这里使用12M计算，此值可以有一定误差
value|=0x80;
if(j<8)
{
value>>=1;
}
k++;
}
IRcord[i]=value;
value=0;
}
irpro_ok=1;//处理完毕标志位置1
}
/*------------------------------------------------
主函数
------------------------------------------------*/
void main(void)
{
EX0init(); //初始化外部中断
TIM0init(); //初始化定时器
LCD_Init(); //初始化液晶
DelayMs(20); //延时有助于稳定
LCD_Clear(); //清屏
LCD_Write_String(0,0,"www.doflye.net");
LCD_Write_String(0,1,"Code:");
while(1)//主循环
{
if(irok) //如果接收好了进行红外处理
{
Ircordpro();
irok=0;
}
if(irpro_ok) //如果处理好后进行工作处理，如按对应的按键后显示对应的数字等
{
Ir_work();
}
}
}
⑤ 单片机红外接收
要想通过无线系统传送数字信号，首先要把数字数据转换为串行数据才能发送。这些内容数字电路里应该会讲到。这个一般单片机很容易实现。要想用过无线传送，单片机外需加收发模块。选用33M的频率电磁波传送，单片机需外加33M的频率电磁波收发模块。如选用红外收发，单片机外加红外发射管和驱动电路红外接收模块。红外收发模块特点是线路非常简单，基本不用调试。传输范围为可是范围，距离一般10几米。电磁波收发可绕过或穿透建筑物，视其发射功率不同，可传输到很远的距离。电磁波收发模块成本较高，调试相对也麻烦。
⑥ 红外在单片机上怎么用
红外可以做单片机上做收发。你可以完全做个类似电视遥控器的系统。
红外的发射你可以通过三极管和红外发射管做一个简单发射电路。
红外的接收，你买个红外一体化接收头。这2样设备你看我的文库。里面有我详细的器件采购清单，里面有这2个东西。淘宝可以买到的。
红外的程序编写你需要详细掌握红外的协议，一般用nec公司的资料。
你学会了他们的收发时序，然后通过单片机编程，就可以实现红外的收发系统。
希望对你有用！！
⑦ 51单片机怎么接受红外线 C语言
单片机本身不能接收，只是控制器，要另加电路才能接受。
⑧ 基于单片机的红外遥控收发系统的设计与实现
红外遥控一般采用38KHz载波
⑨ 单片机的红外遥控的原理
1、发送端由单片机和红外发光二极管组成。
单片机控制红外发光二极管发射38KHz左右的红外光，这个红外光就可能起到传递信号的作用。你可以在你的程序中规定发射红外线时表示二进制的一个位‘1’无红外线时表示二进制的‘0’。这样你就可以发出一系列由‘1’和‘0’所级成的信号。
2、接收端是由红外接收二极管和单片机组成。
前面我们让发射端发出信号，现在接收头就开始收信号。
⑩ 单片机红外发射与接收电路电路搭接
红外管的阳极接单片机，阴极对地串联一个510欧姆电阻。
接收光电二极管的阳极接地，阴极接一个10K电阻，电阻另一段接电源5V，从阴极于电阻之间引线出来就是信号线，可以输出高低电平。