8051单片机汇编

❶ 求一个用汇编语言编写一个8051单片机的时钟程序（急急急啊）

给你当参缺春祥考...不足功能自己改...有问题再发问..

;P1.4小时调整伏搏 P1.5分种调整

CODE_SEG SEGMENT CODE
DATA_SEG SEGMENT DATA
STACK_SEG SEGMENT IDATA

K1 BIT P1.4
K2 BIT P1.5

RSEG DATA_SEG
KEY_S: DS 1
KEY_V: DS 1
DIS_DIGIT: DS 1
SEC: DS 1
DIS_INDEX: DS 1
HOUR: DS 1
MIN: DS 1
SEC100: DS 1
DIS_BUF: DS 8

BUF_HOUR_H EQU DIS_BUF ; 小时十位
BUF_HOUR_L EQU DIS_BUF+1 ; 小时个森氏位
BUF_MIN_H EQU DIS_BUF+3 ; 分十位
BUF_MIN_L EQU DIS_BUF+4 ; 分个位
BUF_SEC_H EQU DIS_BUF+6 ; 秒十位
BUF_SEC_L EQU DIS_BUF+7 ; 秒个位

RSEG STACK_SEG
STACK: DS 20

;===============================================================================

CSEG AT 0000H
JMP MAIN

CSEG AT 0000BH
LJMP TIMER0

CSEG AT 0001BH
LJMP TIMER1

;===============================================================================

RSEG CODE_SEG
MAIN:
USING 0

MOV SP, #(STACK-1) ;

MOV P0,#0FFH
MOV P2,#0FFH
MOV TMOD,#011H ; 定时器0, 1工作模式1, 16位定时方式
MOV TH0,#0FCH
MOV TL0,#017H
MOV TH1,#0DCH
CLR A
MOV TL1,A

MOV HOUR,#12 ;
CLR A ;
MOV MIN,A
MOV SEC,A
MOV SEC100,A

MOV A,HOUR
MOV B,#10
DIV AB
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_HOUR_H,A ; 时十位
MOV A,HOUR
MOV B,#10
DIV AB
MOV A,B
MOVC A,@A+DPTR
MOV BUF_HOUR_L,A ; 时个位
MOV A,MIN
MOV B,#10
DIV AB
MOVC A,@A+DPTR
MOV BUF_MIN_H,A ; 分十位
MOV A,MIN
MOV B,#10
DIV AB
MOV A,B
MOVC A,@A+DPTR
MOV BUF_MIN_L,A ; 分个位
MOV A,SEC
MOV B,#10
DIV AB
MOVC A,@A+DPTR
MOV BUF_SEC_H,A ; 秒十位
MOV A,SEC
MOV B,#10
DIV AB
MOV A,B
MOVC A,@A+DPTR
MOV BUF_SEC_L,A ; 秒个位

MOV BUF_HOUR_H+02H,#0BFH
MOV BUF_HOUR_H+05H,#0BFH

MOV DIS_DIGIT,#0FEH
CLR A
MOV DIS_INDEX,A

MOV IE,#08AH ; 使能timer0,1 中断

SETB TR0
SETB TR1

MOV KEY_V,#03H

MAIN_LP:
LCALL SCAN_KEY ; 键扫描
JZ MAIN_LP ; 无键返回

MOV R7,#10 ; 延时10ms
LCALL DELAYMS ; 延时去抖动
LCALL SCAN_KEY ; 再次扫描
JZ MAIN_LP ; 无键返回

MOV KEY_V,KEY_S ; 保存键值
LCALL PROC_KEY ; 键处理
SJMP MAIN_LP ; 调回主循环

;===============================================================================
SCAN_KEY:
; 扫键扫描子程序
; 保存按键状态到key_s
; 返回: A --- 按键是否按下(BOOL)

CLR A

MOV C,K1 ; 读按键K1
MOV ACC.0,C
MOV C,K2 ; 读按键K2
MOV ACC.1,C

MOV KEY_S,A ; 保存按键状态到key_s
XRL A,KEY_V
RET

;===============================================================================
PROC_KEY:
; 键处理子程序
; 传入参数: KEY_V --- 按键值
; 返回值: 无

CLR EA

MOV A,KEY_V
JNB ACC.0,PROC_K1
JNB ACC.1,PROC_K2
SJMP END_PROC_KEY

PROC_K1: ; 按键k1处理
LCALL INC_HOUR ; 小时加1
SJMP END_PROC_KEY

PROC_K2: ; 按键K2处理
INC MIN ; 分钟加1

MOV A,MIN ;
SETB C
SUBB A,#59
JC K2_UPDATE_MIN ; 如果分钟等于60,则分清0,小时加1

CLR A ;
MOV MIN,A

K2_UPDATE_MIN: ; 更新分显示缓冲区
MOV A,MIN
MOV B,#10
DIV AB ; A = MIN / 10
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_MIN_H,A ; 更新分十位

MOV A,MIN
MOV B,#10
DIV AB
MOV A,B ; A = MIN % 10
MOVC A,@A+DPTR
MOV BUF_MIN_L,A ; 更新分个位

END_PROC_KEY:
SETB EA
RET

;===============================================================================

USING 0
TIMER0:
; 定时器0中断服程序, 用于数码管的动态扫描
; DIS_INDEX --- 显示索引, 用于标识当前显示的数码管和缓冲区的偏移量
; DIS_DIGIT --- 位选通值, 传送到P2口用于选通当前数码管的数值, 如等于0xfe时,
; 选通P2.0口数码管
; DIS_BUF --- 显于缓冲区基地址

PUSH ACC
PUSH PSW
PUSH AR0

MOV TH0,#0FCH
MOV TL0,#017H

MOV P2,#0FFH ; 先关闭所有数码管

MOV A,#DIS_BUF ; 获得显示缓冲区基地址
ADD A,DIS_INDEX ; 获得偏移量
MOV R0,A ; R0 = 基地址 + 偏移量
MOV A,@R0 ; 获得显示代码
MOV P0,A ; 显示代码传送到P0口

MOV P2,DIS_DIGIT

MOV A,DIS_DIGIT ; 位选通值左移, 下次中断时选通下一位数码管
RL A
MOV DIS_DIGIT,A

INC DIS_INDEX ; DIS_INDEX加1, 下次中断时显示下一位
ANL DIS_INDEX,#0x07 ; 当DIS_INDEX等于8(0000 1000)时, 清0

POP AR0
POP PSW
POP ACC

RETI

;===============================================================================
USING 0
TIMER1:
; 定时器1中断服务程序, 产生时基信号10ms
;
;
PUSH PSW
PUSH ACC
PUSH B
PUSH DPH
PUSH DPL

MOV TH1,#0DCH

INC SEC100

MOV A,SEC100
CLR C
SUBB A,#100 ; 是否中断100次(达到1s)
JC END_TIMER1 ; < 1S

MOV SEC100,#00H ; 达到1s
LCALL INC_SEC ; 秒加1

END_TIMER1:
POP DPL
POP DPH
POP B
POP ACC
POP PSW

RETI ;

;===============================================================================
INC_SEC:
INC SEC

MOV A,SEC
SETB C
SUBB A,#59 ;
JC UPDATE_SEC

CLR A
MOV SEC,A
LCALL INC_MIN

UPDATE_SEC:
MOV A,SEC
MOV B,#10
DIV AB ; A = SEC / 10
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR ;
MOV BUF_SEC_H,A ;

MOV A,SEC
MOV B,#10
DIV AB
MOV A,B ; A = SEC % 10
MOVC A,@A+DPTR
MOV BUF_SEC_L,A
RET

;===============================================================================

INC_MIN:
INC MIN ; 分钟加1

MOV A,MIN ;
SETB C
SUBB A,#59
JC UPDATE_MIN ; 如果分钟等于60,则分清0,小时加1

CLR A ;
MOV MIN,A
LCALL INC_HOUR ; 小时加1

UPDATE_MIN: ; 更新分显示缓冲区
MOV A,MIN
MOV B,#10
DIV AB ; A = MIN / 10
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_MIN_H,A ; 更新分十位

MOV A,MIN
MOV B,#10
DIV AB
MOV A,B ; A = MIN % 10
MOVC A,@A+DPTR
MOV BUF_MIN_L,A ; 更新分个位

RET

;===============================================================================

INC_HOUR:
INC HOUR ; 小时加1
MOV A,HOUR
SETB C
SUBB A,#24
JC UPDATE_HOUR ; 如果小时等于24,则小时清0

CLR A
MOV HOUR,A ; 小时清0

UPDATE_HOUR:
MOV A,HOUR
SETB C
SUBB A,#10
JC UPDATE_HOUR1 ; 如果小时小于10,则十位0不显示

MOV A,HOUR
MOV B,#10
DIV AB
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR ;
MOV BUF_HOUR_H,A
SJMP UPDATE_HOUR2

UPDATE_HOUR1:
MOV BUF_HOUR_H,#0FFH

UPDATE_HOUR2:
MOV A,HOUR
MOV B,#10
DIV AB
MOV A,B
MOV DPTR,#DIS_CODE
MOVC A,@A+DPTR
MOV BUF_HOUR_L,A
RET

;===============================================================================

DELAYMS:
; 延时子程序
; 传入参数：R7 --- 延时值(MS)
; 返回值：无

MOV A,R7
JZ END_DLYMS
DLY_LP1:
MOV R6,#185
DLY_LP2:
NOP
NOP
NOP
DJNZ R6,DLY_LP2
DJNZ R7,DLY_LP1

END_DLYMS:
RET

; END OF DELAYMS

;===============================================================================

DIS_CODE:
DB 0C0H
DB 0F9H
DB 0A4H
DB 0B0H
DB 099H
DB 092H
DB 082H
DB 0F8H
DB 080H
DB 090H
DB 0FFH

END

❷ 51单片机编程题，用汇编语言怎么做

在8051单片机的时钟频率为6MHz，那么定时器的计数脉冲周期就是 2uS；

sbit CP=P1^0;

void Timer0_init()

{

TMOD |=0x01; //T0定时器，方式1，采用16位定时器

TH0 = (65536-500)/256; //定时器装初值500, 即 1000uS 中断一次

TL0 = (65536-500)%256;

EA=1; ET0=1; TR0=1;

}

void timer0() interrupt 1

{

TH0 = (65536-500)/256; //定时器装初值500, 1mS 中断一次

TL0 = (65536-500)%256;

CP=~CP; //改变脉冲信号的输出状态

}

void main()

{

Timer0_init();

CP=0;

while(1) { }

}

汇编语言，才看到，算了，你别人的回答吧

❸ 8051单片机的汇编程序编程问题！！！

既然向我求助,那我就写一下大概的思路和C语言程序,至于汇编语言,兄弟可自己由C语言翻译,我今天的确没太有时间.
周期为2个ms的方波,也就是说半个周期为1ms,也就是说,P1.2每1ms翻转一次;
同理,P1.3每3.5ms翻转一次,因为只能用一个定时器,所以,取1ms和3.5ms的最大公约数,是0.5ms,也就是说,让定时器0.5ms中断一次,然后每两个中断,翻转一次P1.2,每7个中断翻转一次P1.3;
这就是编程思路,那么我们来看具体的编程细节;
6Mhz,也就是指令周期是2us,0.5ms需要250个计数,250<256,为了速度和效率,我们让定时器1工作在自动重载模式下,也就是模式2;

C语言整个程序编程如下;

#include <reg52.h>
bit P1_2_Turn_Cnt = 0; //----用于P1.2的计数翻转,因为只有两次,大可不必用unsigned char类型的
unsigned char P1_3_Turn_Cnt = 0; //----用于P1.3的计数翻转,因为要7次,所以用unsigned char
sbit P1_3 = P1^3;
sbt P1_2 = P1^2;
void main(void)
{
//----初始化定时器,工作在模式2,自动重载,开中断,每0.5ms中断一次
TH1 = 256 - 250; //----设置定时器,250 X 2us = 500us = 0.5ms
TL1 = 256 -250;
TMOD = 0x20; //----定时器/计数器1 工作在模式2下;
ET1 = 1; //----开定时器1中断
TR1 = 1; //-----启动定时器
EA = 1; //----开总中断
while(1); //----定时器初始化完成,方波工作在定时器内部完成;
}

void ISR_Timer1(void) interrupt 3
{
P1_2_Turn_Cnt = ~P1_2_Turn_Cnt;//---P1_2翻转计数,由于初始化为0,所以第1次会翻转为1;
//---由此推论,奇数次翻转后状态为1,偶数次中断会翻转为
//---0,所以当P1_2_Turn_Cnt = 0时,P1_2翻转.
if(P1_2_Turn_Cnt == 0)
{
P1_2 = ~P1_2;
}
P1_3_Turn_Cnt++;
if(P1_3_Turn_Cnt >= 7)
{
P1_3_Turn_Cnt = 0;
P1_3 = ~P1_3;
}
}

以上就是这个程序实现的全部过程,你可以自己手动翻译成汇编语言,也可以用Keil的Debug模式自动翻译,因为我时间有限,所以就不给你翻译了,请见谅!

❹ 请教8051汇编指令

MCS-51数据传送指令

数据传送指令共有29条，数据传送指令一般的操作是把源操作数传送到目的操作数，指令执行完成后，源操作数不变，目的操作数等于源操作数。如果要求在进行数据传送时，目的操作数不丢失，则不能用直接传送指令，而采用交换型的数据传送指令，数据传送指令不影响标志C,AC和OV，但可能会对奇偶标志P有影响。

[1]. 以累加器A为目的操作数类指令（4条）
这4条指令的作用是把源操作数指向的内容送到累加器A。有直接、立即数、寄存器和寄存器间接寻址方式：

MOV A,data ;（data）→（A） 直接单元地址中的内容送到累加器A
MOV A,#data ;#data→（A） 立即数送到累加器A中
MOV A,Rn ;（Rn）→（A） Rn中的内容送到累加器A中
MOV A,@Ri ;（（Ri））→（A） Ri内容指向的地址单元中的内容送到累加器A

[2]. 以寄存器Rn为目的操作数的指令（3条）
这3条指令的功能是把源操作数指定的内容送到所选定的工作寄存器Rn中。有直接、立即和寄存器寻址方式：

MOV Rn,data ;（data）→（Rn） 直接寻址单元中的内容送到寄存器Rn中
MOV Rn,#data ;#data→（Rn） 立即数直接送到寄存器Rn中
MOV Rn,A ;（A）→（Rn） 累加器A中的内容送到寄存器Rn中

[3]. 以直接地址为目的操作数的指令（5条）
这组指令的功能是把源操作数指定的内容送到由直接地址data所选定的片内RAM中。有直接、立即、寄存器和寄存器间接4种寻址方式：

MOV data,data ;（data）→（data） 直接地址单元中的内容送到直接地址单元
MOV data,#data ;#data→（data） 立即数送到直接地址单元
MOV data,A ;（A）→（data） 累加器A中的内容送到直接地址单元
MOV data,Rn ;（Rn）→（data） 寄存器Rn中的内容送到直接地址单元
MOV data,@Ri ;（（Ri））→（data） 寄存器Ri中的内容指定的地址单元中数据送到直接地址单元

[4]. 以间接地址为目的操作数的指令（3条）
这组指令的功能是把源操作数指定的内容送到以Ri中的内容为地址的片内RAM中。有直接、立即和寄存器3种寻址方式：

MOV @Ri,data ;（data）→（（Ri）） 直接地址单元中的内容送到以Ri中的内容为地址的RAM单元
MOV @Ri,#data ;#data→（（Ri）） 立即数送到以Ri中的内容为地址的RAM单元
MOV @Ri,A ;（A）→（（Ri）） 累加器A中的内容送到以Ri中的内容为地址的RAM单元

[5]. 查表指令（2条）
这组指令的功能是对存放于程序存储器中的数据表格进行查找传送，使用变址寻址方式：

MOVC A,@A+DPTR ;（（A））+（DPTR）→（A） 表格地址单元中的内容送到累加器A中
MOVC A,@A+PC ;（（PC））+1→（A），（（A））+（PC）→（A） 表格地址单元中的内容送到累加器A中

[6]. 累加器A与片外数据存储器RAM传送指令（4条）
这4条指令的作用是累加器A与片外RAM间的数据传送。使用寄存器寻址方式：

MOVX @DPTR,A ;（A）→（（DPTR）） 累加器中的内容送到数据指针指向片外RAM地址中
MOVX A, @DPTR ;（（DPTR））→（A） 数据指针指向片外RAM地址中的内容送到累加器A中
MOVX A, @Ri ;（（Ri））→（A） 寄存器Ri指向片外RAM地址中的内容送到累加器A中
MOVX @Ri,A ;（A）→（（Ri）） 累加器中的内容送到寄存器Ri指向片外RAM地址中

[7]. 堆栈操作类指令（2条）
这4类指令的作用是把直接寻址单元的内容传送到堆栈指针SP所指的单元中，以及把SP所指单元的内容送到直接寻址单元中。这类指令只有两条，下述的第一条常称为入栈操作指令，第二条称为出栈操作指令。需要指出的是，单片机开机复位后，（SP）默认为07H，但一般都需要重新赋值，设置新的SP首址。入栈的第一个数据必须存放于SP+1所指存储单元，故实际的堆栈底为SP+1所指的存储单元。

PUSH data ;（SP）+1→（SP），（data）→（SP） 堆栈指针首先加1，直接寻址单元中的数据送到堆栈指针SP所指的单元中
POP data ;（SP）→（data）（SP）-1→（SP）， 堆栈指针SP所指的单元数据送到直接寻址单元中，堆栈指针SP再进行减1操作

[8]. 交换指令（5条）
这5条指令的功能是把累加器A中的内容与源操作数所指的数据相互交换。

XCH A,Rn ;（A）←→（Rn）累加器与工作寄存器Rn中的内容互换
XCH A,@Ri ;（A）←→（（Ri））累加器与工作寄存器Ri所指的存储单元中的内容互换
XCH A,data ;（A）←→（data）累加器与直接地址单元中的内容互换
XCHD A,@Ri ;（A 3-0 ）←→（（Ri） 3-0 ）累加器与工作寄存器Ri所指的存储单元中的内容低半字节互换
SWAP A ;（A 3-0 ）←→（A 7-4 ）累加器中的内容高低半字节互换

[9]. 16位数据传送指令（1条）
这条指令的功能是把16位常数送入数据指针寄存器。

MOV DPTR,#data16 ;#dataH→（DPH），#dataL→（DPL）16位常数的高8位送到DPH，低8位送到DPL

MCS-51算术运算指令

算术运算指令共有24条，算术运算主要是执行加、减、乘、除法四则运算。另外MCS-51指令系统中有相当一部分是进行加、减1操作，BCD码的运算和调整，我们都归类为运算指令。虽然MCS-51单片机的算术逻辑单元ALU仅能对8位无符号整数进行运算，但利用进位标志C，则可进行多字节无符号整数的运算。同时利用溢出标志，还可以对带符号数进行补码运算。需要指出的是，除加、减1指令外，这类指令大多数都会对PSW（程序状态字）有影响。这在使用中应特别注意。

[1]. 加法指令（4条）
这4条指令的作用是把立即数，直接地址、工作寄存器及间接地址内容与累加器A的内容相加，运算结果存在A中。

ADD A,#data ;（A）+#data→（A） 累加器A中的内容与立即数#data相加，结果存在A中
ADD A,data ;（A）+（data）→（A） 累加器A中的内容与直接地址单元中的内容相加，结果存在A中
ADD A,Rn ;（A）+（Rn）→（A） 累加器A中的内容与工作寄存器Rn中的内容相加，结果存在A中
ADD A,@Ri ;（A）+（（Ri））→（A） 累加器A中的内容与工作寄存器Ri所指向地址单元中的内容相加，结果存在A中

[2]. 带进位加法指令（4条）
这4条指令除与[1]功能相同外，在进行加法运算时还需考虑进位问题。

ADDC A,data ;（A）+（data）+（C）→（A） 累加器A中的内容与直接地址单元的内容连同进位位相加，结果存在A中
ADDC A,#data ;（A）+#data +（C）→（A） 累加器A中的内容与立即数连同进位位相加，结果存在A中
ADDC A,Rn ;（A）+Rn+（C）→（A） 累加器A中的内容与工作寄存器Rn中的内容、连同进位位相加，结果存在A中
ADDC A,@Ri ;（A）+（（Ri））+（C）→（A） 累加器A中的内容与工作寄存器Ri指向地址单元中的内容、连同进位位相加，结果存在A中

[3]. 带借位减法指令（4条）
这组指令包含立即数、直接地址、间接地址及工作寄存器与累加器A连同借位位C内容相减，结果送回累加器A中。
这里我们对借位位C的状态作出说明，在进行减法运算中，CY=1表示有借位，CY=0则无借位。OV=1声明带符号数相减时，从一个正数减去一个负数结果为负数，或者从一个负数中减去一个正数结果为正数的错误情况。在进行减法运算前，如果不知道借位标志位C的状态，则应先对CY进行清零操作。

SUBB A,data ;（A）-（data） - （C）→（A） 累加器A中的内容与直接地址单元中的内容、连同借位位相减，结果存在A中
SUBB A,#data ;（A）-#data -（C）→（A） 累加器A中的内容与立即数、连同借位位相减，结果存在A中
SUBB A,Rn ;（A）-（Rn） -（C）→（A） 累加器A中的内容与工作寄存器中的内容、连同借位位相减，结果存在A中
SUBB A,@Ri ;（A）-（（Ri）） -（C）→（A） 累加器A中的内容与工作寄存器Ri指向的地址单元中的内容、连同借位位相减，结果存在A中

[4]. 乘法指令（1条）
这个指令的作用是把累加器A和寄存器B中的8位无符号数相乘，所得到的是16位乘积，这个结果低8位存在累加器A，而高8位存在寄存器B中。如果OV=1，说明乘积大于FFH，否则OV=0，但进位标志位CY总是等于0。

MUL AB ;（A）×（B）→（A）和（B） 累加器A中的内容与寄存器B中的内容相乘，结果存在A、B中

[5]. 除法指令（1条）
这个指令的作用是把累加器A的8位无符号整数除以寄存器B中的8位无符号整数，所得到的商存在累加器A，而余数存在寄存器B中。除法运算总是使OV和进位标志位CY等于0。如果OV=1，表明寄存器B中的内容为00H，那么执行结果为不确定值，表示除法有溢出。

DIV AB ;（A）÷（B）→（A）和（B） 累加器A中的内容除以寄存器B中的内容，所得到的商存在累加器A，而余数存在寄存器B中。

[6]. 加1指令（5条）
这5条指令的的功能均为原寄存器的内容加1，结果送回原寄存器。上述提到，加1指令不会对任何标志有影响，如果原寄存器的内容为FFH，执行加1后，结果就会是00H。这组指令共有直接、寄存器、寄存器减间址等寻址方式：

INC A ;（A）+1→（A） 累加器A中的内容加1，结果存在A中
INC data ;（data）+1→（data） 直接地址单元中的内容加1，结果送回原地址单元中
INC @Ri ;（（Ri））+1→（（Ri）） 寄存器的内容指向的地址单元中的内容加1，结果送回原地址单元中
INC Rn ;（Rn）+1→（Rn）寄存器Rn的内容加1，结果送回原地址单元中
INC DPTR ;（DPTR）+1→（DPTR）数据指针的内容加1，结果送回数据指针中

在INC data这条指令中，如果直接地址是I/O，其功能是先读入I/O锁存器的内容，然后在CPU进行加1操作，再输出到I/O上，这就是“读—修改—写”操作。

[7]. 减1指令（4条）
这组指令的作用是把所指的寄存器内容减1，结果送回原寄存器，若原寄存器的内容为00H，减1后即为FFH，运算结果不影响任何标志位，这组指令共有直接、寄存器、寄存器间址等寻址方式，当直接地址是I/O口锁存器时，“读—修改—写”操作与加1指令类似。

DEC A ;（A）-1→（A）累加器A中的内容减1，结果送回累加器A中
DEC data ;（data）-1→（data）直接地址单元中的内容减1，结果送回直接地址单元中
DEC @Ri ;（（Ri））-1→（（Ri））寄存器Ri指向的地址单元中的内容减1，结果送回原地址单元中

DEC Rn ;（Rn）-1→（Rn）寄存器Rn中的内容减1，结果送回寄存器Rn中

[8]. 十进制调整指令（1条）
在进行BCD码运算时，这条指令总是跟在ADD或ADDC指令之后，其功能是将执行加法运算后存于累加器A中的结果进行调整和修正。

DA A

MCS-51逻辑运算及移位指令

逻辑运算和移位指令共有25条，有与、或、异或、求反、左右移位、清0等逻辑操作，有直接、寄存器和寄存器间址等寻址方式。这类指令一般不影响程序状态字（PSW）标志。

[1]. 循环移位指令（4条）
这4条指令的作用是将累加器中的内容循环左或右移一位，后两条指令是连同进位位CY一起移位。

RL A ;累加器A中的内容左移一位
RR A ;累加器A中的内容右移一位
RLC A ;累加器A中的内容连同进位位CY左移一位
RRC A ;累加器A中的内容连同进位位CY右移一位

[2]. 累加器半字节交换指令（1条）
这条指令是将累加器中的内容高低半字节互换，这在上一节中内容已有介绍。

SWAP A ; 累加器中的内容高低半字节互换

[3]. 求反指令（1条）
这条指令将累加器中的内容按位取反。

CPL A ; 累加器中的内容按位取反

[4]. 清零指令（1条）
这条指令将累加器中的内容清0。

CLR A ; 0→（A），累加器中的内容清0

[5]. 逻辑与操作指令（6条）
这组指令的作用是将两个单元中的内容执行逻辑与操作。如果直接地址是I/O地址，则为“读—修改—写”操作。

ANL A,data ;累加器A中的内容和直接地址单元中的内容执行与逻辑操作。结果存在寄存器A中。
ANL data,#data ;直接地址单元中的内容和立即数执行与逻辑操作。结果存在直接地址单元中。
ANL A,#data ;累加器A的内容和立即数执行与逻辑操作。结果存在累加器A中。
ANL A,Rn ;累加器A的内容和寄存器Rn中的内容执行与逻辑操作。结果存在累加器A中。
ANL data,A ;直接地址单元中的内容和累加器A的内容执行与逻辑操作。结果存在直接地址单元中。
ANL A,@Ri ;累加器A的内容和工作寄存器Ri指向的地址单元中的内容执行与逻辑操作。结果存在累加器A中。

[6]. 逻辑或操作指令（6条）
这组指令的作用是将两个单元中的内容执行逻辑或操作。如果直接地址是I/O地址，则为“读—修改—写”操作。

ORL A,data ;累加器A中的内容和直接地址单元中的内容执行逻辑或操作。结果存在寄存器A中。
ORL data,#data ;直接地址单元中的内容和立即数执行逻辑或操作。结果存在直接地址单元中。
ORL A,#data ;累加器A的内容和立即数执行逻辑或操作。结果存在累加器A中。
ORL A,Rn ;累加器A的内容和寄存器Rn中的内容执行逻辑或操作。结果存在累加器A中。
ORL data,A ;直接地址单元中的内容和累加器A的内容执行逻辑或操作。结果存在直接地址单元中。
ORL A,@Ri ;累加器A的内容和工作寄存器Ri指向的地址单元中的内容执行逻辑或操作。结果存在累加器A中。

[7]. 逻辑异或操作指令（6条）
这组指令的作用是将两个单元中的内容执行逻辑异或操作。如果直接地址是I/O地址，则为“读—修改—写”操作。

XRL A,data ;累加器A中的内容和直接地址单元中的内容执行逻辑异或操作。结果存在寄存器A中。
XRL data,#data ;直接地址单元中的内容和立即数执行逻辑异或操作。结果存在直接地址单元中。
XRL A,#data ;累加器A的内容和立即数执行逻辑异或操作。结果存在累加器A中。
XRL A,Rn ;累加器A的内容和寄存器Rn中的内容执行逻辑异或操作。结果存在累加器A中。
XRL data,A ;直接地址单元中的内容和累加器A的内容执行逻辑异或操作。结果存在直接地址单元中。
XRL A,@Ri ;累加器A的内容和工作寄存器Ri指向的地址单元中的内容执行逻辑异或操作。结果存在累加器A中。

MCS-51控制转移指令

控制转移指令用于控制程序的流向，所控制的范围即为程序存储器区间，MCS-51系列单片机的控制转移指令相对丰富，有可对64kB程序空间地址单元进行访问的长调用、长转移指令，也有可对2kB字节进行访问的绝对调用和绝对转移指令，还有在一页范围内短相对转移及其它无条件转移指令，这些指令的执行一般都不会对标志位有影响。

[1]. 无条件转移指令（4条）
这组指令执行完后，程序就会无条件转移到指令所指向的地址上去。长转移指令访问的程序存储器空间为16地址64kB，绝对转移指令访问的程序存储器空间为11位地址2kB空间。

LJMP addr16 ;addr16→（PC），给程序计数器赋予新值（16位地址）

AJMP addr11 ;（PC）+2→（PC），addr11→（PC 10-0 ）程序计数器赋予新值（11位地址），（PC 15-11 ）不改变

SJMP rel ;（PC）+ 2 + rel→（PC）当前程序计数器先加上2再加上偏移量给程序计数器赋予新值

JMP @A+DPTR ;（A）+ （DPTR）→（PC），累加器所指向地址单元的值加上数据指针的值给程序计数器赋予新值

[2]. 条件转移指令（8条）
程序可利用这组丰富的指令根据当前的条件进行判断，看是否满足某种特定的条件，从而控制程序的转向。

JZ rel ; A=0,（PC）+ 2 + rel→（PC）,累加器中的内容为0，则转移到偏移量所指向的地址，否则程序往下执行

JNZ rel ; A≠0,（PC）+ 2 + rel→（PC）,累加器中的内容不为0，则转移到偏移量所指向的地址，否则程序往下执行

CJNE A, data, rel ; A≠（data）,（PC）+ 3 + rel→（PC）,累加器中的内容不等于直接地址单元的内容，则转移到偏移量所指向的地址，否则程序往下执行

CJNE A, #data, rel ; A≠#data,（PC）+ 3 + rel→（PC）,累加器中的内容不等于立即数，则转移到偏移量所指向的地址，否则程序往下执行

CJNE Rn, #data, rel ; A≠#data,（PC）+ 3 + rel→（PC）,工作寄存器Rn中的内容不等于立即数，则转移到偏移量所指向的地址，否则程序往下执行

CJNE @Ri, #data, rel ; A≠#data,（PC）+ 3 + rel→（PC）,工作寄存器Ri指向地址单元中的内容不等于立即数，则转移到偏移量所指向的地址，否则程序往下执行

DJNZ Rn, rel ; （Rn）-1→（Rn),（Rn)≠0,（PC）+ 2 + rel→（PC）工作寄存器Rn减1不等于0，则转移到偏移量所指向的地址，否则程序往下执行

DJNZ data, rel ; （Rn）-1→（Rn),（Rn)≠0,（PC）+ 2 + rel→（PC）直接地址单元中的内容减1不等于0，则转移到偏移量所指向的地址，否则程序往下执行

[3]. 子程序调用指令（1条）
子程序是为了便于程序编写，减少那些需反复执行的程序占用多余的地址空间而引入的程序分支，从而有了主程序和子程序的概念，需要反复执行的一些程序，我们在编程时一般都把它们编写成子程序，当需要用它们时，就用一个调用命令使程序按调用的地址去执行，这就需要子程序的调用指令和返回指令。

LCALL addr16 ; 长调用指令，可在64kB空间调用子程序。此时（PC）+ 3→（PC），（SP）+ 1→（SP），（PC 7-0 ）→（SP），（SP）+ 1→（SP），（PC 15-8 ）→（SP），addr16→（PC），即分别从堆栈中弹出调用子程序时压入的返回地址

ACALL addr11 ; 绝对调用指令，可在2kB空间调用子程序，此时（PC）+ 2→（PC），（SP）+ 1→（SP），（PC 7-0 ）→（SP），（SP）+ 1→（SP），（PC 15-8 ）→（SP），addr11→（PC 10-0 ）

RET ; 子程序返回指令。此时（SP）→（PC 15-8 ），（SP）- 1→（SP），（SP）→（PC 7-0 ），（SP）- 1→（SP）

RETI ; 中断返回指令，除具有RET功能外，还具有恢复中断逻辑的功能，需注意的是，RETI指令不能用RET代替

[4]. 空操作指令（1条）
这条指令将累加器中的内容清0。

NOP ; 这条指令除了使PC加1，消耗一个机器周期外，没有执行任何操作。可用于短时间的延时

MCS-51布尔变量操作指令

布尔处理功能是MCS-51系列单片机的一个重要特征，这是出于实际应用需要而设置的。布尔变量也即开关变量，它是以位（bit）为单位进行操作的。

在物理结构上，MCS-51单片机有一个布尔处理机，它以进位标志做为累加位，以内部RAM可寻址的128个为存储位。

既然有布尔处理机功能，所以也就有相应的布尔操作指令集，下面我们分别谈论。

[1]. 位传送指令（2条）
位传送指令就是可寻址位与累加位CY之间的传送，指令有两条。

MOV C,bit ;bit→CY，某位数据送CY

MOV bit,C ;CY→bit，CY数据送某位

[2]. 位置位复位指令（4条）
这些指令对CY及可寻址位进行置位或复位操作，共有四条指令。

CLR C ; 0→CY,清CY

CLR bit ; 0→bit,清某一位

SETB C ; 1→CY,置位CY

SETB bit ; 1→bit,置位某一位

[3]. 位运算指令（6条）
位运算都是逻辑运算，有与、或、非三种指令，共六条。

ANL C,bit ;(CY)∧(bit)→CY

ANL C,/bit ;(CY)∧( )→CY

ORL C,bit ;(CY)∨(bit)→CY

ORL C,/bit ;(CY)∧( )→CY

CPL C ;( )→CY

CPL bit ;( )→bir

[4]. 位控制转移指令（5）
位控制转移指令是以位的状态作为实现程序转移的判断条件，介绍如下：

JC rel ; (CY)=1转移，（PC）+2+rel→PC，否则程序往下执行，（PC）+2→PC。

JNC rel ; (CY)=0转移，（PC）+2+rel→PC，否则程序往下执行，（PC）+2→PC。

JB bit, rel ; 位状态为1转移。

JNB bit, rel ; 位状态为0转移。

JBC bit, rel ; 位状态为1转移，并使该位清“0”。

后三条指令都是三字节指令，如果条件满足，（PC）+3+rel→PC，否则程序往下执行，（PC）+3→PC

❺ 8051单片机汇编程序请教

你的第二次修改，还有一处不足：
……
;CLR C
MOV DPTR,#TABLE
LOOP:
CLR A ;这里少了一句，下面每次读出的，
;就不知道是什么了
MOVC A,@A+DPTR
JNZ CONT_P
INC R2
SJMP NEXT
……

可以正常计数的程序如下。
;=========================================
ORG 0H
MOV A,#00H
MOV R2,A
MOV R3,A
MOV R4,A
MOV R6,A
MOV R5,#40
;CLR C
MOV DPTR,#TABLE
LOOP:
CLR A
MOVC A,@A+DPTR
JNZ CONT_P
; CJNE A,#00H,CONT_P
INC R2
SJMP NEXT
CONT_P:
JB ACC.7, CONT_N
INC R3
SJMP NEXT
CONT_N:
INC R4
NEXT:
INC DPTR
DJNZ R5, LOOP
MOV P0,R4
SJMP $
; 实际个数 保存单元 统计个数
;零个数 14 R2 21
;正数个数 19 R3 19
;负数个数: 7 R4 0
;其实是零和负数没有分开统计,请高手指教一下,谢谢!

ORG 400H
TABLE:
DB 01H, 15H, 22H,0FFH, 00H, 02H, 09H,0F9H, 00H, 00H
DB 01H, 15H, 22H,0FFH, 00H, 02H, 09H,0F9H, 00H, 00H
DB 01H, 15H, 22H,0FFH, 00H, 02H, 09H,0F9H, 00H, 00H
DB 02H, 05H, 00H,0FFH, 26H, 34H, 00H, 00H, 00H, 00H
END

❻ 8051怎么读取rom中的内容

假设您使用的是8051单片机，下面是一种可能的汇编语言代码实现，将ROM 2000H单元中的内容传送到内部RAM 20H单元中：

cssCopy codeMOV DPTR,#2000H ; 将ROM地址2000H的内容存储到DPTR寄存器中
MOV A,@DPTR ; 将DPTR寄存器中地址对应的ROM中的值传送到累加器A中
MOV @20H,A ; 将累加器A中的值传送到内部RAM 20H单元中

解释：

• MOV DPTR,#2000H：将ROM地址2000H存储到DPTR寄存器中。

• MOV A,@DPTR：将DPTR寄存器中地址对应的ROM中的值传送到累加器A中。

• MOV @20H,A：将累加器A中的值传送到内部RAM 20H单元中。

需要注意的是，具体的实现方式可能会因单片机型号、编译器等因素而有所不同。